arch/arm/lib/putuser.S

   1 /*
   2  *  linux/arch/arm/lib/putuser.S
   3  *
   4  *  Copyright (C) 2001 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  11  *
  12  * These functions have a non-standard call interface to make
  13  * them more efficient, especially as they return an error
  14  * value in addition to the "real" return value.
  15  *
  16  * __put_user_X
  17  *
  18  * Inputs:      r0 contains the address
  19  *              r2, r3 contains the value
  20  * Outputs:     r0 is the error code
  21  *              lr corrupted
  22  *
  23  * No other registers must be altered.  (see include/asm-arm/uaccess.h
  24  * for specific ASM register usage).
  25  *
  26  * Note that ADDR_LIMIT is either 0 or 0xc0000000
  27  * Note also that it is intended that __put_user_bad is not global.
  28  */
  29 #include <asm/constants.h>
  30 #include <asm/thread_info.h>
  31 #include <asm/errno.h>
  32
  33         .global __put_user_1
  34 __put_user_1:
  35 1:      strbt   r2, [r0]
  36         mov     r0, #0
  37         mov     pc, lr
  38
  39         .global __put_user_2
  40 __put_user_2:
  41         mov     ip, r2, lsr #8
  42 #ifndef __ARMEB__
  43 2:      strbt   r2, [r0], #1
  44 3:      strbt   ip, [r0]
  45 #else
  46 2:      strbt   ip, [r0], #1
  47 3:      strbt   r2, [r0]
  48 #endif
  49         mov     r0, #0
  50         mov     pc, lr
  51
  52         .global __put_user_4
  53 __put_user_4:
  54 4:      strt    r2, [r0]
  55         mov     r0, #0
  56         mov     pc, lr
  57
  58         .global __put_user_8
  59 __put_user_8:
  60 5:      strt    r2, [r0], #4
  61 6:      strt    r3, [r0]
  62         mov     r0, #0
  63         mov     pc, lr
  64
  65 __put_user_bad:
  66         mov     r0, #-EFAULT
  67         mov     pc, lr
  68
  69 .section __ex_table, "a"
  70         .long   1b, __put_user_bad
  71         .long   2b, __put_user_bad
  72         .long   3b, __put_user_bad
  73         .long   4b, __put_user_bad
  74         .long   5b, __put_user_bad
  75         .long   6b, __put_user_bad
  76 .previous