include/asm-parisc/assembly.h

   1 /*
   2  * Copyright (C) 1999 Hewlett-Packard (Frank Rowand)
   3  * Copyright (C) 1999 Philipp Rumpf <prumpf@tux.org>
   4  * Copyright (C) 1999 SuSE GmbH
   5  *
   6  *    This program is free software; you can redistribute it and/or modify
   7  *    it under the terms of the GNU General Public License as published by
   8  *    the Free Software Foundation; either version 2, or (at your option)
   9  *    any later version.
  10  *
  11  *    This program is distributed in the hope that it will be useful,
  12  *    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  *    GNU General Public License for more details.
  15  *
  16  *    You should have received a copy of the GNU General Public License
  17  *    along with this program; if not, write to the Free Software
  18  *    Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  19  */
  20
  21 #ifndef _PARISC_ASSEMBLY_H
  22 #define _PARISC_ASSEMBLY_H
  23
  24 #ifdef __LP64__
  25 #define LDREG   ldd
  26 #define STREG   std
  27 #define LDREGX  ldd,s
  28 #define LDREGM  ldd,mb
  29 #define STREGM  std,ma
  30 #define RP_OFFSET       16
  31 #define FRAME_SIZE      128
  32 #else
  33 #define LDREG   ldw
  34 #define STREG   stw
  35 #define LDREGX  ldwx,s
  36 #define LDREGM  ldwm
  37 #define STREGM  stwm
  38 #define RP_OFFSET       20
  39 #define FRAME_SIZE      64
  40 #endif
  41
  42 #ifdef CONFIG_PA20
  43 #define BL              b,l
  44 #else
  45 #define BL              bl
  46 #endif
  47
  48 #ifdef __ASSEMBLY__
  49
  50 #ifdef __LP64__
  51 /* the 64-bit pa gnu assembler unfortunately defaults to .level 1.1 or 2.0 so
  52  * work around that for now... */
  53         .level 2.0w
  54 #endif
  55
  56 #include <asm/offsets.h>
  57 #include <asm/page.h>
  58
  59 #include <asm/asmregs.h>
  60
  61         sp      =       30
  62         gp      =       27
  63         ipsw    =       22
  64
  65         /*
  66          * We provide two versions of each macro to convert from physical
  67          * to virtual and vice versa. The "_r1" versions take one argument
  68          * register, but trashes r1 to do the conversion. The other
  69          * version takes two arguments: a src and destination register.
  70          * However, the source and destination registers can not be
  71          * the same register.
  72          */
  73
  74         .macro  tophys  grvirt, grphys
  75         ldil    L%(__PAGE_OFFSET), \grphys
  76         sub     \grvirt, \grphys, \grphys
  77         .endm
  78
  79         .macro  tovirt  grphys, grvirt
  80         ldil    L%(__PAGE_OFFSET), \grvirt
  81         add     \grphys, \grvirt, \grvirt
  82         .endm
  83
  84         .macro  tophys_r1  gr
  85         ldil    L%(__PAGE_OFFSET), %r1
  86         sub     \gr, %r1, \gr
  87         .endm
  88
  89         .macro  tovirt_r1  gr
  90         ldil    L%(__PAGE_OFFSET), %r1
  91         add     \gr, %r1, \gr
  92         .endm
  93
  94         .macro delay value
  95         ldil    L%\value, 1
  96         ldo     R%\value(1), 1
  97         addib,UV,n -1,1,.
  98         addib,NUV,n -1,1,.+8
  99         nop
 100         .endm
 101
 102         .macro  debug value
 103         .endm
 104
 105
 106         /* Shift Left - note the r and t can NOT be the same! */
 107         .macro shl r, sa, t
 108         dep,z   \r, 31-\sa, 32-\sa, \t
 109         .endm
 110
 111         /* The PA 2.0 shift left */
 112         .macro shlw r, sa, t
 113         depw,z  \r, 31-\sa, 32-\sa, \t
 114         .endm
 115
 116         /* And the PA 2.0W shift left */
 117         .macro shld r, sa, t
 118         depd,z  \r, 63-\sa, 64-\sa, \t
 119         .endm
 120
 121         /* Shift Right - note the r and t can NOT be the same! */
 122         .macro shr r, sa, t
 123         extru \r, 31-\sa, 32-\sa, \t
 124         .endm
 125
 126         /* pa20w version of shift right */
 127         .macro shrd r, sa, t
 128         extrd,u \r, 63-\sa, 64-\sa, \t
 129         .endm
 130
 131         /* load 32-bit 'value' into 'reg' compensating for the ldil
 132          * sign-extension when running in wide mode.
 133          * WARNING!! neither 'value' nor 'reg' can be expressions
 134          * containing '.'!!!! */
 135         .macro  load32 value, reg
 136         ldil    L%\value, \reg
 137         ldo     R%\value(\reg), \reg
 138         .endm
 139
 140         .macro loadgp
 141 #ifdef __LP64__
 142         ldil            L%__gp, %r27
 143         ldo             R%__gp(%r27), %r27
 144 #else
 145         ldil            L%$global$, %r27
 146         ldo             R%$global$(%r27), %r27
 147 #endif
 148         .endm
 149
 150 #define SAVE_SP(r, where) mfsp r, %r1 ! STREG %r1, where
 151 #define REST_SP(r, where) LDREG where, %r1 ! mtsp %r1, r
 152 #define SAVE_CR(r, where) mfctl r, %r1 ! STREG %r1, where
 153 #define REST_CR(r, where) LDREG where, %r1 ! mtctl %r1, r
 154
 155         .macro  save_general    regs
 156         STREG %r1, PT_GR1 (\regs)
 157         STREG %r2, PT_GR2 (\regs)
 158         STREG %r3, PT_GR3 (\regs)
 159         STREG %r4, PT_GR4 (\regs)
 160         STREG %r5, PT_GR5 (\regs)
 161         STREG %r6, PT_GR6 (\regs)
 162         STREG %r7, PT_GR7 (\regs)
 163         STREG %r8, PT_GR8 (\regs)
 164         STREG %r9, PT_GR9 (\regs)
 165         STREG %r10, PT_GR10(\regs)
 166         STREG %r11, PT_GR11(\regs)
 167         STREG %r12, PT_GR12(\regs)
 168         STREG %r13, PT_GR13(\regs)
 169         STREG %r14, PT_GR14(\regs)
 170         STREG %r15, PT_GR15(\regs)
 171         STREG %r16, PT_GR16(\regs)
 172         STREG %r17, PT_GR17(\regs)
 173         STREG %r18, PT_GR18(\regs)
 174         STREG %r19, PT_GR19(\regs)
 175         STREG %r20, PT_GR20(\regs)
 176         STREG %r21, PT_GR21(\regs)
 177         STREG %r22, PT_GR22(\regs)
 178         STREG %r23, PT_GR23(\regs)
 179         STREG %r24, PT_GR24(\regs)
 180         STREG %r25, PT_GR25(\regs)
 181         /* r26 is saved in get_stack and used to preserve a value across virt_map */
 182         STREG %r27, PT_GR27(\regs)
 183         STREG %r28, PT_GR28(\regs)
 184         /* r29 is saved in get_stack and used to point to saved registers */
 185         /* r30 stack pointer saved in get_stack */
 186         STREG %r31, PT_GR31(\regs)
 187         .endm
 188
 189         .macro  rest_general    regs
 190         /* r1 used as a temp in rest_stack and is restored there */
 191         LDREG PT_GR2 (\regs), %r2
 192         LDREG PT_GR3 (\regs), %r3
 193         LDREG PT_GR4 (\regs), %r4
 194         LDREG PT_GR5 (\regs), %r5
 195         LDREG PT_GR6 (\regs), %r6
 196         LDREG PT_GR7 (\regs), %r7
 197         LDREG PT_GR8 (\regs), %r8
 198         LDREG PT_GR9 (\regs), %r9
 199         LDREG PT_GR10(\regs), %r10
 200         LDREG PT_GR11(\regs), %r11
 201         LDREG PT_GR12(\regs), %r12
 202         LDREG PT_GR13(\regs), %r13
 203         LDREG PT_GR14(\regs), %r14
 204         LDREG PT_GR15(\regs), %r15
 205         LDREG PT_GR16(\regs), %r16
 206         LDREG PT_GR17(\regs), %r17
 207         LDREG PT_GR18(\regs), %r18
 208         LDREG PT_GR19(\regs), %r19
 209         LDREG PT_GR20(\regs), %r20
 210         LDREG PT_GR21(\regs), %r21
 211         LDREG PT_GR22(\regs), %r22
 212         LDREG PT_GR23(\regs), %r23
 213         LDREG PT_GR24(\regs), %r24
 214         LDREG PT_GR25(\regs), %r25
 215         LDREG PT_GR26(\regs), %r26
 216         LDREG PT_GR27(\regs), %r27
 217         LDREG PT_GR28(\regs), %r28
 218         /* r29 points to register save area, and is restored in rest_stack */
 219         /* r30 stack pointer restored in rest_stack */
 220         LDREG PT_GR31(\regs), %r31
 221         .endm
 222
 223         .macro  save_fp         regs
 224         fstd,ma  %fr0, 8(\regs)
 225         fstd,ma  %fr1, 8(\regs)
 226         fstd,ma  %fr2, 8(\regs)
 227         fstd,ma  %fr3, 8(\regs)
 228         fstd,ma  %fr4, 8(\regs)
 229         fstd,ma  %fr5, 8(\regs)
 230         fstd,ma  %fr6, 8(\regs)
 231         fstd,ma  %fr7, 8(\regs)
 232         fstd,ma  %fr8, 8(\regs)
 233         fstd,ma  %fr9, 8(\regs)
 234         fstd,ma %fr10, 8(\regs)
 235         fstd,ma %fr11, 8(\regs)
 236         fstd,ma %fr12, 8(\regs)
 237         fstd,ma %fr13, 8(\regs)
 238         fstd,ma %fr14, 8(\regs)
 239         fstd,ma %fr15, 8(\regs)
 240         fstd,ma %fr16, 8(\regs)
 241         fstd,ma %fr17, 8(\regs)
 242         fstd,ma %fr18, 8(\regs)
 243         fstd,ma %fr19, 8(\regs)
 244         fstd,ma %fr20, 8(\regs)
 245         fstd,ma %fr21, 8(\regs)
 246         fstd,ma %fr22, 8(\regs)
 247         fstd,ma %fr23, 8(\regs)
 248         fstd,ma %fr24, 8(\regs)
 249         fstd,ma %fr25, 8(\regs)
 250         fstd,ma %fr26, 8(\regs)
 251         fstd,ma %fr27, 8(\regs)
 252         fstd,ma %fr28, 8(\regs)
 253         fstd,ma %fr29, 8(\regs)
 254         fstd,ma %fr30, 8(\regs)
 255         fstd    %fr31, 0(\regs)
 256         .endm
 257
 258         .macro  rest_fp         regs
 259         fldd    0(\regs),        %fr31
 260         fldd,mb -8(\regs),       %fr30
 261         fldd,mb -8(\regs),       %fr29
 262         fldd,mb -8(\regs),       %fr28
 263         fldd,mb -8(\regs),       %fr27
 264         fldd,mb -8(\regs),       %fr26
 265         fldd,mb -8(\regs),       %fr25
 266         fldd,mb -8(\regs),       %fr24
 267         fldd,mb -8(\regs),       %fr23
 268         fldd,mb -8(\regs),       %fr22
 269         fldd,mb -8(\regs),       %fr21
 270         fldd,mb -8(\regs),       %fr20
 271         fldd,mb -8(\regs),       %fr19
 272         fldd,mb -8(\regs),       %fr18
 273         fldd,mb -8(\regs),       %fr17
 274         fldd,mb -8(\regs),       %fr16
 275         fldd,mb -8(\regs),       %fr15
 276         fldd,mb -8(\regs),       %fr14
 277         fldd,mb -8(\regs),       %fr13
 278         fldd,mb -8(\regs),       %fr12
 279         fldd,mb -8(\regs),       %fr11
 280         fldd,mb -8(\regs),       %fr10
 281         fldd,mb -8(\regs),       %fr9
 282         fldd,mb -8(\regs),       %fr8
 283         fldd,mb -8(\regs),       %fr7
 284         fldd,mb -8(\regs),       %fr6
 285         fldd,mb -8(\regs),       %fr5
 286         fldd,mb -8(\regs),       %fr4
 287         fldd,mb -8(\regs),       %fr3
 288         fldd,mb -8(\regs),       %fr2
 289         fldd,mb -8(\regs),       %fr1
 290         fldd,mb -8(\regs),       %fr0
 291         .endm
 292
 293 #ifdef __LP64__
 294         .macro  callee_save
 295         std,ma    %r3,  144(%r30)
 296         mfctl     %cr27, %r3
 297         std       %r4,  -136(%r30)
 298         std       %r5,  -128(%r30)
 299         std       %r6,  -120(%r30)
 300         std       %r7,  -112(%r30)
 301         std       %r8,  -104(%r30)
 302         std       %r9,   -96(%r30)
 303         std      %r10,   -88(%r30)
 304         std      %r11,   -80(%r30)
 305         std      %r12,   -72(%r30)
 306         std      %r13,   -64(%r30)
 307         std      %r14,   -56(%r30)
 308         std      %r15,   -48(%r30)
 309         std      %r16,   -40(%r30)
 310         std      %r17,   -32(%r30)
 311         std      %r18,   -24(%r30)
 312         std       %r3,   -16(%r30)
 313         .endm
 314
 315         .macro  callee_rest
 316         ldd      -16(%r30),    %r3
 317         ldd      -24(%r30),   %r18
 318         ldd      -32(%r30),   %r17
 319         ldd      -40(%r30),   %r16
 320         ldd      -48(%r30),   %r15
 321         ldd      -56(%r30),   %r14
 322         ldd      -64(%r30),   %r13
 323         ldd      -72(%r30),   %r12
 324         ldd      -80(%r30),   %r11
 325         ldd      -88(%r30),   %r10
 326         ldd      -96(%r30),    %r9
 327         ldd     -104(%r30),    %r8
 328         ldd     -112(%r30),    %r7
 329         ldd     -120(%r30),    %r6
 330         ldd     -128(%r30),    %r5
 331         ldd     -136(%r30),    %r4
 332         mtctl   %r3, %cr27
 333         ldd,mb  -144(%r30),    %r3
 334         .endm
 335
 336 #else /* ! __LP64__ */
 337
 338         .macro  callee_save
 339         stw,ma   %r3,   128(%r30)
 340         mfctl    %cr27, %r3
 341         stw      %r4,   -124(%r30)
 342         stw      %r5,   -120(%r30)
 343         stw      %r6,   -116(%r30)
 344         stw      %r7,   -112(%r30)
 345         stw      %r8,   -108(%r30)
 346         stw      %r9,   -104(%r30)
 347         stw      %r10,  -100(%r30)
 348         stw      %r11,   -96(%r30)
 349         stw      %r12,   -92(%r30)
 350         stw      %r13,   -88(%r30)
 351         stw      %r14,   -84(%r30)
 352         stw      %r15,   -80(%r30)
 353         stw      %r16,   -76(%r30)
 354         stw      %r17,   -72(%r30)
 355         stw      %r18,   -68(%r30)
 356         stw       %r3,   -64(%r30)
 357         .endm
 358
 359         .macro  callee_rest
 360         ldw      -64(%r30),    %r3
 361         ldw      -68(%r30),   %r18
 362         ldw      -72(%r30),   %r17
 363         ldw      -76(%r30),   %r16
 364         ldw      -80(%r30),   %r15
 365         ldw      -84(%r30),   %r14
 366         ldw      -88(%r30),   %r13
 367         ldw      -92(%r30),   %r12
 368         ldw      -96(%r30),   %r11
 369         ldw     -100(%r30),   %r10
 370         ldw     -104(%r30),   %r9
 371         ldw     -108(%r30),   %r8
 372         ldw     -112(%r30),   %r7
 373         ldw     -116(%r30),   %r6
 374         ldw     -120(%r30),   %r5
 375         ldw     -124(%r30),   %r4
 376         mtctl   %r3, %cr27
 377         ldw,mb  -128(%r30),   %r3
 378         .endm
 379 #endif /* ! __LP64__ */
 380
 381         .macro  save_specials   regs
 382
 383         SAVE_SP  (%sr0, PT_SR0 (\regs))
 384         SAVE_SP  (%sr1, PT_SR1 (\regs))
 385         SAVE_SP  (%sr2, PT_SR2 (\regs))
 386         SAVE_SP  (%sr3, PT_SR3 (\regs))
 387         SAVE_SP  (%sr4, PT_SR4 (\regs))
 388         SAVE_SP  (%sr5, PT_SR5 (\regs))
 389         SAVE_SP  (%sr6, PT_SR6 (\regs))
 390         SAVE_SP  (%sr7, PT_SR7 (\regs))
 391
 392         SAVE_CR  (%cr17, PT_IASQ0(\regs))
 393         mtctl    %r0,   %cr17
 394         SAVE_CR  (%cr17, PT_IASQ1(\regs))
 395
 396         SAVE_CR  (%cr18, PT_IAOQ0(\regs))
 397         mtctl    %r0,   %cr18
 398         SAVE_CR  (%cr18, PT_IAOQ1(\regs))
 399
 400 #ifdef __LP64__
 401         /* cr11 (sar) is a funny one.  5 bits on PA1.1 and 6 bit on PA2.0
 402          * For PA2.0 mtsar or mtctl always write 6 bits, but mfctl only
 403          * reads 5 bits.  Use mfctl,w to read all six bits.  Otherwise
 404          * we lose the 6th bit on a save/restore over interrupt.
 405          */
 406         mfctl,w  %cr11, %r1
 407         STREG    %r1, PT_SAR (\regs)
 408 #else
 409         SAVE_CR  (%cr11, PT_SAR  (\regs))
 410 #endif
 411         SAVE_CR  (%cr19, PT_IIR  (\regs))
 412
 413         /*
 414          * Code immediately following this macro (in intr_save) relies
 415          * on r8 containing ipsw.
 416          */
 417         mfctl    %cr22, %r8
 418         STREG    %r8,   PT_PSW(\regs)
 419         .endm
 420
 421         .macro  rest_specials   regs
 422
 423         REST_SP  (%sr0, PT_SR0 (\regs))
 424         REST_SP  (%sr1, PT_SR1 (\regs))
 425         REST_SP  (%sr2, PT_SR2 (\regs))
 426         REST_SP  (%sr3, PT_SR3 (\regs))
 427         REST_SP  (%sr4, PT_SR4 (\regs))
 428         REST_SP  (%sr5, PT_SR5 (\regs))
 429         REST_SP  (%sr6, PT_SR6 (\regs))
 430         REST_SP  (%sr7, PT_SR7 (\regs))
 431
 432         REST_CR (%cr17, PT_IASQ0(\regs))
 433         REST_CR (%cr17, PT_IASQ1(\regs))
 434
 435         REST_CR (%cr18, PT_IAOQ0(\regs))
 436         REST_CR (%cr18, PT_IAOQ1(\regs))
 437
 438         REST_CR (%cr11, PT_SAR  (\regs))
 439
 440         REST_CR (%cr22, PT_PSW  (\regs))
 441         .endm
 442
 443 #endif /* __ASSEMBLY__ */
 444 #endif