arch/arm/boot/compressed/head-sa1100.S

   1 /*
   2  * linux/arch/arm/boot/compressed/head-sa1100.S
   3  *
   4  * Copyright (C) 1999 Nicolas Pitre <nico@cam.org>
   5  *
   6  * SA1100 specific tweaks.  This is merged into head.S by the linker.
   7  *
   8  */
   9
  10 #include <linux/config.h>
  11 #include <linux/linkage.h>
  12 #include <asm/mach-types.h>
  13
  14                 .section        ".start", "ax"
  15
  16 __SA1100_start:
  17
  18                 @ Preserve r8/r7 i.e. kernel entry values
  19
  20 #if defined(CONFIG_SA1100_GRAPHICSCLIENT) && !defined(CONFIG_ANGELBOOT)
  21                 mov     r7, #MACH_TYPE_GRAPHICSCLIENT
  22                 mov     r8, #0
  23 #endif
  24 #if defined(CONFIG_SA1100_GRAPHICSMASTER) && !defined(CONFIG_ANGELBOOT)
  25                 mov     r7, #MACH_TYPE_GRAPHICSMASTER
  26                 mov     r8, #0
  27 #endif
  28 #if defined(CONFIG_SA1100_ADSBITSY) && !defined(CONFIG_ANGELBOOT)
  29                 mov     r7, #MACH_TYPE_ADSBITSY
  30                 mov     r8, #0
  31 #endif
  32
  33 #ifdef CONFIG_SA1100_COLLIE
  34                 mov     r7, #MACH_TYPE_COLLIE
  35 #endif
  36 #ifdef CONFIG_SA1100_PFS168
  37                 @ REVISIT_PFS168: Temporary until firmware updated to use assigned machine number
  38                 mov     r7, #MACH_TYPE_PFS168
  39 #endif
  40 #ifdef CONFIG_SA1100_SIMPAD
  41                 @ UNTIL we've something like an open bootldr
  42                 mov     r7, #MACH_TYPE_SIMPAD @should be 87
  43 #endif
  44
  45 #ifdef CONFIG_SA1100_VICTOR
  46                 teq     r7, #MACH_TYPE_VICTOR
  47                 bne     10f
  48
  49                 @ Copy cmdline to 0xc0000000
  50                 mov     r1, #0xc0000000
  51                 cmp     r0, #0
  52                 moveq   r2, #0
  53 1:              ldrneb  r2, [r0], #1
  54                 cmpne   r2, #0
  55                 strb    r2, [r1], #1
  56                 bne     1b
  57 10:
  58 #endif
  59
  60                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
  61                 ands    r0, r0, #0x0d
  62                 beq     99f
  63
  64                 @ Data cache might be active.
  65                 @ Be sure to flush kernel binary out of the cache,
  66                 @ whatever state it is, before it is turned off.
  67                 @ This is done by fetching through currently executed
  68                 @ memory to be sure we hit the same cache.
  69                 bic     r2, pc, #0x1f
  70                 add     r3, r2, #0x4000         @ 16 kb is quite enough...
  71 1:              ldr     r0, [r2], #32
  72                 teq     r2, r3
  73                 bne     1b
  74                 mcr     p15, 0, r0, c7, c10, 4  @ drain WB
  75                 mcr     p15, 0, r0, c7, c7, 0   @ flush I & D caches
  76
  77                 @ disabling MMU and caches
  78                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
  79                 bic     r0, r0, #0x0d           @ clear WB, DC, MMU
  80                 bic     r0, r0, #0x1000         @ clear Icache
  81                 mcr     p15, 0, r0, c1, c0, 0
  82 99: