src/admin/meson.build

   1 admin_driver_sources = [
   2   'admin_server.c',
   3   'admin_server_dispatch.c',
   4 ]
   5
   6 admin_driver_protocol = files('admin_protocol.x')
   7
   8 rpc_probe_files += admin_driver_protocol
   9
  10 admin_driver_generated = []
  11
  12 admin_protocol_h = custom_target(
  13   'admin_protocol.h',
  14   input: admin_driver_protocol,
  15   output: 'admin_protocol.h',
  16   depend_files: rpcgen_src,
  17   command: [
  18     rpcgen_prog,
  19     '--mode=header', '@INPUT@', '@OUTPUT@',
  20   ],
  21 )
  22 admin_driver_generated += admin_protocol_h
  23
  24 admin_driver_generated += custom_target(
  25   'admin_protocol.c',
  26   input: admin_driver_protocol,
  27   output: 'admin_protocol.c',
  28   depend_files: rpcgen_src,
  29   command: [
  30     rpcgen_prog,
  31     '--mode=source', '--header=admin_protocol.h', '@INPUT@', '@OUTPUT@',
  32   ],
  33 )
  34
  35 admin_driver_generated += custom_target(
  36   'admin_server_dispatch_stubs.h',
  37   input: admin_driver_protocol,
  38   output: 'admin_server_dispatch_stubs.h',
  39   command: [
  40     gendispatch_prog, '--mode=server', 'admin', 'ADMIN', '@INPUT@',
  41   ],
  42   capture: true,
  43 )
  44
  45 admin_sources = files(
  46   'libvirt-admin.c',
  47 )
  48
  49 admin_client_generated = custom_target(
  50   'admin_client.h',
  51   input: admin_driver_protocol,
  52   output: 'admin_client.h',
  53   command: [
  54     gendispatch_prog, '--mode=client', 'admin', 'ADMIN', '@INPUT@',
  55   ],
  56   capture: true,
  57 )
  58
  59 libvirt_admin_public_syms = files(
  60   'libvirt_admin_public.syms',
  61 )
  62
  63 libvirt_admin_private_syms = files(
  64   'libvirt_admin_private.syms',
  65 )
  66
  67 libvirt_admin_syms = custom_target(
  68   'libvirt_admin.syms',
  69   input: [
  70     libvirt_admin_public_syms,
  71     libvirt_admin_private_syms,
  72   ],
  73   output: 'libvirt_admin.syms',
  74   command: [
  75     meson_gen_sym_prog,
  76     '@OUTPUT@', 'LIBVIRT_ADMIN_PRIVATE_' + meson.project_version(), '@INPUT@',
  77   ],
  78 )
  79
  80 if host_machine.system() == 'windows'
  81   libvirt_admin_def = custom_target(
  82     'libvirt_admin.def',
  83     input: libvirt_admin_syms,
  84     output: 'libvirt_admin.def',
  85     command: [
  86       meson_gen_def_prog,
  87       '@INPUT@', '@OUTPUT@',
  88     ],
  89   )
  90   libvirt_admin_syms_file = libvirt_admin_def
  91   libvirt_admin_syms_path = libvirt_admin_syms_file.full_path()
  92 else
  93   libvirt_admin_syms_file = libvirt_admin_syms
  94   libvirt_admin_syms_path = libvirt_admin_syms_file.full_path()
  95 endif
  96
  97 libvirt_admin_link_args = [
  98   libvirt_nodelete,
  99 ]
 100 libvirt_admin_link_depends = []
 101
 102 if version_script_flags != ''
 103   libvirt_admin_link_args += '@0@@1@'.format(
 104     version_script_flags,
 105     libvirt_admin_syms_path,
 106   )
 107   libvirt_admin_link_depends += libvirt_admin_syms_file
 108 endif
 109
 110 if conf.has('WITH_REMOTE')
 111   admin_driver_lib = static_library(
 112     'virt_admin_driver',
 113     [
 114       admin_driver_sources,
 115       admin_driver_generated,
 116     ],
 117     dependencies: [
 118       rpc_dep,
 119       sasl_dep,
 120       src_dep,
 121       xdr_dep,
 122     ],
 123   )
 124
 125   check_protocols += {
 126     'name': 'admin_protocol',
 127     'lib': admin_driver_lib,
 128   }
 129 endif
 130
 131 virt_conf_files += files('libvirt-admin.conf')
 132
 133 admin_inc_dir = include_directories('.')
 134
 135 admin_dep = declare_dependency(
 136   include_directories: admin_inc_dir,
 137   sources: [ admin_protocol_h ],
 138 )