arch/arm/include/asm/assembler.h

   1 /*
   2  *  arch/arm/include/asm/assembler.h
   3  *
   4  *  Copyright (C) 1996-2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  This file contains arm architecture specific defines
  11  *  for the different processors.
  12  *
  13  *  Do not include any C declarations in this file - it is included by
  14  *  assembler source.
  15  */
  16 #ifndef __ASSEMBLY__
  17 #error "Only include this from assembly code"
  18 #endif
  19
  20 #include <asm/ptrace.h>
  21
  22 /*
  23  * Endian independent macros for shifting bytes within registers.
  24  */
  25 #ifndef __ARMEB__
  26 #define pull            lsr
  27 #define push            lsl
  28 #define get_byte_0      lsl #0
  29 #define get_byte_1      lsr #8
  30 #define get_byte_2      lsr #16
  31 #define get_byte_3      lsr #24
  32 #define put_byte_0      lsl #0
  33 #define put_byte_1      lsl #8
  34 #define put_byte_2      lsl #16
  35 #define put_byte_3      lsl #24
  36 #else
  37 #define pull            lsl
  38 #define push            lsr
  39 #define get_byte_0      lsr #24
  40 #define get_byte_1      lsr #16
  41 #define get_byte_2      lsr #8
  42 #define get_byte_3      lsl #0
  43 #define put_byte_0      lsl #24
  44 #define put_byte_1      lsl #16
  45 #define put_byte_2      lsl #8
  46 #define put_byte_3      lsl #0
  47 #endif
  48
  49 /*
  50  * Data preload for architectures that support it
  51  */
  52 #if __LINUX_ARM_ARCH__ >= 5
  53 #define PLD(code...)    code
  54 #else
  55 #define PLD(code...)
  56 #endif
  57
  58 /*
  59  * This can be used to enable code to cacheline align the destination
  60  * pointer when bulk writing to memory.  Experiments on StrongARM and
  61  * XScale didn't show this a worthwhile thing to do when the cache is not
  62  * set to write-allocate (this would need further testing on XScale when WA
  63  * is used).
  64  *
  65  * On Feroceon there is much to gain however, regardless of cache mode.
  66  */
  67 #ifdef CONFIG_CPU_FEROCEON
  68 #define CALGN(code...) code
  69 #else
  70 #define CALGN(code...)
  71 #endif
  72
  73 /*
  74  * Enable and disable interrupts
  75  */
  76 #if __LINUX_ARM_ARCH__ >= 6
  77         .macro  disable_irq_notrace
  78         cpsid   i
  79         .endm
  80
  81         .macro  enable_irq_notrace
  82         cpsie   i
  83         .endm
  84 #else
  85         .macro  disable_irq_notrace
  86         msr     cpsr_c, #PSR_I_BIT | SVC_MODE
  87         .endm
  88
  89         .macro  enable_irq_notrace
  90         msr     cpsr_c, #SVC_MODE
  91         .endm
  92 #endif
  93
  94         .macro asm_trace_hardirqs_off
  95 #if defined(CONFIG_TRACE_IRQFLAGS)
  96         stmdb   sp!, {r0-r3, ip, lr}
  97         bl      trace_hardirqs_off
  98         ldmia   sp!, {r0-r3, ip, lr}
  99 #endif
 100         .endm
 101
 102         .macro asm_trace_hardirqs_on_cond, cond
 103 #if defined(CONFIG_TRACE_IRQFLAGS)
 104         /*
 105          * actually the registers should be pushed and pop'd conditionally, but
 106          * after bl the flags are certainly clobbered
 107          */
 108         stmdb   sp!, {r0-r3, ip, lr}
 109         bl\cond trace_hardirqs_on
 110         ldmia   sp!, {r0-r3, ip, lr}
 111 #endif
 112         .endm
 113
 114         .macro asm_trace_hardirqs_on
 115         asm_trace_hardirqs_on_cond al
 116         .endm
 117
 118         .macro disable_irq
 119         disable_irq_notrace
 120         asm_trace_hardirqs_off
 121         .endm
 122
 123         .macro enable_irq
 124         asm_trace_hardirqs_on
 125         enable_irq_notrace
 126         .endm
 127 /*
 128  * Save the current IRQ state and disable IRQs.  Note that this macro
 129  * assumes FIQs are enabled, and that the processor is in SVC mode.
 130  */
 131         .macro  save_and_disable_irqs, oldcpsr
 132         mrs     \oldcpsr, cpsr
 133         disable_irq
 134         .endm
 135
 136         .macro  save_and_disable_irqs_notrace, oldcpsr
 137         mrs     \oldcpsr, cpsr
 138         disable_irq_notrace
 139         .endm
 140
 141 /*
 142  * Restore interrupt state previously stored in a register.  We don't
 143  * guarantee that this will preserve the flags.
 144  */
 145         .macro  restore_irqs_notrace, oldcpsr
 146         msr     cpsr_c, \oldcpsr
 147         .endm
 148
 149         .macro restore_irqs, oldcpsr
 150         tst     \oldcpsr, #PSR_I_BIT
 151         asm_trace_hardirqs_on_cond eq
 152         restore_irqs_notrace \oldcpsr
 153         .endm
 154
 155 #define USER(x...)                              \
 156 9999:   x;                                      \
 157         .section __ex_table,"a";                \
 158         .align  3;                              \
 159         .long   9999b,9001f;                    \
 160         .previous
 161
 162 /*
 163  * SMP data memory barrier
 164  */
 165         .macro  smp_dmb
 166 #ifdef CONFIG_SMP
 167 #if __LINUX_ARM_ARCH__ >= 7
 168         dmb
 169 #elif __LINUX_ARM_ARCH__ == 6
 170         mcr     p15, 0, r0, c7, c10, 5  @ dmb
 171 #endif
 172 #endif
 173         .endm
 174
 175 #ifdef CONFIG_THUMB2_KERNEL
 176         .macro  setmode, mode, reg
 177         mov     \reg, #\mode
 178         msr     cpsr_c, \reg
 179         .endm
 180 #else
 181         .macro  setmode, mode, reg
 182         msr     cpsr_c, #\mode
 183         .endm
 184 #endif
 185
 186 /*
 187  * STRT/LDRT access macros with ARM and Thumb-2 variants
 188  */
 189 #ifdef CONFIG_THUMB2_KERNEL
 190
 191         .macro  usraccoff, instr, reg, ptr, inc, off, cond, abort
 192 9999:
 193         .if     \inc == 1
 194         \instr\cond\()bt \reg, [\ptr, #\off]
 195         .elseif \inc == 4
 196         \instr\cond\()t \reg, [\ptr, #\off]
 197         .else
 198         .error  "Unsupported inc macro argument"
 199         .endif
 200
 201         .section __ex_table,"a"
 202         .align  3
 203         .long   9999b, \abort
 204         .previous
 205         .endm
 206
 207         .macro  usracc, instr, reg, ptr, inc, cond, rept, abort
 208         @ explicit IT instruction needed because of the label
 209         @ introduced by the USER macro
 210         .ifnc   \cond,al
 211         .if     \rept == 1
 212         itt     \cond
 213         .elseif \rept == 2
 214         ittt    \cond
 215         .else
 216         .error  "Unsupported rept macro argument"
 217         .endif
 218         .endif
 219
 220         @ Slightly optimised to avoid incrementing the pointer twice
 221         usraccoff \instr, \reg, \ptr, \inc, 0, \cond, \abort
 222         .if     \rept == 2
 223         usraccoff \instr, \reg, \ptr, \inc, \inc, \cond, \abort
 224         .endif
 225
 226         add\cond \ptr, #\rept * \inc
 227         .endm
 228
 229 #else   /* !CONFIG_THUMB2_KERNEL */
 230
 231         .macro  usracc, instr, reg, ptr, inc, cond, rept, abort
 232         .rept   \rept
 233 9999:
 234         .if     \inc == 1
 235         \instr\cond\()bt \reg, [\ptr], #\inc
 236         .elseif \inc == 4
 237         \instr\cond\()t \reg, [\ptr], #\inc
 238         .else
 239         .error  "Unsupported inc macro argument"
 240         .endif
 241
 242         .section __ex_table,"a"
 243         .align  3
 244         .long   9999b, \abort
 245         .previous
 246         .endr
 247         .endm
 248
 249 #endif  /* CONFIG_THUMB2_KERNEL */
 250
 251         .macro  strusr, reg, ptr, inc, cond=al, rept=1, abort=9001f
 252         usracc  str, \reg, \ptr, \inc, \cond, \rept, \abort
 253         .endm
 254
 255         .macro  ldrusr, reg, ptr, inc, cond=al, rept=1, abort=9001f
 256         usracc  ldr, \reg, \ptr, \inc, \cond, \rept, \abort
 257         .endm