arch/um/kernel/dyn.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2
   3 OUTPUT_FORMAT(ELF_FORMAT)
   4 OUTPUT_ARCH(ELF_ARCH)
   5 ENTRY(_start)
   6 jiffies = jiffies_64;
   7
   8 SECTIONS
   9 {
  10   . = START + SIZEOF_HEADERS;
  11   .interp         : { *(.interp) }
  12   __binary_start = .;
  13   . = ALIGN(4096);              /* Init code and data */
  14   _stext = .;
  15   __init_begin = .;
  16   .init.text : {
  17         _sinittext = .;
  18         *(.init.text)
  19         _einittext = .;
  20   }
  21
  22   . = ALIGN(4096);
  23
  24   /* Read-only sections, merged into text segment: */
  25   .hash           : { *(.hash) }
  26   .dynsym         : { *(.dynsym) }
  27   .dynstr         : { *(.dynstr) }
  28   .gnu.version    : { *(.gnu.version) }
  29   .gnu.version_d  : { *(.gnu.version_d) }
  30   .gnu.version_r  : { *(.gnu.version_r) }
  31   .rel.init       : { *(.rel.init) }
  32   .rela.init      : { *(.rela.init) }
  33   .rel.text       : { *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*) }
  34   .rela.text      : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) }
  35   .rel.fini       : { *(.rel.fini) }
  36   .rela.fini      : { *(.rela.fini) }
  37   .rel.rodata     : { *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*) }
  38   .rela.rodata    : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) }
  39   .rel.data       : { *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*) }
  40   .rela.data      : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) }
  41   .rel.tdata      : { *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*) }
  42   .rela.tdata     : { *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*) }
  43   .rel.tbss       : { *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*) }
  44   .rela.tbss      : { *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*) }
  45   .rel.ctors      : { *(.rel.ctors) }
  46   .rela.ctors     : { *(.rela.ctors) }
  47   .rel.dtors      : { *(.rel.dtors) }
  48   .rela.dtors     : { *(.rela.dtors) }
  49   .rel.got        : { *(.rel.got) }
  50   .rela.got       : { *(.rela.got) }
  51   .rel.bss        : { *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*) }
  52   .rela.bss       : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) }
  53   .rel.plt        : { *(.rel.plt) }
  54   .rela.plt       : { *(.rela.plt) }
  55   .init           : {
  56     KEEP (*(.init))
  57   } =0x90909090
  58   .plt            : { *(.plt) }
  59   .text           : {
  60     *(.text)
  61     SCHED_TEXT
  62     *(.stub .text.* .gnu.linkonce.t.*)
  63     /* .gnu.warning sections are handled specially by elf32.em.  */
  64     *(.gnu.warning)
  65   } =0x90909090
  66   .fini           : {
  67     KEEP (*(.fini))
  68   } =0x90909090
  69
  70   .kstrtab : { *(.kstrtab) }
  71
  72   #include "asm/common.lds.S"
  73
  74   init.data : { *(.init.data) }
  75
  76   /* Ensure the __preinit_array_start label is properly aligned.  We
  77      could instead move the label definition inside the section, but
  78      the linker would then create the section even if it turns out to
  79      be empty, which isn't pretty.  */
  80   . = ALIGN(32 / 8);
  81   .preinit_array     : { *(.preinit_array) }
  82   .init_array     : { *(.init_array) }
  83   .fini_array     : { *(.fini_array) }
  84   .data           : {
  85     . = ALIGN(KERNEL_STACK_SIZE);               /* init_task */
  86     *(.data.init_task)
  87     *(.data .data.* .gnu.linkonce.d.*)
  88     SORT(CONSTRUCTORS)
  89   }
  90   .data1          : { *(.data1) }
  91   .tdata          : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
  92   .tbss           : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
  93   .eh_frame       : { KEEP (*(.eh_frame)) }
  94   .gcc_except_table   : { *(.gcc_except_table) }
  95   .dynamic        : { *(.dynamic) }
  96   .ctors          : {
  97     /* gcc uses crtbegin.o to find the start of
  98        the constructors, so we make sure it is
  99        first.  Because this is a wildcard, it
 100        doesn't matter if the user does not
 101        actually link against crtbegin.o; the
 102        linker won't look for a file to match a
 103        wildcard.  The wildcard also means that it
 104        doesn't matter which directory crtbegin.o
 105        is in.  */
 106     KEEP (*crtbegin.o(.ctors))
 107     /* We don't want to include the .ctor section from
 108        from the crtend.o file until after the sorted ctors.
 109        The .ctor section from the crtend file contains the
 110        end of ctors marker and it must be last */
 111     KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
 112     KEEP (*(SORT(.ctors.*)))
 113     KEEP (*(.ctors))
 114   }
 115   .dtors          : {
 116     KEEP (*crtbegin.o(.dtors))
 117     KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
 118     KEEP (*(SORT(.dtors.*)))
 119     KEEP (*(.dtors))
 120   }
 121   .jcr            : { KEEP (*(.jcr)) }
 122   .got            : { *(.got.plt) *(.got) }
 123   _edata = .;
 124   PROVIDE (edata = .);
 125   __bss_start = .;
 126   .bss            : {
 127    *(.dynbss)
 128    *(.bss .bss.* .gnu.linkonce.b.*)
 129    *(COMMON)
 130    /* Align here to ensure that the .bss section occupies space up to
 131       _end.  Align after .bss to ensure correct alignment even if the
 132       .bss section disappears because there are no input sections.  */
 133    . = ALIGN(32 / 8);
 134   . = ALIGN(32 / 8);
 135   }
 136   _end = .;
 137   PROVIDE (end = .);
 138    /* Stabs debugging sections.  */
 139   .stab          0 : { *(.stab) }
 140   .stabstr       0 : { *(.stabstr) }
 141   .stab.excl     0 : { *(.stab.excl) }
 142   .stab.exclstr  0 : { *(.stab.exclstr) }
 143   .stab.index    0 : { *(.stab.index) }
 144   .stab.indexstr 0 : { *(.stab.indexstr) }
 145   .comment       0 : { *(.comment) }
 146   /* DWARF debug sections.
 147      Symbols in the DWARF debugging sections are relative to the beginning
 148      of the section so we begin them at 0.  */
 149   /* DWARF 1 */
 150   .debug          0 : { *(.debug) }
 151   .line           0 : { *(.line) }
 152   /* GNU DWARF 1 extensions */
 153   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 154   .debug_sfnames  0 : { *(.debug_sfnames) }
 155   /* DWARF 1.1 and DWARF 2 */
 156   .debug_aranges  0 : { *(.debug_aranges) }
 157   .debug_pubnames 0 : { *(.debug_pubnames) }
 158   /* DWARF 2 */
 159   .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
 160   .debug_abbrev   0 : { *(.debug_abbrev) }
 161   .debug_line     0 : { *(.debug_line) }
 162   .debug_frame    0 : { *(.debug_frame) }
 163   .debug_str      0 : { *(.debug_str) }
 164   .debug_loc      0 : { *(.debug_loc) }
 165   .debug_macinfo  0 : { *(.debug_macinfo) }
 166   /* SGI/MIPS DWARF 2 extensions */
 167   .debug_weaknames 0 : { *(.debug_weaknames) }
 168   .debug_funcnames 0 : { *(.debug_funcnames) }
 169   .debug_typenames 0 : { *(.debug_typenames) }
 170   .debug_varnames  0 : { *(.debug_varnames) }
 171 }