ground/gcs/src/experimental/SerialLogger/SerialLogger.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-08-25T23:31:09
   4 #
   5 #-------------------------------------------------
   6
   7 QT       += core
   8 QT       -= gui
   9
  10 TARGET = SerialLogger
  11 CONFIG   += console
  12 CONFIG   -= app_bundle
  13
  14 TEMPLATE = app
  15
  16 INCLUDEPATH += ../../libs/qextserialport/src
  17
  18 # event driven device enumeration on windows requires the gui module
  19 win32:QT               += gui
  20
  21 HEADERS                 = ../../libs/qextserialport/src/qextserialport.h \
  22                           ../../libs/qextserialport/src/qextserialenumerator.h \
  23                           ../../libs/qextserialport/src/qextserialport_global.h
  24 SOURCES                 = ../../libs/qextserialport/src/qextserialport.cpp
  25
  26 unix:SOURCES           += ../../libs/qextserialport/src/posix_qextserialport.cpp
  27 unix:!macx:SOURCES     += ../../libs/qextserialport/src/qextserialenumerator_unix.cpp
  28 macx {
  29   SOURCES          += ../../libs/qextserialport/src/qextserialenumerator_osx.cpp
  30   LIBS             += -framework IOKit -framework CoreFoundation
  31 }
  32
  33 win32 {
  34   SOURCES          += ../../libs/qextserialport/src/win_qextserialport.cpp
  35   SOURCES          += ../../libs/qextserialport/src/qextserialenumerator_win.cpp
  36   DEFINES          += WINVER=0x0501 # needed for mingw to pull in appropriate dbt business...probably a better way to do this
  37   LIBS             += -lsetupapi
  38 }
  39
  40 SOURCES += main.cpp