drivers/gpu/drm/nouveau/nvc0_grgpc.fuc

   1 /* fuc microcode for nvc0 PGRAPH/GPC
   2  *
   3  * Copyright 2011 Red Hat Inc.
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice shall be included in
  13  * all copies or substantial portions of the Software.
  14  *
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  18  * THE COPYRIGHT HOLDER(S) OR AUTHOR(S) BE LIABLE FOR ANY CLAIM, DAMAGES OR
  19  * OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
  20  * ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  21  * OTHER DEALINGS IN THE SOFTWARE.
  22  *
  23  * Authors: Ben Skeggs
  24  */
  25
  26 /* To build:
  27  *    m4 nvc0_grgpc.fuc | envyas -a -w -m fuc -V nva3 -o nvc0_grgpc.fuc.h
  28  */
  29
  30 /* TODO
  31  * - bracket certain functions with scratch writes, useful for debugging
  32  * - watchdog timer around ctx operations
  33  */
  34
  35 .section nvc0_grgpc_data
  36 include(`nvc0_graph.fuc')
  37 gpc_id:                 .b32 0
  38 gpc_mmio_list_head:     .b32 0
  39 gpc_mmio_list_tail:     .b32 0
  40
  41 tpc_count:              .b32 0
  42 tpc_mask:               .b32 0
  43 tpc_mmio_list_head:     .b32 0
  44 tpc_mmio_list_tail:     .b32 0
  45
  46 cmd_queue:              queue_init
  47
  48 // chipset descriptions
  49 chipsets:
  50 .b8  0xc0 0 0 0
  51 .b16 nvc0_gpc_mmio_head
  52 .b16 nvc0_gpc_mmio_tail
  53 .b16 nvc0_tpc_mmio_head
  54 .b16 nvc0_tpc_mmio_tail
  55 .b8  0xc1 0 0 0
  56 .b16 nvc0_gpc_mmio_head
  57 .b16 nvc1_gpc_mmio_tail
  58 .b16 nvc0_tpc_mmio_head
  59 .b16 nvc1_tpc_mmio_tail
  60 .b8  0xc3 0 0 0
  61 .b16 nvc0_gpc_mmio_head
  62 .b16 nvc0_gpc_mmio_tail
  63 .b16 nvc0_tpc_mmio_head
  64 .b16 nvc3_tpc_mmio_tail
  65 .b8  0xc4 0 0 0
  66 .b16 nvc0_gpc_mmio_head
  67 .b16 nvc0_gpc_mmio_tail
  68 .b16 nvc0_tpc_mmio_head
  69 .b16 nvc3_tpc_mmio_tail
  70 .b8  0xc8 0 0 0
  71 .b16 nvc0_gpc_mmio_head
  72 .b16 nvc0_gpc_mmio_tail
  73 .b16 nvc0_tpc_mmio_head
  74 .b16 nvc0_tpc_mmio_tail
  75 .b8  0xce 0 0 0
  76 .b16 nvc0_gpc_mmio_head
  77 .b16 nvc0_gpc_mmio_tail
  78 .b16 nvc0_tpc_mmio_head
  79 .b16 nvc3_tpc_mmio_tail
  80 .b8  0 0 0 0
  81
  82 // GPC mmio lists
  83 nvc0_gpc_mmio_head:
  84 mmctx_data(0x000380, 1)
  85 mmctx_data(0x000400, 6)
  86 mmctx_data(0x000450, 9)
  87 mmctx_data(0x000600, 1)
  88 mmctx_data(0x000684, 1)
  89 mmctx_data(0x000700, 5)
  90 mmctx_data(0x000800, 1)
  91 mmctx_data(0x000808, 3)
  92 mmctx_data(0x000828, 1)
  93 mmctx_data(0x000830, 1)
  94 mmctx_data(0x0008d8, 1)
  95 mmctx_data(0x0008e0, 1)
  96 mmctx_data(0x0008e8, 6)
  97 mmctx_data(0x00091c, 1)
  98 mmctx_data(0x000924, 3)
  99 mmctx_data(0x000b00, 1)
 100 mmctx_data(0x000b08, 6)
 101 mmctx_data(0x000bb8, 1)
 102 mmctx_data(0x000c08, 1)
 103 mmctx_data(0x000c10, 8)
 104 mmctx_data(0x000c80, 1)
 105 mmctx_data(0x000c8c, 1)
 106 mmctx_data(0x001000, 3)
 107 mmctx_data(0x001014, 1)
 108 nvc0_gpc_mmio_tail:
 109 mmctx_data(0x000c6c, 1);
 110 nvc1_gpc_mmio_tail:
 111
 112 // TPC mmio lists
 113 nvc0_tpc_mmio_head:
 114 mmctx_data(0x000018, 1)
 115 mmctx_data(0x00003c, 1)
 116 mmctx_data(0x000048, 1)
 117 mmctx_data(0x000064, 1)
 118 mmctx_data(0x000088, 1)
 119 mmctx_data(0x000200, 6)
 120 mmctx_data(0x00021c, 2)
 121 mmctx_data(0x000300, 6)
 122 mmctx_data(0x0003d0, 1)
 123 mmctx_data(0x0003e0, 2)
 124 mmctx_data(0x000400, 3)
 125 mmctx_data(0x000420, 1)
 126 mmctx_data(0x0004b0, 1)
 127 mmctx_data(0x0004e8, 1)
 128 mmctx_data(0x0004f4, 1)
 129 mmctx_data(0x000520, 2)
 130 mmctx_data(0x000604, 4)
 131 mmctx_data(0x000644, 20)
 132 mmctx_data(0x000698, 1)
 133 mmctx_data(0x000750, 2)
 134 nvc0_tpc_mmio_tail:
 135 mmctx_data(0x000758, 1)
 136 mmctx_data(0x0002c4, 1)
 137 mmctx_data(0x0004bc, 1)
 138 mmctx_data(0x0006e0, 1)
 139 nvc3_tpc_mmio_tail:
 140 mmctx_data(0x000544, 1)
 141 nvc1_tpc_mmio_tail:
 142
 143
 144 .section nvc0_grgpc_code
 145 bra init
 146 define(`include_code')
 147 include(`nvc0_graph.fuc')
 148
 149 // reports an exception to the host
 150 //
 151 // In: $r15 error code (see nvc0_graph.fuc)
 152 //
 153 error:
 154         push $r14
 155         mov $r14 -0x67ec        // 0x9814
 156         sethi $r14 0x400000
 157         call nv_wr32            // HUB_CTXCTL_CC_SCRATCH[5] = error code
 158         add b32 $r14 0x41c
 159         mov $r15 1
 160         call nv_wr32            // HUB_CTXCTL_INTR_UP_SET
 161         pop $r14
 162         ret
 163
 164 // GPC fuc initialisation, executed by triggering ucode start, will
 165 // fall through to main loop after completion.
 166 //
 167 // Input:
 168 //   CC_SCRATCH[0]: chipset (PMC_BOOT_0 read returns 0x0bad0bad... sigh)
 169 //   CC_SCRATCH[1]: context base
 170 //
 171 // Output:
 172 //   CC_SCRATCH[0]:
 173 //           31:31: set to signal completion
 174 //   CC_SCRATCH[1]:
 175 //            31:0: GPC context size
 176 //
 177 init:
 178         clear b32 $r0
 179         mov $sp $r0
 180
 181         // enable fifo access
 182         mov $r1 0x1200
 183         mov $r2 2
 184         iowr I[$r1 + 0x000] $r2         // FIFO_ENABLE
 185
 186         // setup i0 handler, and route all interrupts to it
 187         mov $r1 ih
 188         mov $iv0 $r1
 189         mov $r1 0x400
 190         iowr I[$r1 + 0x300] $r0         // INTR_DISPATCH
 191
 192         // enable fifo interrupt
 193         mov $r2 4
 194         iowr I[$r1 + 0x000] $r2         // INTR_EN_SET
 195
 196         // enable interrupts
 197         bset $flags ie0
 198
 199         // figure out which GPC we are, and how many TPCs we have
 200         mov $r1 0x608
 201         shl b32 $r1 6
 202         iord $r2 I[$r1 + 0x000]         // UNITS
 203         mov $r3 1
 204         and $r2 0x1f
 205         shl b32 $r3 $r2
 206         sub b32 $r3 1
 207         st b32 D[$r0 + tpc_count] $r2
 208         st b32 D[$r0 + tpc_mask] $r3
 209         add b32 $r1 0x400
 210         iord $r2 I[$r1 + 0x000]         // MYINDEX
 211         st b32 D[$r0 + gpc_id] $r2
 212
 213         // find context data for this chipset
 214         mov $r2 0x800
 215         shl b32 $r2 6
 216         iord $r2 I[$r2 + 0x000]         // CC_SCRATCH[0]
 217         mov $r1 chipsets - 12
 218         init_find_chipset:
 219                 add b32 $r1 12
 220                 ld b32 $r3 D[$r1 + 0x00]
 221                 cmpu b32 $r3 $r2
 222                 bra e init_context
 223                 cmpu b32 $r3 0
 224                 bra ne init_find_chipset
 225                 // unknown chipset
 226                 ret
 227
 228         // initialise context base, and size tracking
 229         init_context:
 230         mov $r2 0x800
 231         shl b32 $r2 6
 232         iord $r2 I[$r2 + 0x100] // CC_SCRATCH[1], initial base
 233         clear b32 $r3           // track GPC context size here
 234
 235         // set mmctx base addresses now so we don't have to do it later,
 236         // they don't currently ever change
 237         mov $r4 0x700
 238         shl b32 $r4 6
 239         shr b32 $r5 $r2 8
 240         iowr I[$r4 + 0x000] $r5         // MMCTX_SAVE_SWBASE
 241         iowr I[$r4 + 0x100] $r5         // MMCTX_LOAD_SWBASE
 242
 243         // calculate GPC mmio context size, store the chipset-specific
 244         // mmio list pointers somewhere we can get at them later without
 245         // re-parsing the chipset list
 246         clear b32 $r14
 247         clear b32 $r15
 248         ld b16 $r14 D[$r1 + 4]
 249         ld b16 $r15 D[$r1 + 6]
 250         st b16 D[$r0 + gpc_mmio_list_head] $r14
 251         st b16 D[$r0 + gpc_mmio_list_tail] $r15
 252         call mmctx_size
 253         add b32 $r2 $r15
 254         add b32 $r3 $r15
 255
 256         // calculate per-TPC mmio context size, store the list pointers
 257         ld b16 $r14 D[$r1 + 8]
 258         ld b16 $r15 D[$r1 + 10]
 259         st b16 D[$r0 + tpc_mmio_list_head] $r14
 260         st b16 D[$r0 + tpc_mmio_list_tail] $r15
 261         call mmctx_size
 262         ld b32 $r14 D[$r0 + tpc_count]
 263         mulu $r14 $r15
 264         add b32 $r2 $r14
 265         add b32 $r3 $r14
 266
 267         // round up base/size to 256 byte boundary (for strand SWBASE)
 268         add b32 $r4 0x1300
 269         shr b32 $r3 2
 270         iowr I[$r4 + 0x000] $r3         // MMCTX_LOAD_COUNT, wtf for?!?
 271         shr b32 $r2 8
 272         shr b32 $r3 6
 273         add b32 $r2 1
 274         add b32 $r3 1
 275         shl b32 $r2 8
 276         shl b32 $r3 8
 277
 278         // calculate size of strand context data
 279         mov b32 $r15 $r2
 280         call strand_ctx_init
 281         add b32 $r3 $r15
 282
 283         // save context size, and tell HUB we're done
 284         mov $r1 0x800
 285         shl b32 $r1 6
 286         iowr I[$r1 + 0x100] $r3         // CC_SCRATCH[1]  = context size
 287         add b32 $r1 0x800
 288         clear b32 $r2
 289         bset $r2 31
 290         iowr I[$r1 + 0x000] $r2         // CC_SCRATCH[0] |= 0x80000000
 291
 292 // Main program loop, very simple, sleeps until woken up by the interrupt
 293 // handler, pulls a command from the queue and executes its handler
 294 //
 295 main:
 296         bset $flags $p0
 297         sleep $p0
 298         mov $r13 cmd_queue
 299         call queue_get
 300         bra $p1 main
 301
 302         // 0x0000-0x0003 are all context transfers
 303         cmpu b32 $r14 0x04
 304         bra nc main_not_ctx_xfer
 305                 // fetch $flags and mask off $p1/$p2
 306                 mov $r1 $flags
 307                 mov $r2 0x0006
 308                 not b32 $r2
 309                 and $r1 $r2
 310                 // set $p1/$p2 according to transfer type
 311                 shl b32 $r14 1
 312                 or $r1 $r14
 313                 mov $flags $r1
 314                 // transfer context data
 315                 call ctx_xfer
 316                 bra main
 317
 318         main_not_ctx_xfer:
 319         shl b32 $r15 $r14 16
 320         or $r15 E_BAD_COMMAND
 321         call error
 322         bra main
 323
 324 // interrupt handler
 325 ih:
 326         push $r8
 327         mov $r8 $flags
 328         push $r8
 329         push $r9
 330         push $r10
 331         push $r11
 332         push $r13
 333         push $r14
 334         push $r15
 335
 336         // incoming fifo command?
 337         iord $r10 I[$r0 + 0x200]        // INTR
 338         and $r11 $r10 0x00000004
 339         bra e ih_no_fifo
 340                 // queue incoming fifo command for later processing
 341                 mov $r11 0x1900
 342                 mov $r13 cmd_queue
 343                 iord $r14 I[$r11 + 0x100]       // FIFO_CMD
 344                 iord $r15 I[$r11 + 0x000]       // FIFO_DATA
 345                 call queue_put
 346                 add b32 $r11 0x400
 347                 mov $r14 1
 348                 iowr I[$r11 + 0x000] $r14       // FIFO_ACK
 349
 350         // ack, and wake up main()
 351         ih_no_fifo:
 352         iowr I[$r0 + 0x100] $r10        // INTR_ACK
 353
 354         pop $r15
 355         pop $r14
 356         pop $r13
 357         pop $r11
 358         pop $r10
 359         pop $r9
 360         pop $r8
 361         mov $flags $r8
 362         pop $r8
 363         bclr $flags $p0
 364         iret
 365
 366 // Set this GPC's bit in HUB_BAR, used to signal completion of various
 367 // activities to the HUB fuc
 368 //
 369 hub_barrier_done:
 370         mov $r15 1
 371         ld b32 $r14 D[$r0 + gpc_id]
 372         shl b32 $r15 $r14
 373         mov $r14 -0x6be8        // 0x409418 - HUB_BAR_SET
 374         sethi $r14 0x400000
 375         call nv_wr32
 376         ret
 377
 378 // Disables various things, waits a bit, and re-enables them..
 379 //
 380 // Not sure how exactly this helps, perhaps "ENABLE" is not such a
 381 // good description for the bits we turn off?  Anyways, without this,
 382 // funny things happen.
 383 //
 384 ctx_redswitch:
 385         mov $r14 0x614
 386         shl b32 $r14 6
 387         mov $r15 0x020
 388         iowr I[$r14] $r15       // GPC_RED_SWITCH = POWER
 389         mov $r15 8
 390         ctx_redswitch_delay:
 391                 sub b32 $r15 1
 392                 bra ne ctx_redswitch_delay
 393         mov $r15 0xa20
 394         iowr I[$r14] $r15       // GPC_RED_SWITCH = UNK11, ENABLE, POWER
 395         ret
 396
 397 // Transfer GPC context data between GPU and storage area
 398 //
 399 // In: $r15 context base address
 400 //     $p1 clear on save, set on load
 401 //     $p2 set if opposite direction done/will be done, so:
 402 //              on save it means: "a load will follow this save"
 403 //              on load it means: "a save preceeded this load"
 404 //
 405 ctx_xfer:
 406         // set context base address
 407         mov $r1 0xa04
 408         shl b32 $r1 6
 409         iowr I[$r1 + 0x000] $r15// MEM_BASE
 410         bra not $p1 ctx_xfer_not_load
 411                 call ctx_redswitch
 412         ctx_xfer_not_load:
 413
 414         // strands
 415         mov $r1 0x4afc
 416         sethi $r1 0x20000
 417         mov $r2 0xc
 418         iowr I[$r1] $r2         // STRAND_CMD(0x3f) = 0x0c
 419         call strand_wait
 420         mov $r2 0x47fc
 421         sethi $r2 0x20000
 422         iowr I[$r2] $r0         // STRAND_FIRST_GENE(0x3f) = 0x00
 423         xbit $r2 $flags $p1
 424         add b32 $r2 3
 425         iowr I[$r1] $r2         // STRAND_CMD(0x3f) = 0x03/0x04 (SAVE/LOAD)
 426
 427         // mmio context
 428         xbit $r10 $flags $p1    // direction
 429         or $r10 2               // first
 430         mov $r11 0x0000
 431         sethi $r11 0x500000
 432         ld b32 $r12 D[$r0 + gpc_id]
 433         shl b32 $r12 15
 434         add b32 $r11 $r12       // base = NV_PGRAPH_GPCn
 435         ld b32 $r12 D[$r0 + gpc_mmio_list_head]
 436         ld b32 $r13 D[$r0 + gpc_mmio_list_tail]
 437         mov $r14 0              // not multi
 438         call mmctx_xfer
 439
 440         // per-TPC mmio context
 441         xbit $r10 $flags $p1    // direction
 442         or $r10 4               // last
 443         mov $r11 0x4000
 444         sethi $r11 0x500000     // base = NV_PGRAPH_GPC0_TPC0
 445         ld b32 $r12 D[$r0 + gpc_id]
 446         shl b32 $r12 15
 447         add b32 $r11 $r12       // base = NV_PGRAPH_GPCn_TPC0
 448         ld b32 $r12 D[$r0 + tpc_mmio_list_head]
 449         ld b32 $r13 D[$r0 + tpc_mmio_list_tail]
 450         ld b32 $r15 D[$r0 + tpc_mask]
 451         mov $r14 0x800          // stride = 0x800
 452         call mmctx_xfer
 453
 454         // wait for strands to finish
 455         call strand_wait
 456
 457         // if load, or a save without a load following, do some
 458         // unknown stuff that's done after finishing a block of
 459         // strand commands
 460         bra $p1 ctx_xfer_post
 461         bra not $p2 ctx_xfer_done
 462         ctx_xfer_post:
 463                 mov $r1 0x4afc
 464                 sethi $r1 0x20000
 465                 mov $r2 0xd
 466                 iowr I[$r1] $r2         // STRAND_CMD(0x3f) = 0x0d
 467                 call strand_wait
 468
 469         // mark completion in HUB's barrier
 470         ctx_xfer_done:
 471         call hub_barrier_done
 472         ret
 473
 474 .align 256