ground/gcs/src/libs/osgearth/osgearth.pro

   1 TEMPLATE = lib
   2 TARGET = GCSOsgEarth
   3 DEFINES += OSGEARTH_LIBRARY
   4
   5 #DEFINES += OSG_VERBOSE
   6
   7 osg:DEFINES += USE_OSG
   8 osgQt:DEFINES += USE_OSG_QT
   9
  10 osgearth:DEFINES += USE_OSGEARTH
  11 osgearthQt:DEFINES += USE_OSGEARTH_QT
  12
  13 #DEFINES += OSG_USE_QT_PRIVATE
  14
  15 QT += widgets opengl qml quick
  16 contains(DEFINES, OSG_USE_QT_PRIVATE) {
  17     QT += core-private gui-private
  18 }
  19
  20 include(../../library.pri)
  21 include(../utils/utils.pri)
  22
  23 include(osgearth_dependencies.pri)
  24
  25 linux {
  26     QMAKE_RPATHDIR = $$shell_quote(\$$ORIGIN/$$relative_path($$GCS_LIBRARY_PATH/osg, $$GCS_LIBRARY_PATH))
  27     include(../../rpath.pri)
  28 }
  29
  30 # disable all warnings on mac to avoid build failures
  31 macx:CONFIG += warn_off
  32
  33 # osg and osgearth emit a lot of unused parameter warnings...
  34 QMAKE_CXXFLAGS += -Wno-unused-parameter
  35
  36 HEADERS += \
  37     osgearth_global.h \
  38     osgearth.h \
  39     utils/qtwindowingsystem.h \
  40     utils/utility.h \
  41     utils/shapeutils.h \
  42     utils/imagesource.hpp
  43
  44 SOURCES += \
  45     osgearth.cpp \
  46     utils/qtwindowingsystem.cpp \
  47     utils/utility.cpp \
  48     utils/shapeutils.cpp \
  49     utils/imagesource.cpp
  50
  51 HEADERS += \
  52     osgQtQuick/Export.hpp \
  53     osgQtQuick/DirtySupport.hpp \
  54     osgQtQuick/OSGNode.hpp \
  55     osgQtQuick/OSGGroup.hpp \
  56     osgQtQuick/OSGTransformNode.hpp \
  57     osgQtQuick/OSGShapeNode.hpp \
  58     osgQtQuick/OSGImageNode.hpp \
  59     osgQtQuick/OSGTextNode.hpp \
  60     osgQtQuick/OSGFileNode.hpp \
  61     osgQtQuick/OSGBillboardNode.hpp \
  62     osgQtQuick/OSGCamera.hpp \
  63     osgQtQuick/OSGViewport.hpp
  64
  65 SOURCES += \
  66     osgQtQuick/DirtySupport.cpp \
  67     osgQtQuick/OSGNode.cpp \
  68     osgQtQuick/OSGGroup.cpp \
  69     osgQtQuick/OSGTransformNode.cpp \
  70     osgQtQuick/OSGShapeNode.cpp \
  71     osgQtQuick/OSGImageNode.cpp \
  72     osgQtQuick/OSGTextNode.cpp \
  73     osgQtQuick/OSGFileNode.cpp \
  74     osgQtQuick/OSGBillboardNode.cpp \
  75     osgQtQuick/OSGCamera.cpp \
  76     osgQtQuick/OSGViewport.cpp
  77
  78 HEADERS += \
  79     osgQtQuick/ga/OSGCameraManipulator.hpp \
  80     osgQtQuick/ga/OSGNodeTrackerManipulator.hpp \
  81     osgQtQuick/ga/OSGTrackballManipulator.hpp
  82
  83 SOURCES += \
  84     osgQtQuick/ga/OSGCameraManipulator.cpp \
  85     osgQtQuick/ga/OSGNodeTrackerManipulator.cpp \
  86     osgQtQuick/ga/OSGTrackballManipulator.cpp
  87
  88 gstreamer:HEADERS += \
  89     utils/gstreamer/gstimagestream.hpp \
  90     utils/gstreamer/gstimagesource.hpp
  91
  92 gstreamer:SOURCES += \
  93     utils/gstreamer/gstimagestream.cpp \
  94     utils/gstreamer/gstimagesource.cpp
  95
  96 osgearth:HEADERS += \
  97     osgQtQuick/OSGSkyNode.hpp \
  98     osgQtQuick/OSGGeoTransformNode.hpp
  99
 100 osgearth:SOURCES += \
 101     osgQtQuick/OSGSkyNode.cpp \
 102     osgQtQuick/OSGGeoTransformNode.cpp
 103
 104 osgearth:HEADERS += \
 105     osgQtQuick/ga/OSGEarthManipulator.hpp \
 106     osgQtQuick/ga/OSGGeoTransformManipulator.hpp
 107
 108 osgearth:SOURCES += \
 109     osgQtQuick/ga/OSGEarthManipulator.cpp \
 110     osgQtQuick/ga/OSGGeoTransformManipulator.cpp
 111
 112 copy_osg:include(copydata.pro)