ground/openpilotgcs/openpilotgcs.pri

   1 defineReplace(cleanPath) {
   2     win32:1 ~= s|\\\\|/|g
   3     contains(1, ^/.*):pfx = /
   4     else:pfx =
   5     segs = $$split(1, /)
   6     out =
   7     for(seg, segs) {
   8         equals(seg, ..):out = $$member(out, 0, -2)
   9         else:!equals(seg, .):out += $$seg
  10     }
  11     return($$join(out, /, $$pfx))
  12 }
  13
  14 defineReplace(addNewline) {
  15     return($$escape_expand(\\n\\t))
  16 }
  17
  18 defineReplace(qtLibraryName) {
  19    unset(LIBRARY_NAME)
  20    LIBRARY_NAME = $$1
  21    CONFIG(debug, debug|release) {
  22       !debug_and_release|build_pass {
  23           mac:RET = $$member(LIBRARY_NAME, 0)_debug
  24               else:win32:RET = $$member(LIBRARY_NAME, 0)d
  25       }
  26    }
  27    isEmpty(RET):RET = $$LIBRARY_NAME
  28    return($$RET)
  29 }
  30
  31 defineTest(addCopyFileTarget) {
  32     file = $$1
  33     src  = $$2/$$1
  34     dest = $$3/$$1
  35
  36     $${file}.target    = $$dest
  37     $${file}.depends   = $$src
  38
  39     # create directory. Better would be an order only dependency
  40     $${file}.commands  = -@$(MKDIR) \"$$dirname(dest)\" $$addNewline()
  41     $${file}.commands += $(COPY_FILE) \"$$src\" \"$$dest\"
  42
  43     QMAKE_EXTRA_TARGETS += $$file
  44     POST_TARGETDEPS += $$eval($${file}.target)
  45
  46     export($${file}.target)
  47     export($${file}.depends)
  48     export($${file}.commands)
  49     export(QMAKE_EXTRA_TARGETS)
  50     export(POST_TARGETDEPS)
  51
  52     return(true)
  53 }
  54
  55 defineTest(addCopyDirTarget) {
  56     dir  = $$1
  57     src  = $$2/$$1
  58     dest = $$3/$$1
  59
  60     $${dir}.target    = $$dest
  61     $${dir}.depends   = $$src
  62     # Windows does not update directory timestamp if files are modified
  63     win32: $${dir}.depends += FORCE
  64
  65     $${dir}.commands  = @rm -rf \"$$dest\" $$addNewline()
  66     # create directory. Better would be an order only dependency
  67     $${dir}.commands += -@$(MKDIR) \"$$dirname(dest)\" $$addNewline()
  68     $${dir}.commands += $(COPY_DIR) \"$$src\" \"$$dest\"
  69
  70     QMAKE_EXTRA_TARGETS += $$dir
  71     POST_TARGETDEPS += $$eval($${dir}.target)
  72
  73     export($${dir}.target)
  74     export($${dir}.depends)
  75     export($${dir}.commands)
  76     export(QMAKE_EXTRA_TARGETS)
  77     export(POST_TARGETDEPS)
  78
  79     return(true)
  80 }
  81
  82 # For use in custom compilers which just copy files
  83 win32:i_flag = i
  84 defineReplace(stripSrcDir) {
  85     win32 {
  86         !contains(1, ^.:.*):1 = $$OUT_PWD/$$1
  87     } else {
  88         !contains(1, ^/.*):1 = $$OUT_PWD/$$1
  89     }
  90     out = $$cleanPath($$1)
  91     out ~= s|^$$re_escape($$_PRO_FILE_PWD_/)||$$i_flag
  92     return($$out)
  93 }
  94
  95 isEmpty(TEST):CONFIG(debug, debug|release) {
  96     !debug_and_release|build_pass {
  97         TEST = 1
  98     }
  99 }
 100
 101 isEmpty(GCS_LIBRARY_BASENAME) {
 102     GCS_LIBRARY_BASENAME = lib
 103 }
 104
 105 DEFINES += GCS_LIBRARY_BASENAME=\\\"$$GCS_LIBRARY_BASENAME\\\"
 106
 107 equals(TEST, 1) {
 108     QT +=testlib
 109     DEFINES += WITH_TESTS
 110 }
 111
 112 #ideally, we would want a qmake.conf patch, but this does the trick...
 113 win32:!isEmpty(QMAKE_SH):QMAKE_COPY_DIR = cp -r -f
 114
 115 GCS_SOURCE_TREE = $$PWD
 116 ROOT_DIR = $$GCS_SOURCE_TREE/../..
 117
 118 isEmpty(GCS_BUILD_TREE) {
 119     sub_dir = $$_PRO_FILE_PWD_
 120     sub_dir ~= s,^$$re_escape($$PWD),,
 121     GCS_BUILD_TREE = $$cleanPath($$OUT_PWD)
 122     GCS_BUILD_TREE ~= s,$$re_escape($$sub_dir)$,,
 123 }
 124
 125 # Find the tools directory,
 126 # try from Makefile (not run by Qt Creator),
 127 TOOLS_DIR = $$(TOOLS_DIR)
 128 isEmpty(TOOLS_DIR) {
 129     # check for custom enviroment variable,
 130     TOOLS_DIR = $$(OPENPILOT_TOOLS_DIR)
 131     # fallback to default location.
 132     isEmpty(TOOLS_DIR):TOOLS_DIR = $$clean_path($$ROOT_DIR/tools)
 133 }
 134
 135 GCS_APP_PATH = $$GCS_BUILD_TREE/bin
 136 macx {
 137     GCS_APP_TARGET   = "OpenPilot GCS"
 138     GCS_LIBRARY_PATH = $$GCS_APP_PATH/$${GCS_APP_TARGET}.app/Contents/Plugins
 139     GCS_PLUGIN_PATH  = $$GCS_LIBRARY_PATH
 140     GCS_QT_QML_PATH = $$GCS_APP_PATH/$${GCS_APP_TARGET}.app/Contents/Imports
 141     GCS_LIBEXEC_PATH = $$GCS_APP_PATH/$${GCS_APP_TARGET}.app/Contents/Resources
 142     GCS_DATA_PATH    = $$GCS_APP_PATH/$${GCS_APP_TARGET}.app/Contents/Resources
 143     GCS_DATA_BASENAME = Resources
 144     GCS_DOC_PATH     = $$GCS_DATA_PATH/doc
 145     copydata = 1
 146     copyqt = 1
 147 } else {
 148     GCS_LIBRARY_PATH = $$GCS_BUILD_TREE/$$GCS_LIBRARY_BASENAME/openpilotgcs
 149     GCS_PLUGIN_PATH  = $$GCS_LIBRARY_PATH/plugins
 150     GCS_LIBEXEC_PATH = $$GCS_APP_PATH # FIXME
 151     GCS_DATA_PATH    = $$GCS_BUILD_TREE/share/openpilotgcs
 152     GCS_DATA_BASENAME = share/openpilotgcs
 153     GCS_DOC_PATH     = $$GCS_BUILD_TREE/share/doc
 154
 155     !isEqual(GCS_SOURCE_TREE, $$GCS_BUILD_TREE):copydata = 1
 156
 157     win32 {
 158         SDL_DIR = $$(SDL_DIR)
 159         isEmpty(SDL_DIR):SDL_DIR = $${TOOLS_DIR}/SDL-1.2.15
 160
 161         OPENSSL_DIR = $$(OPENSSL_DIR)
 162         isEmpty(OPENSSL_DIR):OPENSSL_DIR = $${TOOLS_DIR}/openssl-1.0.1e-win32
 163
 164         MESAWIN_DIR = $$(MESAWIN_DIR)
 165         isEmpty(MESAWIN_DIR):MESAWIN_DIR = $${TOOLS_DIR}/mesawin
 166
 167         GCS_APP_TARGET   = openpilotgcs
 168
 169         GCS_QT_PLUGINS_PATH = $$GCS_APP_PATH
 170         GCS_QT_QML_PATH = $$GCS_APP_PATH
 171
 172         copyqt = $$copydata
 173     } else {
 174         GCS_APP_TARGET   = openpilotgcs
 175         GCS_QT_BASEPATH = $$GCS_LIBRARY_PATH/qt5
 176         GCS_QT_LIBRARY_PATH = $$GCS_QT_BASEPATH/lib
 177         GCS_QT_PLUGINS_PATH = $$GCS_QT_BASEPATH/plugins
 178         GCS_QT_QML_PATH = $$GCS_QT_BASEPATH/qml
 179
 180         QT_INSTALL_DIR = $$clean_path($$[QT_INSTALL_LIBS]/../../../..)
 181         equals(QT_INSTALL_DIR, $$TOOLS_DIR) {
 182             copyqt = 1
 183         } else {
 184             copyqt = 0
 185         }
 186     }
 187 }
 188
 189
 190 DEFINES += GCS_DATA_BASENAME=\\\"$$GCS_DATA_BASENAME\\\"
 191
 192
 193 INCLUDEPATH += \
 194     $$GCS_SOURCE_TREE/src/libs
 195
 196 DEPENDPATH += \
 197     $$GCS_SOURCE_TREE/src/libs
 198
 199 LIBS += -L$$GCS_LIBRARY_PATH
 200
 201 # DEFINES += QT_NO_CAST_FROM_ASCII
 202 DEFINES += QT_NO_CAST_TO_ASCII
 203 #DEFINES += QT_USE_FAST_OPERATOR_PLUS
 204 #DEFINES += QT_USE_FAST_CONCATENATION
 205
 206 unix {
 207     CONFIG(debug, debug|release):OBJECTS_DIR = $${OUT_PWD}/.obj/debug-shared
 208     CONFIG(release, debug|release):OBJECTS_DIR = $${OUT_PWD}/.obj/release-shared
 209
 210     CONFIG(debug, debug|release):MOC_DIR = $${OUT_PWD}/.moc/debug-shared
 211     CONFIG(release, debug|release):MOC_DIR = $${OUT_PWD}/.moc/release-shared
 212
 213     RCC_DIR = $${OUT_PWD}/.rcc
 214     UI_DIR = $${OUT_PWD}/.uic
 215 }
 216
 217 linux-g++-* {
 218     # Bail out on non-selfcontained libraries. Just a security measure
 219     # to prevent checking in code that does not compile on other platforms.
 220     QMAKE_LFLAGS += -Wl,--allow-shlib-undefined -Wl,--no-undefined
 221 }
 222
 223 win32 {
 224     # Fix ((packed)) pragma handling issue introduced when upgrading MinGW from 4.4 to 4.8
 225     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=52991
 226     # The ((packet)) pragma is used in uav metadata struct and other places
 227     QMAKE_CXXFLAGS += -mno-ms-bitfields
 228 }