arch/parisc/kernel/syscall.S

   1 /*
   2  * Linux/PA-RISC Project (http://www.parisc-linux.org/)
   3  *
   4  * System call entry code Copyright (c) Matthew Wilcox 1999 <willy@bofh.ai>
   5  * Licensed under the GNU GPL.
   6  * thanks to Philipp Rumpf, Mike Shaver and various others
   7  * sorry about the wall, puffin..
   8  */
   9
  10 #include <asm/asm-offsets.h>
  11 #include <asm/unistd.h>
  12 #include <asm/errno.h>
  13 #include <asm/page.h>
  14 #include <asm/psw.h>
  15 #include <asm/thread_info.h>
  16 #include <asm/assembly.h>
  17 #include <asm/processor.h>
  18
  19 #include <linux/linkage.h>
  20
  21         /* We fill the empty parts of the gateway page with
  22          * something that will kill the kernel or a
  23          * userspace application.
  24          */
  25 #define KILL_INSN       break   0,0
  26
  27         .level          LEVEL
  28
  29         .text
  30
  31         .import syscall_exit,code
  32         .import syscall_exit_rfi,code
  33
  34         /* Linux gateway page is aliased to virtual page 0 in the kernel
  35          * address space. Since it is a gateway page it cannot be
  36          * dereferenced, so null pointers will still fault. We start
  37          * the actual entry point at 0x100. We put break instructions
  38          * at the beginning of the page to trap null indirect function
  39          * pointers.
  40          */
  41
  42         .align PAGE_SIZE
  43 ENTRY(linux_gateway_page)
  44
  45         /* ADDRESS 0x00 to 0xb0 = 176 bytes / 4 bytes per insn = 44 insns */
  46         .rept 44
  47         KILL_INSN
  48         .endr
  49
  50         /* ADDRESS 0xb0 to 0xb4, lws uses 1 insns for entry */
  51         /* Light-weight-syscall entry must always be located at 0xb0 */
  52         /* WARNING: Keep this number updated with table size changes */
  53 #define __NR_lws_entries (2)
  54
  55 lws_entry:
  56         /* Unconditional branch to lws_start, located on the
  57            same gateway page */
  58         b,n     lws_start
  59
  60         /* Fill from 0xb4 to 0xe0 */
  61         .rept 11
  62         KILL_INSN
  63         .endr
  64
  65         /* This function MUST be located at 0xe0 for glibc's threading
  66         mechanism to work. DO NOT MOVE THIS CODE EVER! */
  67 set_thread_pointer:
  68         gate    .+8, %r0                /* increase privilege */
  69         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  70         be      0(%sr7,%r31)            /* return to user space */
  71         mtctl   %r26, %cr27             /* move arg0 to the control register */
  72
  73         /* Increase the chance of trapping if random jumps occur to this
  74         address, fill from 0xf0 to 0x100 */
  75         .rept 4
  76         KILL_INSN
  77         .endr
  78
  79 /* This address must remain fixed at 0x100 for glibc's syscalls to work */
  80         .align 256
  81 linux_gateway_entry:
  82         gate    .+8, %r0                        /* become privileged */
  83         mtsp    %r0,%sr4                        /* get kernel space into sr4 */
  84         mtsp    %r0,%sr5                        /* get kernel space into sr5 */
  85         mtsp    %r0,%sr6                        /* get kernel space into sr6 */
  86         mfsp    %sr7,%r1                        /* save user sr7 */
  87         mtsp    %r1,%sr3                        /* and store it in sr3 */
  88
  89 #ifdef CONFIG_64BIT
  90         /* for now we can *always* set the W bit on entry to the syscall
  91          * since we don't support wide userland processes.  We could
  92          * also save the current SM other than in r0 and restore it on
  93          * exit from the syscall, and also use that value to know
  94          * whether to do narrow or wide syscalls. -PB
  95          */
  96         ssm     PSW_SM_W, %r1
  97         extrd,u %r1,PSW_W_BIT,1,%r1
  98         /* sp must be aligned on 4, so deposit the W bit setting into
  99          * the bottom of sp temporarily */
 100         or,ev   %r1,%r30,%r30
 101         b,n     1f
 102         /* The top halves of argument registers must be cleared on syscall
 103          * entry from narrow executable.
 104          */
 105         depdi   0, 31, 32, %r26
 106         depdi   0, 31, 32, %r25
 107         depdi   0, 31, 32, %r24
 108         depdi   0, 31, 32, %r23
 109         depdi   0, 31, 32, %r22
 110         depdi   0, 31, 32, %r21
 111 1:
 112 #endif
 113         mfctl   %cr30,%r1
 114         xor     %r1,%r30,%r30                   /* ye olde xor trick */
 115         xor     %r1,%r30,%r1
 116         xor     %r1,%r30,%r30
 117
 118         ldo     THREAD_SZ_ALGN+FRAME_SIZE(%r30),%r30  /* set up kernel stack */
 119
 120         /* N.B.: It is critical that we don't set sr7 to 0 until r30
 121          *       contains a valid kernel stack pointer. It is also
 122          *       critical that we don't start using the kernel stack
 123          *       until after sr7 has been set to 0.
 124          */
 125
 126         mtsp    %r0,%sr7                        /* get kernel space into sr7 */
 127         STREGM  %r1,FRAME_SIZE(%r30)            /* save r1 (usp) here for now */
 128         mfctl   %cr30,%r1                       /* get task ptr in %r1 */
 129         LDREG   TI_TASK(%r1),%r1
 130
 131         /* Save some registers for sigcontext and potential task
 132            switch (see entry.S for the details of which ones are
 133            saved/restored).  TASK_PT_PSW is zeroed so we can see whether
 134            a process is on a syscall or not.  For an interrupt the real
 135            PSW value is stored.  This is needed for gdb and sys_ptrace. */
 136         STREG   %r0,  TASK_PT_PSW(%r1)
 137         STREG   %r2,  TASK_PT_GR2(%r1)          /* preserve rp */
 138         STREG   %r19, TASK_PT_GR19(%r1)
 139
 140         LDREGM  -FRAME_SIZE(%r30), %r2          /* get users sp back */
 141 #ifdef CONFIG_64BIT
 142         extrd,u %r2,63,1,%r19                   /* W hidden in bottom bit */
 143 #if 0
 144         xor     %r19,%r2,%r2                    /* clear bottom bit */
 145         depd,z  %r19,1,1,%r19
 146         std     %r19,TASK_PT_PSW(%r1)
 147 #endif
 148 #endif
 149         STREG   %r2,  TASK_PT_GR30(%r1)         /* ... and save it */
 150
 151         STREG   %r20, TASK_PT_GR20(%r1)         /* Syscall number */
 152         STREG   %r21, TASK_PT_GR21(%r1)
 153         STREG   %r22, TASK_PT_GR22(%r1)
 154         STREG   %r23, TASK_PT_GR23(%r1)         /* 4th argument */
 155         STREG   %r24, TASK_PT_GR24(%r1)         /* 3rd argument */
 156         STREG   %r25, TASK_PT_GR25(%r1)         /* 2nd argument */
 157         STREG   %r26, TASK_PT_GR26(%r1)         /* 1st argument */
 158         STREG   %r27, TASK_PT_GR27(%r1)         /* user dp */
 159         STREG   %r28, TASK_PT_GR28(%r1)         /* return value 0 */
 160         STREG   %r28, TASK_PT_ORIG_R28(%r1)     /* return value 0 (saved for signals) */
 161         STREG   %r29, TASK_PT_GR29(%r1)         /* return value 1 */
 162         STREG   %r31, TASK_PT_GR31(%r1)         /* preserve syscall return ptr */
 163
 164         ldo     TASK_PT_FR0(%r1), %r27          /* save fpregs from the kernel */
 165         save_fp %r27                            /* or potential task switch  */
 166
 167         mfctl   %cr11, %r27                     /* i.e. SAR */
 168         STREG   %r27, TASK_PT_SAR(%r1)
 169
 170         loadgp
 171
 172 #ifdef CONFIG_64BIT
 173         ldo     -16(%r30),%r29                  /* Reference param save area */
 174         copy    %r19,%r2                        /* W bit back to r2 */
 175 #else
 176         /* no need to save these on stack in wide mode because the first 8
 177          * args are passed in registers */
 178         stw     %r22, -52(%r30)                 /* 5th argument */
 179         stw     %r21, -56(%r30)                 /* 6th argument */
 180 #endif
 181
 182         /* Are we being ptraced? */
 183         mfctl   %cr30, %r1
 184         LDREG   TI_TASK(%r1),%r1
 185         ldw     TASK_PTRACE(%r1), %r1
 186         bb,<,n  %r1,31,.Ltracesys
 187
 188         /* Note!  We cannot use the syscall table that is mapped
 189         nearby since the gateway page is mapped execute-only. */
 190
 191 #ifdef CONFIG_64BIT
 192         ldil    L%sys_call_table, %r1
 193         or,=    %r2,%r2,%r2
 194         addil   L%(sys_call_table64-sys_call_table), %r1
 195         ldo     R%sys_call_table(%r1), %r19
 196         or,=    %r2,%r2,%r2
 197         ldo     R%sys_call_table64(%r1), %r19
 198 #else
 199         ldil    L%sys_call_table, %r1
 200         ldo     R%sys_call_table(%r1), %r19
 201 #endif
 202         comiclr,>>      __NR_Linux_syscalls, %r20, %r0
 203         b,n     .Lsyscall_nosys
 204
 205         LDREGX  %r20(%r19), %r19
 206
 207         /* If this is a sys_rt_sigreturn call, and the signal was received
 208          * when not in_syscall, then we want to return via syscall_exit_rfi,
 209          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 210          * trampoline code in signal.c).
 211          */
 212         ldi     __NR_rt_sigreturn,%r2
 213         comb,=  %r2,%r20,.Lrt_sigreturn
 214 .Lin_syscall:
 215         ldil    L%syscall_exit,%r2
 216         be      0(%sr7,%r19)
 217         ldo     R%syscall_exit(%r2),%r2
 218 .Lrt_sigreturn:
 219         comib,<> 0,%r25,.Lin_syscall
 220         ldil    L%syscall_exit_rfi,%r2
 221         be      0(%sr7,%r19)
 222         ldo     R%syscall_exit_rfi(%r2),%r2
 223
 224         /* Note!  Because we are not running where we were linked, any
 225         calls to functions external to this file must be indirect.  To
 226         be safe, we apply the opposite rule to functions within this
 227         file, with local labels given to them to ensure correctness. */
 228
 229 .Lsyscall_nosys:
 230 syscall_nosys:
 231         ldil    L%syscall_exit,%r1
 232         be      R%syscall_exit(%sr7,%r1)
 233         ldo     -ENOSYS(%r0),%r28                  /* set errno */
 234
 235
 236 /* Warning! This trace code is a virtual duplicate of the code above so be
 237  * sure to maintain both! */
 238 .Ltracesys:
 239 tracesys:
 240         /* Need to save more registers so the debugger can see where we
 241          * are.  This saves only the lower 8 bits of PSW, so that the C
 242          * bit is still clear on syscalls, and the D bit is set if this
 243          * full register save path has been executed.  We check the D
 244          * bit on syscall_return_rfi to determine which registers to
 245          * restore.  An interrupt results in a full PSW saved with the
 246          * C bit set, a non-straced syscall entry results in C and D clear
 247          * in the saved PSW.
 248          */
 249         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 250         LDREG   TI_TASK(%r1), %r1
 251         ssm     0,%r2
 252         STREG   %r2,TASK_PT_PSW(%r1)            /* Lower 8 bits only!! */
 253         mfsp    %sr0,%r2
 254         STREG   %r2,TASK_PT_SR0(%r1)
 255         mfsp    %sr1,%r2
 256         STREG   %r2,TASK_PT_SR1(%r1)
 257         mfsp    %sr2,%r2
 258         STREG   %r2,TASK_PT_SR2(%r1)
 259         mfsp    %sr3,%r2
 260         STREG   %r2,TASK_PT_SR3(%r1)
 261         STREG   %r2,TASK_PT_SR4(%r1)
 262         STREG   %r2,TASK_PT_SR5(%r1)
 263         STREG   %r2,TASK_PT_SR6(%r1)
 264         STREG   %r2,TASK_PT_SR7(%r1)
 265         STREG   %r2,TASK_PT_IASQ0(%r1)
 266         STREG   %r2,TASK_PT_IASQ1(%r1)
 267         LDREG   TASK_PT_GR31(%r1),%r2
 268         STREG   %r2,TASK_PT_IAOQ0(%r1)
 269         ldo     4(%r2),%r2
 270         STREG   %r2,TASK_PT_IAOQ1(%r1)
 271         ldo     TASK_REGS(%r1),%r2
 272         /* reg_save %r2 */
 273         STREG   %r3,PT_GR3(%r2)
 274         STREG   %r4,PT_GR4(%r2)
 275         STREG   %r5,PT_GR5(%r2)
 276         STREG   %r6,PT_GR6(%r2)
 277         STREG   %r7,PT_GR7(%r2)
 278         STREG   %r8,PT_GR8(%r2)
 279         STREG   %r9,PT_GR9(%r2)
 280         STREG   %r10,PT_GR10(%r2)
 281         STREG   %r11,PT_GR11(%r2)
 282         STREG   %r12,PT_GR12(%r2)
 283         STREG   %r13,PT_GR13(%r2)
 284         STREG   %r14,PT_GR14(%r2)
 285         STREG   %r15,PT_GR15(%r2)
 286         STREG   %r16,PT_GR16(%r2)
 287         STREG   %r17,PT_GR17(%r2)
 288         STREG   %r18,PT_GR18(%r2)
 289         /* Finished saving things for the debugger */
 290
 291         copy    %r2,%r26
 292         ldil    L%do_syscall_trace_enter,%r1
 293         ldil    L%tracesys_next,%r2
 294         be      R%do_syscall_trace_enter(%sr7,%r1)
 295         ldo     R%tracesys_next(%r2),%r2
 296
 297 tracesys_next:
 298         /* do_syscall_trace_enter either returned the syscallno, or -1L,
 299          *  so we skip restoring the PT_GR20 below, since we pulled it from
 300          *  task->thread.regs.gr[20] above.
 301          */
 302         copy    %ret0,%r20
 303         ldil    L%sys_call_table,%r1
 304         ldo     R%sys_call_table(%r1), %r19
 305
 306         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 307         LDREG   TI_TASK(%r1), %r1
 308         LDREG   TASK_PT_GR26(%r1), %r26         /* Restore the users args */
 309         LDREG   TASK_PT_GR25(%r1), %r25
 310         LDREG   TASK_PT_GR24(%r1), %r24
 311         LDREG   TASK_PT_GR23(%r1), %r23
 312 #ifdef CONFIG_64BIT
 313         LDREG   TASK_PT_GR22(%r1), %r22
 314         LDREG   TASK_PT_GR21(%r1), %r21
 315         ldo     -16(%r30),%r29                  /* Reference param save area */
 316 #endif
 317
 318         comiclr,>>=     __NR_Linux_syscalls, %r20, %r0
 319         b,n     .Lsyscall_nosys
 320
 321         LDREGX  %r20(%r19), %r19
 322
 323         /* If this is a sys_rt_sigreturn call, and the signal was received
 324          * when not in_syscall, then we want to return via syscall_exit_rfi,
 325          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 326          * trampoline code in signal.c).
 327          */
 328         ldi     __NR_rt_sigreturn,%r2
 329         comb,=  %r2,%r20,.Ltrace_rt_sigreturn
 330 .Ltrace_in_syscall:
 331         ldil    L%tracesys_exit,%r2
 332         be      0(%sr7,%r19)
 333         ldo     R%tracesys_exit(%r2),%r2
 334
 335         /* Do *not* call this function on the gateway page, because it
 336         makes a direct call to syscall_trace. */
 337
 338 tracesys_exit:
 339         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 340         LDREG   TI_TASK(%r1), %r1
 341 #ifdef CONFIG_64BIT
 342         ldo     -16(%r30),%r29                  /* Reference param save area */
 343 #endif
 344         ldo     TASK_REGS(%r1),%r26
 345         bl      do_syscall_trace_exit,%r2
 346         STREG   %r28,TASK_PT_GR28(%r1)          /* save return value now */
 347         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 348         LDREG   TI_TASK(%r1), %r1
 349         LDREG   TASK_PT_GR28(%r1), %r28         /* Restore return val. */
 350
 351         ldil    L%syscall_exit,%r1
 352         be,n    R%syscall_exit(%sr7,%r1)
 353
 354 .Ltrace_rt_sigreturn:
 355         comib,<> 0,%r25,.Ltrace_in_syscall
 356         ldil    L%tracesys_sigexit,%r2
 357         be      0(%sr7,%r19)
 358         ldo     R%tracesys_sigexit(%r2),%r2
 359
 360 tracesys_sigexit:
 361         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 362         LDREG   TI_TASK(%r1), %r1
 363 #ifdef CONFIG_64BIT
 364         ldo     -16(%r30),%r29                  /* Reference param save area */
 365 #endif
 366         bl      do_syscall_trace_exit,%r2
 367         ldo     TASK_REGS(%r1),%r26
 368
 369         ldil    L%syscall_exit_rfi,%r1
 370         be,n    R%syscall_exit_rfi(%sr7,%r1)
 371
 372
 373         /*********************************************************
 374                 32/64-bit Light-Weight-Syscall ABI
 375
 376                 * - Indicates a hint for userspace inline asm
 377                 implementations.
 378
 379                 Syscall number (caller-saves)
 380                 - %r20
 381                 * In asm clobber.
 382
 383                 Argument registers (caller-saves)
 384                 - %r26, %r25, %r24, %r23, %r22
 385                 * In asm input.
 386
 387                 Return registers (caller-saves)
 388                 - %r28 (return), %r21 (errno)
 389                 * In asm output.
 390
 391                 Caller-saves registers
 392                 - %r1, %r27, %r29
 393                 - %r2 (return pointer)
 394                 - %r31 (ble link register)
 395                 * In asm clobber.
 396
 397                 Callee-saves registers
 398                 - %r3-%r18
 399                 - %r30 (stack pointer)
 400                 * Not in asm clobber.
 401
 402                 If userspace is 32-bit:
 403                 Callee-saves registers
 404                 - %r19 (32-bit PIC register)
 405
 406                 Differences from 32-bit calling convention:
 407                 - Syscall number in %r20
 408                 - Additional argument register %r22 (arg4)
 409                 - Callee-saves %r19.
 410
 411                 If userspace is 64-bit:
 412                 Callee-saves registers
 413                 - %r27 (64-bit PIC register)
 414
 415                 Differences from 64-bit calling convention:
 416                 - Syscall number in %r20
 417                 - Additional argument register %r22 (arg4)
 418                 - Callee-saves %r27.
 419
 420                 Error codes returned by entry path:
 421
 422                 ENOSYS - r20 was an invalid LWS number.
 423
 424         *********************************************************/
 425 lws_start:
 426         /* Gate and ensure we return to userspace */
 427         gate    .+8, %r0
 428         depi    3, 31, 2, %r31  /* Ensure we return to userspace */
 429
 430 #ifdef CONFIG_64BIT
 431         /* FIXME: If we are a 64-bit kernel just
 432          *        turn this on unconditionally.
 433          */
 434         ssm     PSW_SM_W, %r1
 435         extrd,u %r1,PSW_W_BIT,1,%r1
 436         /* sp must be aligned on 4, so deposit the W bit setting into
 437          * the bottom of sp temporarily */
 438         or,ev   %r1,%r30,%r30
 439
 440         /* Clip LWS number to a 32-bit value always */
 441         depdi   0, 31, 32, %r20
 442 #endif
 443
 444         /* Is the lws entry number valid? */
 445         comiclr,>>=     __NR_lws_entries, %r20, %r0
 446         b,n     lws_exit_nosys
 447
 448         /* WARNING: Trashing sr2 and sr3 */
 449         mfsp    %sr7,%r1                        /* get userspace into sr3 */
 450         mtsp    %r1,%sr3
 451         mtsp    %r0,%sr2                        /* get kernel space into sr2 */
 452
 453         /* Load table start */
 454         ldil    L%lws_table, %r1
 455         ldo     R%lws_table(%r1), %r28  /* Scratch use of r28 */
 456         LDREGX  %r20(%sr2,r28), %r21    /* Scratch use of r21 */
 457
 458         /* Jump to lws, lws table pointers already relocated */
 459         be,n    0(%sr2,%r21)
 460
 461 lws_exit_nosys:
 462         ldo     -ENOSYS(%r0),%r21                  /* set errno */
 463         /* Fall through: Return to userspace */
 464
 465 lws_exit:
 466 #ifdef CONFIG_64BIT
 467         /* decide whether to reset the wide mode bit
 468          *
 469          * For a syscall, the W bit is stored in the lowest bit
 470          * of sp.  Extract it and reset W if it is zero */
 471         extrd,u,*<>     %r30,63,1,%r1
 472         rsm     PSW_SM_W, %r0
 473         /* now reset the lowest bit of sp if it was set */
 474         xor     %r30,%r1,%r30
 475 #endif
 476         be,n    0(%sr3, %r31)
 477
 478
 479
 480         /***************************************************
 481                 Implementing CAS as an atomic operation:
 482
 483                 %r26 - Address to examine
 484                 %r25 - Old value to check (old)
 485                 %r24 - New value to set (new)
 486                 %r28 - Return prev through this register.
 487                 %r21 - Kernel error code
 488
 489                 If debugging is DISabled:
 490
 491                 %r21 has the following meanings:
 492
 493                 EAGAIN - CAS is busy, ldcw failed, try again.
 494                 EFAULT - Read or write failed.
 495
 496                 If debugging is enabled:
 497
 498                 EDEADLOCK - CAS called recursively.
 499                 EAGAIN && r28 == 1 - CAS is busy. Lock contended.
 500                 EAGAIN && r28 == 2 - CAS is busy. ldcw failed.
 501                 EFAULT - Read or write failed.
 502
 503                 Scratch: r20, r28, r1
 504
 505         ****************************************************/
 506
 507         /* Do not enable LWS debugging */
 508 #define ENABLE_LWS_DEBUG 0
 509
 510         /* ELF64 Process entry path */
 511 lws_compare_and_swap64:
 512 #ifdef CONFIG_64BIT
 513         b,n     lws_compare_and_swap
 514 #else
 515         /* If we are not a 64-bit kernel, then we don't
 516          * have 64-bit input registers, and calling
 517          * the 64-bit LWS CAS returns ENOSYS.
 518          */
 519         b,n     lws_exit_nosys
 520 #endif
 521
 522         /* ELF32 Process entry path */
 523 lws_compare_and_swap32:
 524 #ifdef CONFIG_64BIT
 525         /* Clip all the input registers */
 526         depdi   0, 31, 32, %r26
 527         depdi   0, 31, 32, %r25
 528         depdi   0, 31, 32, %r24
 529 #endif
 530
 531 lws_compare_and_swap:
 532 #ifdef CONFIG_SMP
 533         /* Load start of lock table */
 534         ldil    L%lws_lock_start, %r20
 535         ldo     R%lws_lock_start(%r20), %r28
 536
 537         /* Extract four bits from r26 and hash lock (Bits 4-7) */
 538         extru  %r26, 27, 4, %r20
 539
 540         /* Find lock to use, the hash is either one of 0 to
 541            15, multiplied by 16 (keep it 16-byte aligned)
 542            and add to the lock table offset. */
 543         shlw    %r20, 4, %r20
 544         add     %r20, %r28, %r20
 545
 546 # if ENABLE_LWS_DEBUG
 547         /*
 548                 DEBUG, check for deadlock!
 549                 If the thread register values are the same
 550                 then we were the one that locked it last and
 551                 this is a recurisve call that will deadlock.
 552                 We *must* giveup this call and fail.
 553         */
 554         ldw     4(%sr2,%r20), %r28                      /* Load thread register */
 555         /* WARNING: If cr27 cycles to the same value we have problems */
 556         mfctl   %cr27, %r21                             /* Get current thread register */
 557         cmpb,<>,n       %r21, %r28, cas_lock            /* Called recursive? */
 558         b       lws_exit                                /* Return error! */
 559         ldo     -EDEADLOCK(%r0), %r21
 560 cas_lock:
 561         cmpb,=,n        %r0, %r28, cas_nocontend        /* Is nobody using it? */
 562         ldo     1(%r0), %r28                            /* 1st case */
 563         b       lws_exit                                /* Contended... */
 564         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 565 cas_nocontend:
 566 # endif
 567 /* ENABLE_LWS_DEBUG */
 568
 569         LDCW    0(%sr2,%r20), %r28                      /* Try to acquire the lock */
 570         cmpb,<>,n       %r0, %r28, cas_action           /* Did we get it? */
 571 cas_wouldblock:
 572         ldo     2(%r0), %r28                            /* 2nd case */
 573         b       lws_exit                                /* Contended... */
 574         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 575 #endif
 576 /* CONFIG_SMP */
 577
 578         /*
 579                 prev = *addr;
 580                 if ( prev == old )
 581                   *addr = new;
 582                 return prev;
 583         */
 584
 585         /* NOTES:
 586                 This all works becuse intr_do_signal
 587                 and schedule both check the return iasq
 588                 and see that we are on the kernel page
 589                 so this process is never scheduled off
 590                 or is ever sent any signal of any sort,
 591                 thus it is wholly atomic from usrspaces
 592                 perspective
 593         */
 594 cas_action:
 595 #if defined CONFIG_SMP && ENABLE_LWS_DEBUG
 596         /* DEBUG */
 597         mfctl   %cr27, %r1
 598         stw     %r1, 4(%sr2,%r20)
 599 #endif
 600         /* The load and store could fail */
 601 1:      ldw     0(%sr3,%r26), %r28
 602         sub,<>  %r28, %r25, %r0
 603 2:      stw     %r24, 0(%sr3,%r26)
 604 #ifdef CONFIG_SMP
 605         /* Free lock */
 606         stw     %r20, 0(%sr2,%r20)
 607 # if ENABLE_LWS_DEBUG
 608         /* Clear thread register indicator */
 609         stw     %r0, 4(%sr2,%r20)
 610 # endif
 611 #endif
 612         /* Return to userspace, set no error */
 613         b       lws_exit
 614         copy    %r0, %r21
 615
 616 3:
 617         /* Error occured on load or store */
 618 #ifdef CONFIG_SMP
 619         /* Free lock */
 620         stw     %r20, 0(%sr2,%r20)
 621 # if ENABLE_LWS_DEBUG
 622         stw     %r0, 4(%sr2,%r20)
 623 # endif
 624 #endif
 625         b       lws_exit
 626         ldo     -EFAULT(%r0),%r21       /* set errno */
 627         nop
 628         nop
 629         nop
 630         nop
 631
 632         /* Two exception table entries, one for the load,
 633            the other for the store. Either return -EFAULT.
 634            Each of the entries must be relocated. */
 635         .section __ex_table,"aw"
 636         ASM_ULONG_INSN (1b - linux_gateway_page), (3b - linux_gateway_page)
 637         ASM_ULONG_INSN (2b - linux_gateway_page), (3b - linux_gateway_page)
 638         .previous
 639
 640
 641         /* Make sure nothing else is placed on this page */
 642         .align PAGE_SIZE
 643 END(linux_gateway_page)
 644 ENTRY(end_linux_gateway_page)
 645
 646         /* Relocate symbols assuming linux_gateway_page is mapped
 647            to virtual address 0x0 */
 648
 649 #define LWS_ENTRY(_name_) ASM_ULONG_INSN (lws_##_name_ - linux_gateway_page)
 650
 651         .section .rodata,"a"
 652
 653         .align PAGE_SIZE
 654         /* Light-weight-syscall table */
 655         /* Start of lws table. */
 656 ENTRY(lws_table)
 657         LWS_ENTRY(compare_and_swap32)   /* 0 - ELF32 Atomic compare and swap */
 658         LWS_ENTRY(compare_and_swap64)   /* 1 - ELF64 Atomic compare and swap */
 659 END(lws_table)
 660         /* End of lws table */
 661
 662         .align PAGE_SIZE
 663 ENTRY(sys_call_table)
 664 #include "syscall_table.S"
 665 END(sys_call_table)
 666
 667 #ifdef CONFIG_64BIT
 668         .align PAGE_SIZE
 669 ENTRY(sys_call_table64)
 670 #define SYSCALL_TABLE_64BIT
 671 #include "syscall_table.S"
 672 END(sys_call_table64)
 673 #endif
 674
 675 #ifdef CONFIG_SMP
 676         /*
 677                 All light-weight-syscall atomic operations
 678                 will use this set of locks
 679
 680                 NOTE: The lws_lock_start symbol must be
 681                 at least 16-byte aligned for safe use
 682                 with ldcw.
 683         */
 684         .section .data
 685         .align  PAGE_SIZE
 686 ENTRY(lws_lock_start)
 687         /* lws locks */
 688         .rept 16
 689         /* Keep locks aligned at 16-bytes */
 690         .word 1
 691         .word 0
 692         .word 0
 693         .word 0
 694         .endr
 695 END(lws_lock_start)
 696         .previous
 697 #endif
 698 /* CONFIG_SMP for lws_lock_start */
 699
 700 .end
 701
 702