arch/arm/lib/getuser.S

   1 /*
   2  *  linux/arch/arm/lib/getuser.S
   3  *
   4  *  Copyright (C) 2001 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  11  *
  12  * These functions have a non-standard call interface to make them more
  13  * efficient, especially as they return an error value in addition to
  14  * the "real" return value.
  15  *
  16  * __get_user_X
  17  *
  18  * Inputs:      r0 contains the address
  19  * Outputs:     r0 is the error code
  20  *              r2, r3 contains the zero-extended value
  21  *              lr corrupted
  22  *
  23  * No other registers must be altered.  (see <asm/uaccess.h>
  24  * for specific ASM register usage).
  25  *
  26  * Note that ADDR_LIMIT is either 0 or 0xc0000000.
  27  * Note also that it is intended that __get_user_bad is not global.
  28  */
  29 #include <linux/linkage.h>
  30 #include <asm/errno.h>
  31
  32 ENTRY(__get_user_1)
  33 1:      ldrbt   r2, [r0]
  34         mov     r0, #0
  35         mov     pc, lr
  36 ENDPROC(__get_user_1)
  37
  38 ENTRY(__get_user_2)
  39 #ifdef CONFIG_THUMB2_KERNEL
  40 2:      ldrbt   r2, [r0]
  41 3:      ldrbt   r3, [r0, #1]
  42 #else
  43 2:      ldrbt   r2, [r0], #1
  44 3:      ldrbt   r3, [r0]
  45 #endif
  46 #ifndef __ARMEB__
  47         orr     r2, r2, r3, lsl #8
  48 #else
  49         orr     r2, r3, r2, lsl #8
  50 #endif
  51         mov     r0, #0
  52         mov     pc, lr
  53 ENDPROC(__get_user_2)
  54
  55 ENTRY(__get_user_4)
  56 4:      ldrt    r2, [r0]
  57         mov     r0, #0
  58         mov     pc, lr
  59 ENDPROC(__get_user_4)
  60
  61 __get_user_bad:
  62         mov     r2, #0
  63         mov     r0, #-EFAULT
  64         mov     pc, lr
  65 ENDPROC(__get_user_bad)
  66
  67 .pushsection __ex_table, "a"
  68         .long   1b, __get_user_bad
  69         .long   2b, __get_user_bad
  70         .long   3b, __get_user_bad
  71         .long   4b, __get_user_bad
  72 .popsection