| blob | c13fa8da28c7fbbd7aae0377358e9e10f9babff5 |
1 /*
2 * File: arch/blackfin/mach-common/entry.S
3 * Based on:
4 * Author: Linus Torvalds
5 *
6 * Created: ?
7 * Description: contains the system-call and fault low-level handling routines.
8 * This also contains the timer-interrupt handler, as well as all
9 * interrupts and faults that can result in a task-switch.
10 *
11 * Modified:
12 * Copyright 2004-2006 Analog Devices Inc.
13 *
14 * Bugs: Enter bugs at http://blackfin.uclinux.org/
15 *
16 * This program is free software; you can redistribute it and/or modify
17 * it under the terms of the GNU General Public License as published by
18 * the Free Software Foundation; either version 2 of the License, or
19 * (at your option) any later version.
20 *
21 * This program is distributed in the hope that it will be useful,
22 * but WITHOUT ANY WARRANTY; without even the implied warranty of
23 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
24 * GNU General Public License for more details.
25 *
26 * You should have received a copy of the GNU General Public License
27 * along with this program; if not, see the file COPYING, or write
28 * to the Free Software Foundation, Inc.,
29 * 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
30 */
32 /* NOTE: This code handles signal-recognition, which happens every time
33 * after a timer-interrupt and after each system call.
34 */
36 #include <linux/init.h>
37 #include <linux/linkage.h>
38 #include <linux/unistd.h>
39 #include <asm/blackfin.h>
40 #include <asm/errno.h>
41 #include <asm/fixed_code.h>
42 #include <asm/thread_info.h> /* TIF_NEED_RESCHED */
43 #include <asm/asm-offsets.h>
44 #include <asm/trace.h>
46 #include <asm/context.S>
48 #if defined(CONFIG_BFIN_SCRATCH_REG_RETN)
49 # define EX_SCRATCH_REG RETN
50 #elif defined(CONFIG_BFIN_SCRATCH_REG_RETE)
51 # define EX_SCRATCH_REG RETE
52 #else
53 # define EX_SCRATCH_REG CYCLES
54 #endif
56 #ifdef CONFIG_EXCPT_IRQ_SYSC_L1
57 .section .l1.text
58 #else
59 .text
60 #endif
62 /* Slightly simplified and streamlined entry point for CPLB misses.
63 * This one does not lower the level to IRQ5, and thus can be used to
64 * patch up CPLB misses on the kernel stack.
65 */
66 #if ANOMALY_05000261
67 #define _ex_dviol _ex_workaround_261
68 #define _ex_dmiss _ex_workaround_261
69 #define _ex_dmult _ex_workaround_261
71 ENTRY(_ex_workaround_261)
72 /*
73 * Work around an anomaly: if we see a new DCPLB fault, return
74 * without doing anything. Then, if we get the same fault again,
75 * handle it.
76 */
77 P4 = R7; /* Store EXCAUSE */
78 p5.l = _last_cplb_fault_retx;
79 p5.h = _last_cplb_fault_retx;
80 r7 = [p5];
81 r6 = retx;
82 [p5] = r6;
83 cc = r6 == r7;
84 if !cc jump _bfin_return_from_exception;
85 /* fall through */
86 R7 = P4;
87 R6 = 0x26; /* Data CPLB Miss */
88 cc = R6 == R7;
89 if cc jump _ex_dcplb_miss (BP);
90 R6 = 0x23; /* Data CPLB Miss */
91 cc = R6 == R7;
92 if cc jump _ex_dcplb_viol (BP);
93 /* Handle 0x23 Data CPLB Protection Violation
94 * and Data CPLB Multiple Hits - Linux Trap Zero
95 */
96 jump _ex_trap_c;
97 ENDPROC(_ex_workaround_261)
99 #else
100 #ifdef CONFIG_MPU
101 #define _ex_dviol _ex_dcplb_viol
102 #else
103 #define _ex_dviol _ex_trap_c
104 #endif
105 #define _ex_dmiss _ex_dcplb_miss
106 #define _ex_dmult _ex_trap_c
107 #endif
110 ENTRY(_ex_dcplb_viol)
111 ENTRY(_ex_dcplb_miss)
112 ENTRY(_ex_icplb_miss)
113 (R7:6,P5:4) = [sp++];
114 ASTAT = [sp++];
115 SAVE_ALL_SYS
116 #ifdef CONFIG_MPU
117 /* We must load R1 here, _before_ DEBUG_HWTRACE_SAVE, since that
118 * will change the stack pointer. */
119 R0 = SEQSTAT;
120 R1 = SP;
121 #endif
122 DEBUG_HWTRACE_SAVE(p5, r7)
123 #ifdef CONFIG_MPU
124 sp += -12;
125 call _cplb_hdr;
126 sp += 12;
127 CC = R0 == 0;
128 IF !CC JUMP _handle_bad_cplb;
129 #else
130 call __cplb_hdr;
131 #endif
133 #ifdef CONFIG_DEBUG_DOUBLEFAULT
134 /* While we were processing this, did we double fault? */
135 r7 = SEQSTAT; /* reason code is in bit 5:0 */
136 r6.l = lo(SEQSTAT_EXCAUSE);
137 r6.h = hi(SEQSTAT_EXCAUSE);
138 r7 = r7 & r6;
139 r6 = 0x25;
140 CC = R7 == R6;
141 if CC JUMP _double_fault;
142 #endif
144 DEBUG_HWTRACE_RESTORE(p5, r7)
145 RESTORE_ALL_SYS
146 SP = EX_SCRATCH_REG;
147 rtx;
148 ENDPROC(_ex_icplb_miss)
150 ENTRY(_ex_syscall)
151 raise 15; /* invoked by TRAP #0, for sys call */
152 jump.s _bfin_return_from_exception;
153 ENDPROC(_ex_syscall)
155 ENTRY(_ex_soft_bp)
156 r7 = retx;
157 r7 += -2;
158 retx = r7;
159 jump.s _ex_trap_c;
160 ENDPROC(_ex_soft_bp)
162 ENTRY(_ex_single_step)
163 /* If we just returned from an interrupt, the single step event is
164 for the RTI instruction. */
165 r7 = retx;
166 r6 = reti;
167 cc = r7 == r6;
168 if cc jump _bfin_return_from_exception;
170 #ifdef CONFIG_KGDB
171 /* Don't do single step in hardware exception handler */
172 p5.l = lo(IPEND);
173 p5.h = hi(IPEND);
174 r6 = [p5];
175 cc = bittst(r6, 4);
176 if cc jump _bfin_return_from_exception;
177 cc = bittst(r6, 5);
178 if cc jump _bfin_return_from_exception;
180 /* skip single step if current interrupt priority is higher than
181 * that of the first instruction, from which gdb starts single step */
182 r6 >>= 6;
183 r7 = 10;
184 .Lfind_priority_start:
185 cc = bittst(r6, 0);
186 if cc jump .Lfind_priority_done;
187 r6 >>= 1;
188 r7 += -1;
189 cc = r7 == 0;
190 if cc jump .Lfind_priority_done;
191 jump.s .Lfind_priority_start;
192 .Lfind_priority_done:
193 p4.l = _kgdb_single_step;
194 p4.h = _kgdb_single_step;
195 r6 = [p4];
196 cc = r6 == 0;
197 if cc jump .Ldo_single_step;
198 r6 += -1;
199 cc = r6 < r7;
200 if cc jump 1f;
201 .Ldo_single_step:
202 #else
203 /* If we were in user mode, do the single step normally. */
204 p5.l = lo(IPEND);
205 p5.h = hi(IPEND);
206 r6 = [p5];
207 r7 = 0xffe0 (z);
208 r7 = r7 & r6;
209 cc = r7 == 0;
210 if !cc jump 1f;
211 #endif
213 /* Single stepping only a single instruction, so clear the trace
214 * bit here. */
215 r7 = syscfg;
216 bitclr (r7, 0);
217 syscfg = R7;
218 jump _ex_trap_c;
220 1:
221 /*
222 * We were in an interrupt handler. By convention, all of them save
223 * SYSCFG with their first instruction, so by checking whether our
224 * RETX points at the entry point, we can determine whether to allow
225 * a single step, or whether to clear SYSCFG.
226 *
227 * First, find out the interrupt level and the event vector for it.
228 */
229 p5.l = lo(EVT0);
230 p5.h = hi(EVT0);
231 p5 += -4;
232 2:
233 r7 = rot r7 by -1;
234 p5 += 4;
235 if !cc jump 2b;
237 /* What we actually do is test for the _second_ instruction in the
238 * IRQ handler. That way, if there are insns following the restore
239 * of SYSCFG after leaving the handler, we will not turn off SYSCFG
240 * for them. */
242 r7 = [p5];
243 r7 += 2;
244 r6 = RETX;
245 cc = R7 == R6;
246 if !cc jump _bfin_return_from_exception;
248 r7 = syscfg;
249 bitclr (r7, 0);
250 syscfg = R7;
252 /* Fall through to _bfin_return_from_exception. */
253 ENDPROC(_ex_single_step)
255 ENTRY(_bfin_return_from_exception)
256 #if ANOMALY_05000257
257 R7=LC0;
258 LC0=R7;
259 R7=LC1;
260 LC1=R7;
261 #endif
263 #ifdef CONFIG_DEBUG_DOUBLEFAULT
264 /* While we were processing the current exception,
265 * did we cause another, and double fault?
266 */
267 r7 = SEQSTAT; /* reason code is in bit 5:0 */
268 r6.l = lo(SEQSTAT_EXCAUSE);
269 r6.h = hi(SEQSTAT_EXCAUSE);
270 r7 = r7 & r6;
271 r6 = 0x25;
272 CC = R7 == R6;
273 if CC JUMP _double_fault;
275 /* Did we cause a HW error? */
276 p5.l = lo(ILAT);
277 p5.h = hi(ILAT);
278 r6 = [p5];
279 r7 = 0x20; /* Did I just cause anther HW error? */
280 r7 = r7 & r1;
281 CC = R7 == R6;
282 if CC JUMP _double_fault;
283 #endif
285 (R7:6,P5:4) = [sp++];
286 ASTAT = [sp++];
287 sp = EX_SCRATCH_REG;
288 rtx;
289 ENDPROC(_bfin_return_from_exception)
291 ENTRY(_handle_bad_cplb)
292 DEBUG_HWTRACE_RESTORE(p5, r7)
293 /* To get here, we just tried and failed to change a CPLB
294 * so, handle things in trap_c (C code), by lowering to
295 * IRQ5, just like we normally do. Since this is not a
296 * "normal" return path, we have a do alot of stuff to
297 * the stack to get ready so, we can fall through - we
298 * need to make a CPLB exception look like a normal exception
299 */
301 RESTORE_ALL_SYS
302 [--sp] = ASTAT;
303 [--sp] = (R7:6,P5:4);
305 ENTRY(_ex_replaceable)
306 nop;
308 ENTRY(_ex_trap_c)
309 /* Make sure we are not in a double fault */
310 p4.l = lo(IPEND);
311 p4.h = hi(IPEND);
312 r7 = [p4];
313 CC = BITTST (r7, 5);
314 if CC jump _double_fault;
316 /* Call C code (trap_c) to handle the exception, which most
317 * likely involves sending a signal to the current process.
318 * To avoid double faults, lower our priority to IRQ5 first.
319 */
320 P5.h = _exception_to_level5;
321 P5.l = _exception_to_level5;
322 p4.l = lo(EVT5);
323 p4.h = hi(EVT5);
324 [p4] = p5;
325 csync;
327 #ifndef CONFIG_DEBUG_DOUBLEFAULT
328 /*
329 * Save these registers, as they are only valid in exception context
330 * (where we are now - as soon as we defer to IRQ5, they can change)
331 * DCPLB_STATUS and ICPLB_STATUS are also only valid in EVT3,
332 * but they are not very interesting, so don't save them
333 */
335 p4.l = lo(DCPLB_FAULT_ADDR);
336 p4.h = hi(DCPLB_FAULT_ADDR);
337 r7 = [p4];
338 p5.h = _saved_dcplb_fault_addr;
339 p5.l = _saved_dcplb_fault_addr;
340 [p5] = r7;
342 r7 = [p4 + (ICPLB_FAULT_ADDR - DCPLB_FAULT_ADDR)];
343 p5.h = _saved_icplb_fault_addr;
344 p5.l = _saved_icplb_fault_addr;
345 [p5] = r7;
347 r6 = retx;
348 p4.l = _saved_retx;
349 p4.h = _saved_retx;
350 [p4] = r6;
351 #endif
352 r6 = SYSCFG;
353 [p4 + 4] = r6;
354 BITCLR(r6, 0);
355 SYSCFG = r6;
357 /* Disable all interrupts, but make sure level 5 is enabled so
358 * we can switch to that level. Save the old mask. */
359 cli r6;
360 [p4 + 8] = r6;
362 p4.l = lo(SAFE_USER_INSTRUCTION);
363 p4.h = hi(SAFE_USER_INSTRUCTION);
364 retx = p4;
366 r6 = 0x3f;
367 sti r6;
369 raise 5;
370 jump.s _bfin_return_from_exception;
371 ENDPROC(_ex_trap_c)
373 /* We just realized we got an exception, while we were processing a different
374 * exception. This is a unrecoverable event, so crash
375 */
376 ENTRY(_double_fault)
377 /* Turn caches & protection off, to ensure we don't get any more
378 * double exceptions
379 */
381 P4.L = LO(IMEM_CONTROL);
382 P4.H = HI(IMEM_CONTROL);
384 R5 = [P4]; /* Control Register*/
385 BITCLR(R5,ENICPLB_P);
386 SSYNC; /* SSYNC required before writing to IMEM_CONTROL. */
387 .align 8;
388 [P4] = R5;
389 SSYNC;
391 P4.L = LO(DMEM_CONTROL);
392 P4.H = HI(DMEM_CONTROL);
393 R5 = [P4];
394 BITCLR(R5,ENDCPLB_P);
395 SSYNC; /* SSYNC required before writing to DMEM_CONTROL. */
396 .align 8;
397 [P4] = R5;
398 SSYNC;
400 /* Fix up the stack */
401 (R7:6,P5:4) = [sp++];
402 ASTAT = [sp++];
403 SP = EX_SCRATCH_REG;
405 /* We should be out of the exception stack, and back down into
406 * kernel or user space stack
407 */
408 SAVE_ALL_SYS
410 /* The dumping functions expect the return address in the RETI
411 * slot. */
412 r6 = retx;
413 [sp + PT_PC] = r6;
415 r0 = sp; /* stack frame pt_regs pointer argument ==> r0 */
416 SP += -12;
417 call _double_fault_c;
418 SP += 12;
419 .L_double_fault_panic:
420 JUMP .L_double_fault_panic
422 ENDPROC(_double_fault)
424 ENTRY(_exception_to_level5)
425 SAVE_ALL_SYS
427 p4.l = _saved_retx;
428 p4.h = _saved_retx;
429 r6 = [p4];
430 [sp + PT_PC] = r6;
432 r6 = [p4 + 4];
433 [sp + PT_SYSCFG] = r6;
435 /* Restore interrupt mask. We haven't pushed RETI, so this
436 * doesn't enable interrupts until we return from this handler. */
437 r6 = [p4 + 8];
438 sti r6;
440 /* Restore the hardware error vector. */
441 P5.h = _evt_ivhw;
442 P5.l = _evt_ivhw;
443 p4.l = lo(EVT5);
444 p4.h = hi(EVT5);
445 [p4] = p5;
446 csync;
448 p2.l = lo(IPEND);
449 p2.h = hi(IPEND);
450 csync;
451 r0 = [p2]; /* Read current IPEND */
452 [sp + PT_IPEND] = r0; /* Store IPEND */
454 r0 = sp; /* stack frame pt_regs pointer argument ==> r0 */
455 SP += -12;
456 call _trap_c;
457 SP += 12;
459 #ifdef CONFIG_DEBUG_DOUBLEFAULT
460 /* Grab ILAT */
461 p2.l = lo(ILAT);
462 p2.h = hi(ILAT);
463 r0 = [p2];
464 r1 = 0x20; /* Did I just cause anther HW error? */
465 r0 = r0 & r1;
466 CC = R0 == R1;
467 if CC JUMP _double_fault;
468 #endif
470 call _ret_from_exception;
471 RESTORE_ALL_SYS
472 rti;
473 ENDPROC(_exception_to_level5)
475 ENTRY(_trap) /* Exception: 4th entry into system event table(supervisor mode)*/
476 /* Since the kernel stack can be anywhere, it's not guaranteed to be
477 * covered by a CPLB. Switch to an exception stack; use RETN as a
478 * scratch register (for want of a better option).
479 */
480 EX_SCRATCH_REG = sp;
481 sp.l = _exception_stack_top;
482 sp.h = _exception_stack_top;
483 /* Try to deal with syscalls quickly. */
484 [--sp] = ASTAT;
485 [--sp] = (R7:6,P5:4);
487 #if ANOMALY_05000283 || ANOMALY_05000315
488 cc = r7 == r7;
489 p5.h = HI(CHIPID);
490 p5.l = LO(CHIPID);
491 if cc jump 1f;
492 r7.l = W[p5];
493 1:
494 #endif
496 #ifdef CONFIG_DEBUG_DOUBLEFAULT
497 /*
498 * Save these registers, as they are only valid in exception context
499 * (where we are now - as soon as we defer to IRQ5, they can change)
500 * DCPLB_STATUS and ICPLB_STATUS are also only valid in EVT3,
501 * but they are not very interesting, so don't save them
502 */
504 p4.l = lo(DCPLB_FAULT_ADDR);
505 p4.h = hi(DCPLB_FAULT_ADDR);
506 r7 = [p4];
507 p5.h = _saved_dcplb_fault_addr;
508 p5.l = _saved_dcplb_fault_addr;
509 [p5] = r7;
511 r7 = [p4 + (ICPLB_FAULT_ADDR - DCPLB_FAULT_ADDR)];
512 p5.h = _saved_icplb_fault_addr;
513 p5.l = _saved_icplb_fault_addr;
514 [p5] = r7;
516 p4.l = _saved_retx;
517 p4.h = _saved_retx;
518 r6 = retx;
519 [p4] = r6;
521 r7 = SEQSTAT; /* reason code is in bit 5:0 */
522 p4.l = _saved_seqstat;
523 p4.h = _saved_seqstat;
524 [p4] = r7;
525 #else
526 r7 = SEQSTAT; /* reason code is in bit 5:0 */
527 #endif
528 r6.l = lo(SEQSTAT_EXCAUSE);
529 r6.h = hi(SEQSTAT_EXCAUSE);
530 r7 = r7 & r6;
531 p5.h = _ex_table;
532 p5.l = _ex_table;
533 p4 = r7;
534 p5 = p5 + (p4 << 2);
535 p4 = [p5];
536 jump (p4);
538 .Lbadsys:
539 r7 = -ENOSYS; /* signextending enough */
540 [sp + PT_R0] = r7; /* return value from system call */
541 jump .Lsyscall_really_exit;
542 ENDPROC(_trap)
544 ENTRY(_kernel_execve)
545 link SIZEOF_PTREGS;
546 p0 = sp;
547 r3 = SIZEOF_PTREGS / 4;
548 r4 = 0(x);
549 0:
550 [p0++] = r4;
551 r3 += -1;
552 cc = r3 == 0;
553 if !cc jump 0b (bp);
555 p0 = sp;
556 sp += -16;
557 [sp + 12] = p0;
558 call _do_execve;
559 SP += 16;
560 cc = r0 == 0;
561 if ! cc jump 1f;
562 /* Success. Copy our temporary pt_regs to the top of the kernel
563 * stack and do a normal exception return.
564 */
565 r1 = sp;
566 r0 = (-KERNEL_STACK_SIZE) (x);
567 r1 = r1 & r0;
568 p2 = r1;
569 p3 = [p2];
570 r0 = KERNEL_STACK_SIZE - 4 (z);
571 p1 = r0;
572 p1 = p1 + p2;
574 p0 = fp;
575 r4 = [p0--];
576 r3 = SIZEOF_PTREGS / 4;
577 0:
578 r4 = [p0--];
579 [p1--] = r4;
580 r3 += -1;
581 cc = r3 == 0;
582 if ! cc jump 0b (bp);
584 r0 = (KERNEL_STACK_SIZE - SIZEOF_PTREGS) (z);
585 p1 = r0;
586 p1 = p1 + p2;
587 sp = p1;
588 r0 = syscfg;
589 [SP + PT_SYSCFG] = r0;
590 [p3 + (TASK_THREAD + THREAD_KSP)] = sp;
592 RESTORE_CONTEXT;
593 rti;
594 1:
595 unlink;
596 rts;
597 ENDPROC(_kernel_execve)
599 ENTRY(_system_call)
600 /* Store IPEND */
601 p2.l = lo(IPEND);
602 p2.h = hi(IPEND);
603 csync;
604 r0 = [p2];
605 [sp + PT_IPEND] = r0;
607 /* Store RETS for now */
608 r0 = rets;
609 [sp + PT_RESERVED] = r0;
610 /* Set the stack for the current process */
611 r7 = sp;
612 r6.l = lo(ALIGN_PAGE_MASK);
613 r6.h = hi(ALIGN_PAGE_MASK);
614 r7 = r7 & r6; /* thread_info */
615 p2 = r7;
616 p2 = [p2];
618 [p2+(TASK_THREAD+THREAD_KSP)] = sp;
620 /* Check the System Call */
621 r7 = __NR_syscall;
622 /* System call number is passed in P0 */
623 r6 = p0;
624 cc = r6 < r7;
625 if ! cc jump .Lbadsys;
627 /* are we tracing syscalls?*/
628 r7 = sp;
629 r6.l = lo(ALIGN_PAGE_MASK);
630 r6.h = hi(ALIGN_PAGE_MASK);
631 r7 = r7 & r6;
632 p2 = r7;
633 r7 = [p2+TI_FLAGS];
634 CC = BITTST(r7,TIF_SYSCALL_TRACE);
635 if CC JUMP _sys_trace;
637 /* Execute the appropriate system call */
639 p4 = p0;
640 p5.l = _sys_call_table;
641 p5.h = _sys_call_table;
642 p5 = p5 + (p4 << 2);
643 r0 = [sp + PT_R0];
644 r1 = [sp + PT_R1];
645 r2 = [sp + PT_R2];
646 p5 = [p5];
648 [--sp] = r5;
649 [--sp] = r4;
650 [--sp] = r3;
651 SP += -12;
652 call (p5);
653 SP += 24;
654 [sp + PT_R0] = r0;
656 .Lresume_userspace:
657 r7 = sp;
658 r4.l = lo(ALIGN_PAGE_MASK);
659 r4.h = hi(ALIGN_PAGE_MASK);
660 r7 = r7 & r4; /* thread_info->flags */
661 p5 = r7;
662 .Lresume_userspace_1:
663 /* Disable interrupts. */
664 [--sp] = reti;
665 reti = [sp++];
667 r7 = [p5 + TI_FLAGS];
668 r4.l = lo(_TIF_WORK_MASK);
669 r4.h = hi(_TIF_WORK_MASK);
670 r7 = r7 & r4;
672 .Lsyscall_resched:
673 cc = BITTST(r7, TIF_NEED_RESCHED);
674 if !cc jump .Lsyscall_sigpending;
676 /* Reenable interrupts. */
677 [--sp] = reti;
678 r0 = [sp++];
680 SP += -12;
681 call _schedule;
682 SP += 12;
684 jump .Lresume_userspace_1;
686 .Lsyscall_sigpending:
687 cc = BITTST(r7, TIF_RESTORE_SIGMASK);
688 if cc jump .Lsyscall_do_signals;
689 cc = BITTST(r7, TIF_SIGPENDING);
690 if !cc jump .Lsyscall_really_exit;
691 .Lsyscall_do_signals:
692 /* Reenable interrupts. */
693 [--sp] = reti;
694 r0 = [sp++];
696 r0 = sp;
697 SP += -12;
698 call _do_signal;
699 SP += 12;
701 .Lsyscall_really_exit:
702 r5 = [sp + PT_RESERVED];
703 rets = r5;
704 rts;
705 ENDPROC(_system_call)
707 /* Do not mark as ENTRY() to avoid error in assembler ...
708 * this symbol need not be global anyways, so ...
709 */
710 _sys_trace:
711 call _syscall_trace;
713 /* Execute the appropriate system call */
715 p4 = [SP + PT_P0];
716 p5.l = _sys_call_table;
717 p5.h = _sys_call_table;
718 p5 = p5 + (p4 << 2);
719 r0 = [sp + PT_R0];
720 r1 = [sp + PT_R1];
721 r2 = [sp + PT_R2];
722 r3 = [sp + PT_R3];
723 r4 = [sp + PT_R4];
724 r5 = [sp + PT_R5];
725 p5 = [p5];
727 [--sp] = r5;
728 [--sp] = r4;
729 [--sp] = r3;
730 SP += -12;
731 call (p5);
732 SP += 24;
733 [sp + PT_R0] = r0;
735 call _syscall_trace;
736 jump .Lresume_userspace;
737 ENDPROC(_sys_trace)
739 ENTRY(_resume)
740 /*
741 * Beware - when entering resume, prev (the current task) is
742 * in r0, next (the new task) is in r1.
743 */
744 p0 = r0;
745 p1 = r1;
746 [--sp] = rets;
747 [--sp] = fp;
748 [--sp] = (r7:4, p5:3);
750 /* save usp */
751 p2 = usp;
752 [p0+(TASK_THREAD+THREAD_USP)] = p2;
754 /* save current kernel stack pointer */
755 [p0+(TASK_THREAD+THREAD_KSP)] = sp;
757 /* save program counter */
758 r1.l = _new_old_task;
759 r1.h = _new_old_task;
760 [p0+(TASK_THREAD+THREAD_PC)] = r1;
762 /* restore the kernel stack pointer */
763 sp = [p1+(TASK_THREAD+THREAD_KSP)];
765 /* restore user stack pointer */
766 p0 = [p1+(TASK_THREAD+THREAD_USP)];
767 usp = p0;
769 /* restore pc */
770 p0 = [p1+(TASK_THREAD+THREAD_PC)];
771 jump (p0);
773 /*
774 * Following code actually lands up in a new (old) task.
775 */
777 _new_old_task:
778 (r7:4, p5:3) = [sp++];
779 fp = [sp++];
780 rets = [sp++];
782 /*
783 * When we come out of resume, r0 carries "old" task, becuase we are
784 * in "new" task.
785 */
786 rts;
787 ENDPROC(_resume)
789 ENTRY(_ret_from_exception)
790 p2.l = lo(IPEND);
791 p2.h = hi(IPEND);
793 csync;
794 r0 = [p2];
795 [sp + PT_IPEND] = r0;
797 1:
798 r2 = LO(~0x37) (Z);
799 r0 = r2 & r0;
800 cc = r0 == 0;
801 if !cc jump 4f; /* if not return to user mode, get out */
803 /* Make sure any pending system call or deferred exception
804 * return in ILAT for this process to get executed, otherwise
805 * in case context switch happens, system call of
806 * first process (i.e in ILAT) will be carried
807 * forward to the switched process
808 */
810 p2.l = lo(ILAT);
811 p2.h = hi(ILAT);
812 r0 = [p2];
813 r1 = (EVT_IVG14 | EVT_IVG15) (z);
814 r0 = r0 & r1;
815 cc = r0 == 0;
816 if !cc jump 5f;
818 /* Set the stack for the current process */
819 r7 = sp;
820 r4.l = lo(ALIGN_PAGE_MASK);
821 r4.h = hi(ALIGN_PAGE_MASK);
822 r7 = r7 & r4; /* thread_info->flags */
823 p5 = r7;
824 r7 = [p5 + TI_FLAGS];
825 r4.l = lo(_TIF_WORK_MASK);
826 r4.h = hi(_TIF_WORK_MASK);
827 r7 = r7 & r4;
828 cc = r7 == 0;
829 if cc jump 4f;
831 p0.l = lo(EVT15);
832 p0.h = hi(EVT15);
833 p1.l = _schedule_and_signal;
834 p1.h = _schedule_and_signal;
835 [p0] = p1;
836 csync;
837 raise 15; /* raise evt14 to do signal or reschedule */
838 4:
839 r0 = syscfg;
840 bitclr(r0, 0);
841 syscfg = r0;
842 5:
843 rts;
844 ENDPROC(_ret_from_exception)
846 ENTRY(_return_from_int)
847 /* If someone else already raised IRQ 15, do nothing. */
848 csync;
849 p2.l = lo(ILAT);
850 p2.h = hi(ILAT);
851 r0 = [p2];
852 cc = bittst (r0, EVT_IVG15_P);
853 if cc jump 2f;
855 /* if not return to user mode, get out */
856 p2.l = lo(IPEND);
857 p2.h = hi(IPEND);
858 r0 = [p2];
859 r1 = 0x17(Z);
860 r2 = ~r1;
861 r2.h = 0;
862 r0 = r2 & r0;
863 r1 = 1;
864 r1 = r0 - r1;
865 r2 = r0 & r1;
866 cc = r2 == 0;
867 if !cc jump 2f;
869 /* Lower the interrupt level to 15. */
870 p0.l = lo(EVT15);
871 p0.h = hi(EVT15);
872 p1.l = _schedule_and_signal_from_int;
873 p1.h = _schedule_and_signal_from_int;
874 [p0] = p1;
875 csync;
876 #if ANOMALY_05000281
877 r0.l = lo(SAFE_USER_INSTRUCTION);
878 r0.h = hi(SAFE_USER_INSTRUCTION);
879 reti = r0;
880 #endif
881 r0 = 0x801f (z);
882 STI r0;
883 raise 15; /* raise evt15 to do signal or reschedule */
884 rti;
885 2:
886 rts;
887 ENDPROC(_return_from_int)
889 ENTRY(_lower_to_irq14)
890 #if ANOMALY_05000281
891 r0.l = lo(SAFE_USER_INSTRUCTION);
892 r0.h = hi(SAFE_USER_INSTRUCTION);
893 reti = r0;
894 #endif
895 r0 = 0x401f;
896 sti r0;
897 raise 14;
898 rti;
899 ENTRY(_evt14_softirq)
900 #ifdef CONFIG_DEBUG_HWERR
901 r0 = 0x3f;
902 sti r0;
903 #else
904 cli r0;
905 #endif
906 [--sp] = RETI;
907 SP += 4;
908 rts;
910 _schedule_and_signal_from_int:
911 /* To end up here, vector 15 was changed - so we have to change it
912 * back.
913 */
914 p0.l = lo(EVT15);
915 p0.h = hi(EVT15);
916 p1.l = _evt_system_call;
917 p1.h = _evt_system_call;
918 [p0] = p1;
919 csync;
921 /* Set orig_p0 to -1 to indicate this isn't the end of a syscall. */
922 r0 = -1 (x);
923 [sp + PT_ORIG_P0] = r0;
925 p1 = rets;
926 [sp + PT_RESERVED] = p1;
928 p0.l = _irq_flags;
929 p0.h = _irq_flags;
930 r0 = [p0];
931 sti r0;
933 r0 = sp;
934 sp += -12;
935 call _finish_atomic_sections;
936 sp += 12;
937 jump.s .Lresume_userspace;
939 _schedule_and_signal:
940 SAVE_CONTEXT_SYSCALL
941 /* To end up here, vector 15 was changed - so we have to change it
942 * back.
943 */
944 p0.l = lo(EVT15);
945 p0.h = hi(EVT15);
946 p1.l = _evt_system_call;
947 p1.h = _evt_system_call;
948 [p0] = p1;
949 csync;
950 p0.l = 1f;
951 p0.h = 1f;
952 [sp + PT_RESERVED] = P0;
953 call .Lresume_userspace;
954 1:
955 RESTORE_CONTEXT
956 rti;
957 ENDPROC(_lower_to_irq14)
959 /* We handle this 100% in exception space - to reduce overhead
960 * Only potiential problem is if the software buffer gets swapped out of the
961 * CPLB table - then double fault. - so we don't let this happen in other places
962 */
963 #ifdef CONFIG_DEBUG_BFIN_HWTRACE_EXPAND
964 ENTRY(_ex_trace_buff_full)
965 [--sp] = P3;
966 [--sp] = P2;
967 [--sp] = LC0;
968 [--sp] = LT0;
969 [--sp] = LB0;
970 P5.L = _trace_buff_offset;
971 P5.H = _trace_buff_offset;
972 P3 = [P5]; /* trace_buff_offset */
973 P5.L = lo(TBUFSTAT);
974 P5.H = hi(TBUFSTAT);
975 R7 = [P5];
976 R7 <<= 1; /* double, since we need to read twice */
977 LC0 = R7;
978 R7 <<= 2; /* need to shift over again,
979 * to get the number of bytes */
980 P5.L = lo(TBUF);
981 P5.H = hi(TBUF);
982 R6 = ((1 << CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN)*1024) - 1;
984 P2 = R7;
985 P3 = P3 + P2;
986 R7 = P3;
987 R7 = R7 & R6;
988 P3 = R7;
989 P2.L = _trace_buff_offset;
990 P2.H = _trace_buff_offset;
991 [P2] = P3;
993 P2.L = _software_trace_buff;
994 P2.H = _software_trace_buff;
996 LSETUP (.Lstart, .Lend) LC0;
997 .Lstart:
998 R7 = [P5]; /* read TBUF */
999 P4 = P3 + P2;
1000 [P4] = R7;
1001 P3 += -4;
1002 R7 = P3;
1003 R7 = R7 & R6;
1004 .Lend:
1005 P3 = R7;
1007 LB0 = [sp++];
1008 LT0 = [sp++];
1009 LC0 = [sp++];
1010 P2 = [sp++];
1011 P3 = [sp++];
1012 jump _bfin_return_from_exception;
1013 ENDPROC(_ex_trace_buff_full)
1015 #if CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN == 4
1016 .data
1017 #else
1018 .section .l1.data.B
1019 #endif /* CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN */
1020 ENTRY(_trace_buff_offset)
1021 .long 0;
1022 ALIGN
1023 ENTRY(_software_trace_buff)
1024 .rept ((1 << CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN)*256);
1025 .long 0
1026 .endr
1027 #endif /* CONFIG_DEBUG_BFIN_HWTRACE_EXPAND */
1029 #if CONFIG_EARLY_PRINTK
1030 __INIT
1031 ENTRY(_early_trap)
1032 SAVE_ALL_SYS
1033 trace_buffer_stop(p0,r0);
1035 #if ANOMALY_05000283 || ANOMALY_05000315
1036 cc = r5 == r5;
1037 p4.h = HI(CHIPID);
1038 p4.l = LO(CHIPID);
1039 if cc jump 1f;
1040 r5.l = W[p4];
1041 1:
1042 #endif
1044 /* Turn caches off, to ensure we don't get double exceptions */
1046 P4.L = LO(IMEM_CONTROL);
1047 P4.H = HI(IMEM_CONTROL);
1049 R5 = [P4]; /* Control Register*/
1050 BITCLR(R5,ENICPLB_P);
1051 CLI R1;
1052 SSYNC; /* SSYNC required before writing to IMEM_CONTROL. */
1053 .align 8;
1054 [P4] = R5;
1055 SSYNC;
1057 P4.L = LO(DMEM_CONTROL);
1058 P4.H = HI(DMEM_CONTROL);
1059 R5 = [P4];
1060 BITCLR(R5,ENDCPLB_P);
1061 SSYNC; /* SSYNC required before writing to DMEM_CONTROL. */
1062 .align 8;
1063 [P4] = R5;
1064 SSYNC;
1065 STI R1;
1067 r0 = sp; /* stack frame pt_regs pointer argument ==> r0 */
1068 r1 = RETX;
1070 SP += -12;
1071 call _early_trap_c;
1072 SP += 12;
1073 ENDPROC(_early_trap)
1074 __FINIT
1075 #endif /* CONFIG_EARLY_PRINTK */
1077 /*
1078 * Put these in the kernel data section - that should always be covered by
1079 * a CPLB. This is needed to ensure we don't get double fault conditions
1080 */
1082 #ifdef CONFIG_SYSCALL_TAB_L1
1083 .section .l1.data
1084 #else
1085 .data
1086 #endif
1088 ENTRY(_ex_table)
1089 /* entry for each EXCAUSE[5:0]
1090 * This table must be in sync with the table in ./kernel/traps.c
1091 * EXCPT instruction can provide 4 bits of EXCAUSE, allowing 16 to be user defined
1092 */
1093 .long _ex_syscall /* 0x00 - User Defined - Linux Syscall */
1094 .long _ex_soft_bp /* 0x01 - User Defined - Software breakpoint */
1095 #ifdef CONFIG_KGDB
1096 .long _ex_trap_c /* 0x02 - User Defined - KGDB initial connection
1097 and break signal trap */
1098 #else
1099 .long _ex_replaceable /* 0x02 - User Defined */
1100 #endif
1101 .long _ex_trap_c /* 0x03 - User Defined - userspace stack overflow */
1102 .long _ex_trap_c /* 0x04 - User Defined - dump trace buffer */
1103 .long _ex_replaceable /* 0x05 - User Defined */
1104 .long _ex_replaceable /* 0x06 - User Defined */
1105 .long _ex_replaceable /* 0x07 - User Defined */
1106 .long _ex_replaceable /* 0x08 - User Defined */
1107 .long _ex_replaceable /* 0x09 - User Defined */
1108 .long _ex_replaceable /* 0x0A - User Defined */
1109 .long _ex_replaceable /* 0x0B - User Defined */
1110 .long _ex_replaceable /* 0x0C - User Defined */
1111 .long _ex_replaceable /* 0x0D - User Defined */
1112 .long _ex_replaceable /* 0x0E - User Defined */
1113 .long _ex_replaceable /* 0x0F - User Defined */
1114 .long _ex_single_step /* 0x10 - HW Single step */
1115 #ifdef CONFIG_DEBUG_BFIN_HWTRACE_EXPAND
1116 .long _ex_trace_buff_full /* 0x11 - Trace Buffer Full */
1117 #else
1118 .long _ex_trap_c /* 0x11 - Trace Buffer Full */
1119 #endif
1120 .long _ex_trap_c /* 0x12 - Reserved */
1121 .long _ex_trap_c /* 0x13 - Reserved */
1122 .long _ex_trap_c /* 0x14 - Reserved */
1123 .long _ex_trap_c /* 0x15 - Reserved */
1124 .long _ex_trap_c /* 0x16 - Reserved */
1125 .long _ex_trap_c /* 0x17 - Reserved */
1126 .long _ex_trap_c /* 0x18 - Reserved */
1127 .long _ex_trap_c /* 0x19 - Reserved */
1128 .long _ex_trap_c /* 0x1A - Reserved */
1129 .long _ex_trap_c /* 0x1B - Reserved */
1130 .long _ex_trap_c /* 0x1C - Reserved */
1131 .long _ex_trap_c /* 0x1D - Reserved */
1132 .long _ex_trap_c /* 0x1E - Reserved */
1133 .long _ex_trap_c /* 0x1F - Reserved */
1134 .long _ex_trap_c /* 0x20 - Reserved */
1135 .long _ex_trap_c /* 0x21 - Undefined Instruction */
1136 .long _ex_trap_c /* 0x22 - Illegal Instruction Combination */
1137 .long _ex_dviol /* 0x23 - Data CPLB Protection Violation */
1138 .long _ex_trap_c /* 0x24 - Data access misaligned */
1139 .long _ex_trap_c /* 0x25 - Unrecoverable Event */
1140 .long _ex_dmiss /* 0x26 - Data CPLB Miss */
1141 .long _ex_dmult /* 0x27 - Data CPLB Multiple Hits - Linux Trap Zero */
1142 .long _ex_trap_c /* 0x28 - Emulation Watchpoint */
1143 .long _ex_trap_c /* 0x29 - Instruction fetch access error (535 only) */
1144 .long _ex_trap_c /* 0x2A - Instruction fetch misaligned */
1145 .long _ex_trap_c /* 0x2B - Instruction CPLB protection Violation */
1146 .long _ex_icplb_miss /* 0x2C - Instruction CPLB miss */
1147 .long _ex_trap_c /* 0x2D - Instruction CPLB Multiple Hits */
1148 .long _ex_trap_c /* 0x2E - Illegal use of Supervisor Resource */
1149 .long _ex_trap_c /* 0x2E - Illegal use of Supervisor Resource */
1150 .long _ex_trap_c /* 0x2F - Reserved */
1151 .long _ex_trap_c /* 0x30 - Reserved */
1152 .long _ex_trap_c /* 0x31 - Reserved */
1153 .long _ex_trap_c /* 0x32 - Reserved */
1154 .long _ex_trap_c /* 0x33 - Reserved */
1155 .long _ex_trap_c /* 0x34 - Reserved */
1156 .long _ex_trap_c /* 0x35 - Reserved */
1157 .long _ex_trap_c /* 0x36 - Reserved */
1158 .long _ex_trap_c /* 0x37 - Reserved */
1159 .long _ex_trap_c /* 0x38 - Reserved */
1160 .long _ex_trap_c /* 0x39 - Reserved */
1161 .long _ex_trap_c /* 0x3A - Reserved */
1162 .long _ex_trap_c /* 0x3B - Reserved */
1163 .long _ex_trap_c /* 0x3C - Reserved */
1164 .long _ex_trap_c /* 0x3D - Reserved */
1165 .long _ex_trap_c /* 0x3E - Reserved */
1166 .long _ex_trap_c /* 0x3F - Reserved */
1167 END(_ex_table)
1169 ENTRY(_sys_call_table)
1170 .long _sys_restart_syscall /* 0 */
1171 .long _sys_exit
1172 .long _sys_fork
1173 .long _sys_read
1174 .long _sys_write
1175 .long _sys_open /* 5 */
1176 .long _sys_close
1177 .long _sys_ni_syscall /* old waitpid */
1178 .long _sys_creat
1179 .long _sys_link
1180 .long _sys_unlink /* 10 */
1181 .long _sys_execve
1182 .long _sys_chdir
1183 .long _sys_time
1184 .long _sys_mknod
1185 .long _sys_chmod /* 15 */
1186 .long _sys_chown /* chown16 */
1187 .long _sys_ni_syscall /* old break syscall holder */
1188 .long _sys_ni_syscall /* old stat */
1189 .long _sys_lseek
1190 .long _sys_getpid /* 20 */
1191 .long _sys_mount
1192 .long _sys_ni_syscall /* old umount */
1193 .long _sys_setuid
1194 .long _sys_getuid
1195 .long _sys_stime /* 25 */
1196 .long _sys_ptrace
1197 .long _sys_alarm
1198 .long _sys_ni_syscall /* old fstat */
1199 .long _sys_pause
1200 .long _sys_ni_syscall /* old utime */ /* 30 */
1201 .long _sys_ni_syscall /* old stty syscall holder */
1202 .long _sys_ni_syscall /* old gtty syscall holder */
1203 .long _sys_access
1204 .long _sys_nice
1205 .long _sys_ni_syscall /* 35 */ /* old ftime syscall holder */
1206 .long _sys_sync
1207 .long _sys_kill
1208 .long _sys_rename
1209 .long _sys_mkdir
1210 .long _sys_rmdir /* 40 */
1211 .long _sys_dup
1212 .long _sys_pipe
1213 .long _sys_times
1214 .long _sys_ni_syscall /* old prof syscall holder */
1215 .long _sys_brk /* 45 */
1216 .long _sys_setgid
1217 .long _sys_getgid
1218 .long _sys_ni_syscall /* old sys_signal */
1219 .long _sys_geteuid /* geteuid16 */
1220 .long _sys_getegid /* getegid16 */ /* 50 */
1221 .long _sys_acct
1222 .long _sys_umount /* recycled never used phys() */
1223 .long _sys_ni_syscall /* old lock syscall holder */
1224 .long _sys_ioctl
1225 .long _sys_fcntl /* 55 */
1226 .long _sys_ni_syscall /* old mpx syscall holder */
1227 .long _sys_setpgid
1228 .long _sys_ni_syscall /* old ulimit syscall holder */
1229 .long _sys_ni_syscall /* old old uname */
1230 .long _sys_umask /* 60 */
1231 .long _sys_chroot
1232 .long _sys_ustat
1233 .long _sys_dup2
1234 .long _sys_getppid
1235 .long _sys_getpgrp /* 65 */
1236 .long _sys_setsid
1237 .long _sys_ni_syscall /* old sys_sigaction */
1238 .long _sys_sgetmask
1239 .long _sys_ssetmask
1240 .long _sys_setreuid /* setreuid16 */ /* 70 */
1241 .long _sys_setregid /* setregid16 */
1242 .long _sys_ni_syscall /* old sys_sigsuspend */
1243 .long _sys_ni_syscall /* old sys_sigpending */
1244 .long _sys_sethostname
1245 .long _sys_setrlimit /* 75 */
1246 .long _sys_ni_syscall /* old getrlimit */
1247 .long _sys_getrusage
1248 .long _sys_gettimeofday
1249 .long _sys_settimeofday
1250 .long _sys_getgroups /* getgroups16 */ /* 80 */
1251 .long _sys_setgroups /* setgroups16 */
1252 .long _sys_ni_syscall /* old_select */
1253 .long _sys_symlink
1254 .long _sys_ni_syscall /* old lstat */
1255 .long _sys_readlink /* 85 */
1256 .long _sys_uselib
1257 .long _sys_ni_syscall /* sys_swapon */
1258 .long _sys_reboot
1259 .long _sys_ni_syscall /* old_readdir */
1260 .long _sys_ni_syscall /* sys_mmap */ /* 90 */
1261 .long _sys_munmap
1262 .long _sys_truncate
1263 .long _sys_ftruncate
1264 .long _sys_fchmod
1265 .long _sys_fchown /* fchown16 */ /* 95 */
1266 .long _sys_getpriority
1267 .long _sys_setpriority
1268 .long _sys_ni_syscall /* old profil syscall holder */
1269 .long _sys_statfs
1270 .long _sys_fstatfs /* 100 */
1271 .long _sys_ni_syscall
1272 .long _sys_ni_syscall /* old sys_socketcall */
1273 .long _sys_syslog
1274 .long _sys_setitimer
1275 .long _sys_getitimer /* 105 */
1276 .long _sys_newstat
1277 .long _sys_newlstat
1278 .long _sys_newfstat
1279 .long _sys_ni_syscall /* old uname */
1280 .long _sys_ni_syscall /* iopl for i386 */ /* 110 */
1281 .long _sys_vhangup
1282 .long _sys_ni_syscall /* obsolete idle() syscall */
1283 .long _sys_ni_syscall /* vm86old for i386 */
1284 .long _sys_wait4
1285 .long _sys_ni_syscall /* 115 */ /* sys_swapoff */
1286 .long _sys_sysinfo
1287 .long _sys_ni_syscall /* old sys_ipc */
1288 .long _sys_fsync
1289 .long _sys_ni_syscall /* old sys_sigreturn */
1290 .long _sys_clone /* 120 */
1291 .long _sys_setdomainname
1292 .long _sys_newuname
1293 .long _sys_ni_syscall /* old sys_modify_ldt */
1294 .long _sys_adjtimex
1295 .long _sys_ni_syscall /* 125 */ /* sys_mprotect */
1296 .long _sys_ni_syscall /* old sys_sigprocmask */
1297 .long _sys_ni_syscall /* old "creat_module" */
1298 .long _sys_init_module
1299 .long _sys_delete_module
1300 .long _sys_ni_syscall /* 130: old "get_kernel_syms" */
1301 .long _sys_quotactl
1302 .long _sys_getpgid
1303 .long _sys_fchdir
1304 .long _sys_bdflush
1305 .long _sys_ni_syscall /* 135 */ /* sys_sysfs */
1306 .long _sys_personality
1307 .long _sys_ni_syscall /* for afs_syscall */
1308 .long _sys_setfsuid /* setfsuid16 */
1309 .long _sys_setfsgid /* setfsgid16 */
1310 .long _sys_llseek /* 140 */
1311 .long _sys_getdents
1312 .long _sys_ni_syscall /* sys_select */
1313 .long _sys_flock
1314 .long _sys_ni_syscall /* sys_msync */
1315 .long _sys_readv /* 145 */
1316 .long _sys_writev
1317 .long _sys_getsid
1318 .long _sys_fdatasync
1319 .long _sys_sysctl
1320 .long _sys_ni_syscall /* 150 */ /* sys_mlock */
1321 .long _sys_ni_syscall /* sys_munlock */
1322 .long _sys_ni_syscall /* sys_mlockall */
1323 .long _sys_ni_syscall /* sys_munlockall */
1324 .long _sys_sched_setparam
1325 .long _sys_sched_getparam /* 155 */
1326 .long _sys_sched_setscheduler
1327 .long _sys_sched_getscheduler
1328 .long _sys_sched_yield
1329 .long _sys_sched_get_priority_max
1330 .long _sys_sched_get_priority_min /* 160 */
1331 .long _sys_sched_rr_get_interval
1332 .long _sys_nanosleep
1333 .long _sys_mremap
1334 .long _sys_setresuid /* setresuid16 */
1335 .long _sys_getresuid /* getresuid16 */ /* 165 */
1336 .long _sys_ni_syscall /* for vm86 */
1337 .long _sys_ni_syscall /* old "query_module" */
1338 .long _sys_ni_syscall /* sys_poll */
1339 .long _sys_nfsservctl
1340 .long _sys_setresgid /* setresgid16 */ /* 170 */
1341 .long _sys_getresgid /* getresgid16 */
1342 .long _sys_prctl
1343 .long _sys_rt_sigreturn
1344 .long _sys_rt_sigaction
1345 .long _sys_rt_sigprocmask /* 175 */
1346 .long _sys_rt_sigpending
1347 .long _sys_rt_sigtimedwait
1348 .long _sys_rt_sigqueueinfo
1349 .long _sys_rt_sigsuspend
1350 .long _sys_pread64 /* 180 */
1351 .long _sys_pwrite64
1352 .long _sys_lchown /* lchown16 */
1353 .long _sys_getcwd
1354 .long _sys_capget
1355 .long _sys_capset /* 185 */
1356 .long _sys_sigaltstack
1357 .long _sys_sendfile
1358 .long _sys_ni_syscall /* streams1 */
1359 .long _sys_ni_syscall /* streams2 */
1360 .long _sys_vfork /* 190 */
1361 .long _sys_getrlimit
1362 .long _sys_mmap2
1363 .long _sys_truncate64
1364 .long _sys_ftruncate64
1365 .long _sys_stat64 /* 195 */
1366 .long _sys_lstat64
1367 .long _sys_fstat64
1368 .long _sys_chown
1369 .long _sys_getuid
1370 .long _sys_getgid /* 200 */
1371 .long _sys_geteuid
1372 .long _sys_getegid
1373 .long _sys_setreuid
1374 .long _sys_setregid
1375 .long _sys_getgroups /* 205 */
1376 .long _sys_setgroups
1377 .long _sys_fchown
1378 .long _sys_setresuid
1379 .long _sys_getresuid
1380 .long _sys_setresgid /* 210 */
1381 .long _sys_getresgid
1382 .long _sys_lchown
1383 .long _sys_setuid
1384 .long _sys_setgid
1385 .long _sys_setfsuid /* 215 */
1386 .long _sys_setfsgid
1387 .long _sys_pivot_root
1388 .long _sys_ni_syscall /* sys_mincore */
1389 .long _sys_ni_syscall /* sys_madvise */
1390 .long _sys_getdents64 /* 220 */
1391 .long _sys_fcntl64
1392 .long _sys_ni_syscall /* reserved for TUX */
1393 .long _sys_ni_syscall
1394 .long _sys_gettid
1395 .long _sys_readahead /* 225 */
1396 .long _sys_setxattr
1397 .long _sys_lsetxattr
1398 .long _sys_fsetxattr
1399 .long _sys_getxattr
1400 .long _sys_lgetxattr /* 230 */
1401 .long _sys_fgetxattr
1402 .long _sys_listxattr
1403 .long _sys_llistxattr
1404 .long _sys_flistxattr
1405 .long _sys_removexattr /* 235 */
1406 .long _sys_lremovexattr
1407 .long _sys_fremovexattr
1408 .long _sys_tkill
1409 .long _sys_sendfile64
1410 .long _sys_futex /* 240 */
1411 .long _sys_sched_setaffinity
1412 .long _sys_sched_getaffinity
1413 .long _sys_ni_syscall /* sys_set_thread_area */
1414 .long _sys_ni_syscall /* sys_get_thread_area */
1415 .long _sys_io_setup /* 245 */
1416 .long _sys_io_destroy
1417 .long _sys_io_getevents
1418 .long _sys_io_submit
1419 .long _sys_io_cancel
1420 .long _sys_ni_syscall /* 250 */ /* sys_alloc_hugepages */
1421 .long _sys_ni_syscall /* sys_freec_hugepages */
1422 .long _sys_exit_group
1423 .long _sys_lookup_dcookie
1424 .long _sys_bfin_spinlock
1425 .long _sys_epoll_create /* 255 */
1426 .long _sys_epoll_ctl
1427 .long _sys_epoll_wait
1428 .long _sys_ni_syscall /* remap_file_pages */
1429 .long _sys_set_tid_address
1430 .long _sys_timer_create /* 260 */
1431 .long _sys_timer_settime
1432 .long _sys_timer_gettime
1433 .long _sys_timer_getoverrun
1434 .long _sys_timer_delete
1435 .long _sys_clock_settime /* 265 */
1436 .long _sys_clock_gettime
1437 .long _sys_clock_getres
1438 .long _sys_clock_nanosleep
1439 .long _sys_statfs64
1440 .long _sys_fstatfs64 /* 270 */
1441 .long _sys_tgkill
1442 .long _sys_utimes
1443 .long _sys_fadvise64_64
1444 .long _sys_ni_syscall /* vserver */
1445 .long _sys_ni_syscall /* 275, mbind */
1446 .long _sys_ni_syscall /* get_mempolicy */
1447 .long _sys_ni_syscall /* set_mempolicy */
1448 .long _sys_mq_open
1449 .long _sys_mq_unlink
1450 .long _sys_mq_timedsend /* 280 */
1451 .long _sys_mq_timedreceive
1452 .long _sys_mq_notify
1453 .long _sys_mq_getsetattr
1454 .long _sys_ni_syscall /* kexec_load */
1455 .long _sys_waitid /* 285 */
1456 .long _sys_add_key
1457 .long _sys_request_key
1458 .long _sys_keyctl
1459 .long _sys_ioprio_set
1460 .long _sys_ioprio_get /* 290 */
1461 .long _sys_inotify_init
1462 .long _sys_inotify_add_watch
1463 .long _sys_inotify_rm_watch
1464 .long _sys_ni_syscall /* migrate_pages */
1465 .long _sys_openat /* 295 */
1466 .long _sys_mkdirat
1467 .long _sys_mknodat
1468 .long _sys_fchownat
1469 .long _sys_futimesat
1470 .long _sys_fstatat64 /* 300 */
1471 .long _sys_unlinkat
1472 .long _sys_renameat
1473 .long _sys_linkat
1474 .long _sys_symlinkat
1475 .long _sys_readlinkat /* 305 */
1476 .long _sys_fchmodat
1477 .long _sys_faccessat
1478 .long _sys_pselect6
1479 .long _sys_ppoll
1480 .long _sys_unshare /* 310 */
1481 .long _sys_sram_alloc
1482 .long _sys_sram_free
1483 .long _sys_dma_memcpy
1484 .long _sys_accept
1485 .long _sys_bind /* 315 */
1486 .long _sys_connect
1487 .long _sys_getpeername
1488 .long _sys_getsockname
1489 .long _sys_getsockopt
1490 .long _sys_listen /* 320 */
1491 .long _sys_recv
1492 .long _sys_recvfrom
1493 .long _sys_recvmsg
1494 .long _sys_send
1495 .long _sys_sendmsg /* 325 */
1496 .long _sys_sendto
1497 .long _sys_setsockopt
1498 .long _sys_shutdown
1499 .long _sys_socket
1500 .long _sys_socketpair /* 330 */
1501 .long _sys_semctl
1502 .long _sys_semget
1503 .long _sys_semop
1504 .long _sys_msgctl
1505 .long _sys_msgget /* 335 */
1506 .long _sys_msgrcv
1507 .long _sys_msgsnd
1508 .long _sys_shmat
1509 .long _sys_shmctl
1510 .long _sys_shmdt /* 340 */
1511 .long _sys_shmget
1512 .long _sys_splice
1513 .long _sys_sync_file_range
1514 .long _sys_tee
1515 .long _sys_vmsplice /* 345 */
1516 .long _sys_epoll_pwait
1517 .long _sys_utimensat
1518 .long _sys_signalfd
1519 .long _sys_timerfd_create
1520 .long _sys_eventfd /* 350 */
1521 .long _sys_pread64
1522 .long _sys_pwrite64
1523 .long _sys_fadvise64
1524 .long _sys_set_robust_list
1525 .long _sys_get_robust_list /* 355 */
1526 .long _sys_fallocate
1527 .long _sys_semtimedop
1528 .long _sys_timerfd_settime
1529 .long _sys_timerfd_gettime
1530 .long _sys_signalfd4 /* 360 */
1531 .long _sys_eventfd2
1532 .long _sys_epoll_create1
1533 .long _sys_dup3
1534 .long _sys_pipe2
1535 .long _sys_inotify_init1 /* 365 */
1537 .rept NR_syscalls-(.-_sys_call_table)/4
1538 .long _sys_ni_syscall
1539 .endr
1540 END(_sys_call_table)
1542 _exception_stack:
1543 .rept 1024
1544 .long 0;
1545 .endr
1546 _exception_stack_top:
1548 #if ANOMALY_05000261
1549 /* Used by the assembly entry point to work around an anomaly. */
1550 _last_cplb_fault_retx:
1551 .long 0;
1552 #endif