arch/powerpc/kernel/vdso32/vdso32.lds.S

   1 /*
   2  * This is the infamous ld script for the 32 bits vdso
   3  * library
   4  */
   5 #include <asm/vdso.h>
   6
   7 OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc", "elf32-powerpc")
   8 OUTPUT_ARCH(powerpc:common)
   9 ENTRY(_start)
  10
  11 SECTIONS
  12 {
  13         . = VDSO32_LBASE + SIZEOF_HEADERS;
  14
  15         .hash           : { *(.hash) }                  :text
  16         .gnu.hash       : { *(.gnu.hash) }
  17         .dynsym         : { *(.dynsym) }
  18         .dynstr         : { *(.dynstr) }
  19         .gnu.version    : { *(.gnu.version) }
  20         .gnu.version_d  : { *(.gnu.version_d) }
  21         .gnu.version_r  : { *(.gnu.version_r) }
  22
  23         .note           : { *(.note.*) }                :text   :note
  24
  25         . = ALIGN(16);
  26         .text           : {
  27                 *(.text .stub .text.* .gnu.linkonce.t.* __ftr_alt_*)
  28         }                                               :text
  29         PROVIDE(__etext = .);
  30         PROVIDE(_etext = .);
  31         PROVIDE(etext = .);
  32
  33         . = ALIGN(8);
  34         __ftr_fixup     : { *(__ftr_fixup) }
  35
  36         . = ALIGN(8);
  37         __mmu_ftr_fixup : { *(__mmu_ftr_fixup) }
  38
  39         . = ALIGN(8);
  40         __lwsync_fixup  : { *(__lwsync_fixup) }
  41
  42 #ifdef CONFIG_PPC64
  43         . = ALIGN(8);
  44         __fw_ftr_fixup  : { *(__fw_ftr_fixup) }
  45 #endif
  46
  47         /*
  48          * Other stuff is appended to the text segment:
  49          */
  50         .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  51         .rodata1        : { *(.rodata1) }
  52
  53         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  54         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  55         .gcc_except_table : { *(.gcc_except_table) }
  56         .fixup          : { *(.fixup) }
  57
  58         .dynamic        : { *(.dynamic) }               :text   :dynamic
  59         .got            : { *(.got) }                   :text
  60         .plt            : { *(.plt) }
  61
  62         _end = .;
  63         __end = .;
  64         PROVIDE(end = .);
  65
  66         /*
  67          * Stabs debugging sections are here too.
  68          */
  69         .stab 0 : { *(.stab) }
  70         .stabstr 0 : { *(.stabstr) }
  71         .stab.excl 0 : { *(.stab.excl) }
  72         .stab.exclstr 0 : { *(.stab.exclstr) }
  73         .stab.index 0 : { *(.stab.index) }
  74         .stab.indexstr 0 : { *(.stab.indexstr) }
  75         .comment       0 : { *(.comment) }
  76
  77         /*
  78          * DWARF debug sections.
  79          * Symbols in the DWARF debugging sections are relative to the beginning
  80          * of the section so we begin them at 0.
  81          */
  82         /* DWARF 1 */
  83         .debug          0 : { *(.debug) }
  84         .line           0 : { *(.line) }
  85         /* GNU DWARF 1 extensions */
  86         .debug_srcinfo  0 : { *(.debug_srcinfo) }
  87         .debug_sfnames  0 : { *(.debug_sfnames) }
  88         /* DWARF 1.1 and DWARF 2 */
  89         .debug_aranges  0 : { *(.debug_aranges) }
  90         .debug_pubnames 0 : { *(.debug_pubnames) }
  91         /* DWARF 2 */
  92         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  93         .debug_abbrev   0 : { *(.debug_abbrev) }
  94         .debug_line     0 : { *(.debug_line) }
  95         .debug_frame    0 : { *(.debug_frame) }
  96         .debug_str      0 : { *(.debug_str) }
  97         .debug_loc      0 : { *(.debug_loc) }
  98         .debug_macinfo  0 : { *(.debug_macinfo) }
  99         /* SGI/MIPS DWARF 2 extensions */
 100         .debug_weaknames 0 : { *(.debug_weaknames) }
 101         .debug_funcnames 0 : { *(.debug_funcnames) }
 102         .debug_typenames 0 : { *(.debug_typenames) }
 103         .debug_varnames  0 : { *(.debug_varnames) }
 104
 105         /DISCARD/       : {
 106                 *(.note.GNU-stack)
 107                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
 108                 *(.bss .sbss .dynbss .dynsbss)
 109         }
 110 }
 111
 112 /*
 113  * Very old versions of ld do not recognize this name token; use the constant.
 114  */
 115 #define PT_GNU_EH_FRAME 0x6474e550
 116
 117 /*
 118  * We must supply the ELF program headers explicitly to get just one
 119  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 120  */
 121 PHDRS
 122 {
 123         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
 124         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
 125         note            PT_NOTE FLAGS(4);               /* PF_R */
 126         eh_frame_hdr    PT_GNU_EH_FRAME;
 127 }
 128
 129 /*
 130  * This controls what symbols we export from the DSO.
 131  */
 132 VERSION
 133 {
 134         VDSO_VERSION_STRING {
 135         global:
 136                 /*
 137                  * Has to be there for the kernel to find
 138                  */
 139                 __kernel_datapage_offset;
 140
 141                 __kernel_get_syscall_map;
 142                 __kernel_gettimeofday;
 143                 __kernel_clock_gettime;
 144                 __kernel_clock_getres;
 145                 __kernel_get_tbfreq;
 146                 __kernel_sync_dicache;
 147                 __kernel_sync_dicache_p5;
 148                 __kernel_sigtramp32;
 149                 __kernel_sigtramp_rt32;
 150
 151         local: *;
 152         };
 153 }