arch/arm/boot/compressed/vmlinux.lds.in

   1 /*
   2  *  linux/arch/arm/boot/compressed/vmlinux.lds.in
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10 OUTPUT_ARCH(arm)
  11 ENTRY(_start)
  12 SECTIONS
  13 {
  14   /DISCARD/ : {
  15     *(.ARM.exidx*)
  16     *(.ARM.extab*)
  17     /*
  18      * Discard any r/w data - this produces a link error if we have any,
  19      * which is required for PIC decompression.  Local data generates
  20      * GOTOFF relocations, which prevents it being relocated independently
  21      * of the text/got segments.
  22      */
  23     *(.data)
  24   }
  25
  26   . = TEXT_START;
  27   _text = .;
  28
  29   .text : {
  30     _start = .;
  31     *(.start)
  32     *(.text)
  33     *(.text.*)
  34     *(.fixup)
  35     *(.gnu.warning)
  36     *(.glue_7t)
  37     *(.glue_7)
  38   }
  39   .rodata : {
  40     *(.rodata)
  41     *(.rodata.*)
  42   }
  43   .piggydata : {
  44     *(.piggydata)
  45   }
  46
  47   . = ALIGN(4);
  48   _etext = .;
  49
  50   .got.plt              : { *(.got.plt) }
  51   _got_start = .;
  52   .got                  : { *(.got) }
  53   _got_end = .;
  54   _edata = .;
  55
  56   . = BSS_START;
  57   __bss_start = .;
  58   .bss                  : { *(.bss) }
  59   _end = .;
  60
  61   . = ALIGN(8);         /* the stack must be 64-bit aligned */
  62   .stack                : { *(.stack) }
  63
  64   .stab 0               : { *(.stab) }
  65   .stabstr 0            : { *(.stabstr) }
  66   .stab.excl 0          : { *(.stab.excl) }
  67   .stab.exclstr 0       : { *(.stab.exclstr) }
  68   .stab.index 0         : { *(.stab.index) }
  69   .stab.indexstr 0      : { *(.stab.indexstr) }
  70   .comment 0            : { *(.comment) }
  71 }
  72