arch/x86/boot/header.S

   1 /*
   2  *      header.S
   3  *
   4  *      Copyright (C) 1991, 1992 Linus Torvalds
   5  *
   6  *      Based on bootsect.S and setup.S
   7  *      modified by more people than can be counted
   8  *
   9  *      Rewritten as a common file by H. Peter Anvin (Apr 2007)
  10  *
  11  * BIG FAT NOTE: We're in real mode using 64k segments.  Therefore segment
  12  * addresses must be multiplied by 16 to obtain their respective linear
  13  * addresses. To avoid confusion, linear addresses are written using leading
  14  * hex while segment addresses are written as segment:offset.
  15  *
  16  */
  17
  18 #include <asm/segment.h>
  19 #include <generated/utsrelease.h>
  20 #include <asm/boot.h>
  21 #include <asm/e820.h>
  22 #include <asm/page_types.h>
  23 #include <asm/setup.h>
  24 #include "boot.h"
  25 #include "voffset.h"
  26 #include "zoffset.h"
  27
  28 BOOTSEG         = 0x07C0                /* original address of boot-sector */
  29 SYSSEG          = 0x1000                /* historical load address >> 4 */
  30
  31 #ifndef SVGA_MODE
  32 #define SVGA_MODE ASK_VGA
  33 #endif
  34
  35 #ifndef RAMDISK
  36 #define RAMDISK 0
  37 #endif
  38
  39 #ifndef ROOT_RDONLY
  40 #define ROOT_RDONLY 1
  41 #endif
  42
  43         .code16
  44         .section ".bstext", "ax"
  45
  46         .global bootsect_start
  47 bootsect_start:
  48
  49         # Normalize the start address
  50         ljmp    $BOOTSEG, $start2
  51
  52 start2:
  53         movw    %cs, %ax
  54         movw    %ax, %ds
  55         movw    %ax, %es
  56         movw    %ax, %ss
  57         xorw    %sp, %sp
  58         sti
  59         cld
  60
  61         movw    $bugger_off_msg, %si
  62
  63 msg_loop:
  64         lodsb
  65         andb    %al, %al
  66         jz      bs_die
  67         movb    $0xe, %ah
  68         movw    $7, %bx
  69         int     $0x10
  70         jmp     msg_loop
  71
  72 bs_die:
  73         # Allow the user to press a key, then reboot
  74         xorw    %ax, %ax
  75         int     $0x16
  76         int     $0x19
  77
  78         # int 0x19 should never return.  In case it does anyway,
  79         # invoke the BIOS reset code...
  80         ljmp    $0xf000,$0xfff0
  81
  82         .section ".bsdata", "a"
  83 bugger_off_msg:
  84         .ascii  "Direct booting from floppy is no longer supported.\r\n"
  85         .ascii  "Please use a boot loader program instead.\r\n"
  86         .ascii  "\n"
  87         .ascii  "Remove disk and press any key to reboot . . .\r\n"
  88         .byte   0
  89
  90
  91         # Kernel attributes; used by setup.  This is part 1 of the
  92         # header, from the old boot sector.
  93
  94         .section ".header", "a"
  95         .globl  hdr
  96 hdr:
  97 setup_sects:    .byte 0                 /* Filled in by build.c */
  98 root_flags:     .word ROOT_RDONLY
  99 syssize:        .long 0                 /* Filled in by build.c */
 100 ram_size:       .word 0                 /* Obsolete */
 101 vid_mode:       .word SVGA_MODE
 102 root_dev:       .word 0                 /* Filled in by build.c */
 103 boot_flag:      .word 0xAA55
 104
 105         # offset 512, entry point
 106
 107         .globl  _start
 108 _start:
 109                 # Explicitly enter this as bytes, or the assembler
 110                 # tries to generate a 3-byte jump here, which causes
 111                 # everything else to push off to the wrong offset.
 112                 .byte   0xeb            # short (2-byte) jump
 113                 .byte   start_of_setup-1f
 114 1:
 115
 116         # Part 2 of the header, from the old setup.S
 117
 118                 .ascii  "HdrS"          # header signature
 119                 .word   0x020a          # header version number (>= 0x0105)
 120                                         # or else old loadlin-1.5 will fail)
 121                 .globl realmode_swtch
 122 realmode_swtch: .word   0, 0            # default_switch, SETUPSEG
 123 start_sys_seg:  .word   SYSSEG          # obsolete and meaningless, but just
 124                                         # in case something decided to "use" it
 125                 .word   kernel_version-512 # pointing to kernel version string
 126                                         # above section of header is compatible
 127                                         # with loadlin-1.5 (header v1.5). Don't
 128                                         # change it.
 129
 130 type_of_loader: .byte   0               # 0 means ancient bootloader, newer
 131                                         # bootloaders know to change this.
 132                                         # See Documentation/i386/boot.txt for
 133                                         # assigned ids
 134
 135 # flags, unused bits must be zero (RFU) bit within loadflags
 136 loadflags:
 137 LOADED_HIGH     = 1                     # If set, the kernel is loaded high
 138 CAN_USE_HEAP    = 0x80                  # If set, the loader also has set
 139                                         # heap_end_ptr to tell how much
 140                                         # space behind setup.S can be used for
 141                                         # heap purposes.
 142                                         # Only the loader knows what is free
 143                 .byte   LOADED_HIGH
 144
 145 setup_move_size: .word  0x8000          # size to move, when setup is not
 146                                         # loaded at 0x90000. We will move setup
 147                                         # to 0x90000 then just before jumping
 148                                         # into the kernel. However, only the
 149                                         # loader knows how much data behind
 150                                         # us also needs to be loaded.
 151
 152 code32_start:                           # here loaders can put a different
 153                                         # start address for 32-bit code.
 154                 .long   0x100000        # 0x100000 = default for big kernel
 155
 156 ramdisk_image:  .long   0               # address of loaded ramdisk image
 157                                         # Here the loader puts the 32-bit
 158                                         # address where it loaded the image.
 159                                         # This only will be read by the kernel.
 160
 161 ramdisk_size:   .long   0               # its size in bytes
 162
 163 bootsect_kludge:
 164                 .long   0               # obsolete
 165
 166 heap_end_ptr:   .word   _end+STACK_SIZE-512
 167                                         # (Header version 0x0201 or later)
 168                                         # space from here (exclusive) down to
 169                                         # end of setup code can be used by setup
 170                                         # for local heap purposes.
 171
 172 ext_loader_ver:
 173                 .byte   0               # Extended boot loader version
 174 ext_loader_type:
 175                 .byte   0               # Extended boot loader type
 176
 177 cmd_line_ptr:   .long   0               # (Header version 0x0202 or later)
 178                                         # If nonzero, a 32-bit pointer
 179                                         # to the kernel command line.
 180                                         # The command line should be
 181                                         # located between the start of
 182                                         # setup and the end of low
 183                                         # memory (0xa0000), or it may
 184                                         # get overwritten before it
 185                                         # gets read.  If this field is
 186                                         # used, there is no longer
 187                                         # anything magical about the
 188                                         # 0x90000 segment; the setup
 189                                         # can be located anywhere in
 190                                         # low memory 0x10000 or higher.
 191
 192 ramdisk_max:    .long 0x7fffffff
 193                                         # (Header version 0x0203 or later)
 194                                         # The highest safe address for
 195                                         # the contents of an initrd
 196                                         # The current kernel allows up to 4 GB,
 197                                         # but leave it at 2 GB to avoid
 198                                         # possible bootloader bugs.
 199
 200 kernel_alignment:  .long CONFIG_PHYSICAL_ALIGN  #physical addr alignment
 201                                                 #required for protected mode
 202                                                 #kernel
 203 #ifdef CONFIG_RELOCATABLE
 204 relocatable_kernel:    .byte 1
 205 #else
 206 relocatable_kernel:    .byte 0
 207 #endif
 208 min_alignment:          .byte MIN_KERNEL_ALIGN_LG2      # minimum alignment
 209 pad3:                   .word 0
 210
 211 cmdline_size:   .long   COMMAND_LINE_SIZE-1     #length of the command line,
 212                                                 #added with boot protocol
 213                                                 #version 2.06
 214
 215 hardware_subarch:       .long 0                 # subarchitecture, added with 2.07
 216                                                 # default to 0 for normal x86 PC
 217
 218 hardware_subarch_data:  .quad 0
 219
 220 payload_offset:         .long ZO_input_data
 221 payload_length:         .long ZO_z_input_len
 222
 223 setup_data:             .quad 0                 # 64-bit physical pointer to
 224                                                 # single linked list of
 225                                                 # struct setup_data
 226
 227 pref_address:           .quad LOAD_PHYSICAL_ADDR        # preferred load addr
 228
 229 #define ZO_INIT_SIZE    (ZO__end - ZO_startup_32 + ZO_z_extract_offset)
 230 #define VO_INIT_SIZE    (VO__end - VO__text)
 231 #if ZO_INIT_SIZE > VO_INIT_SIZE
 232 #define INIT_SIZE ZO_INIT_SIZE
 233 #else
 234 #define INIT_SIZE VO_INIT_SIZE
 235 #endif
 236 init_size:              .long INIT_SIZE         # kernel initialization size
 237
 238 # End of setup header #####################################################
 239
 240         .section ".entrytext", "ax"
 241 start_of_setup:
 242 #ifdef SAFE_RESET_DISK_CONTROLLER
 243 # Reset the disk controller.
 244         movw    $0x0000, %ax            # Reset disk controller
 245         movb    $0x80, %dl              # All disks
 246         int     $0x13
 247 #endif
 248
 249 # Force %es = %ds
 250         movw    %ds, %ax
 251         movw    %ax, %es
 252         cld
 253
 254 # Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
 255 # which happened to work by accident for the old code.  Recalculate the stack
 256 # pointer if %ss is invalid.  Otherwise leave it alone, LOADLIN sets up the
 257 # stack behind its own code, so we can't blindly put it directly past the heap.
 258
 259         movw    %ss, %dx
 260         cmpw    %ax, %dx        # %ds == %ss?
 261         movw    %sp, %dx
 262         je      2f              # -> assume %sp is reasonably set
 263
 264         # Invalid %ss, make up a new stack
 265         movw    $_end, %dx
 266         testb   $CAN_USE_HEAP, loadflags
 267         jz      1f
 268         movw    heap_end_ptr, %dx
 269 1:      addw    $STACK_SIZE, %dx
 270         jnc     2f
 271         xorw    %dx, %dx        # Prevent wraparound
 272
 273 2:      # Now %dx should point to the end of our stack space
 274         andw    $~3, %dx        # dword align (might as well...)
 275         jnz     3f
 276         movw    $0xfffc, %dx    # Make sure we're not zero
 277 3:      movw    %ax, %ss
 278         movzwl  %dx, %esp       # Clear upper half of %esp
 279         sti                     # Now we should have a working stack
 280
 281 # We will have entered with %cs = %ds+0x20, normalize %cs so
 282 # it is on par with the other segments.
 283         pushw   %ds
 284         pushw   $6f
 285         lretw
 286 6:
 287
 288 # Check signature at end of setup
 289         cmpl    $0x5a5aaa55, setup_sig
 290         jne     setup_bad
 291
 292 # Zero the bss
 293         movw    $__bss_start, %di
 294         movw    $_end+3, %cx
 295         xorl    %eax, %eax
 296         subw    %di, %cx
 297         shrw    $2, %cx
 298         rep; stosl
 299
 300 # Jump to C code (should not return)
 301         calll   main
 302
 303 # Setup corrupt somehow...
 304 setup_bad:
 305         movl    $setup_corrupt, %eax
 306         calll   puts
 307         # Fall through...
 308
 309         .globl  die
 310         .type   die, @function
 311 die:
 312         hlt
 313         jmp     die
 314
 315         .size   die, .-die
 316
 317         .section ".initdata", "a"
 318 setup_corrupt:
 319         .byte   7
 320         .string "No setup signature found...\n"