arch/m68knommu/platform/68328/head-pilot.S

   1 /*
   2  * linux/arch/m68knommu/platform/68328/head-rom.S
   3  * - A startup file for the MC68328
   4  *
   5  * Copyright (C) 1998  D. Jeff Dionne <jeff@ryeham.ee.ryerson.ca>,
   6  *                     Kenneth Albanowski <kjahds@kjahds.com>,
   7  *                     The Silver Hammer Group, Ltd.
   8  *
   9  * (c) 1995, Dionne & Associates
  10  * (c) 1995, DKG Display Tech.
  11  */
  12
  13 #define ASSEMBLY
  14
  15 #define IMMED #
  16 #define DBG_PUTC(x)     moveb IMMED x, 0xfffff907
  17
  18 #include <linux/config.h>
  19
  20 .global _stext
  21 .global _start
  22
  23 .global _rambase
  24 .global __ramvec
  25 .global _ramvec
  26 .global _ramstart
  27 .global _ramend
  28
  29 .global penguin_bits
  30
  31 #ifdef CONFIG_PILOT
  32
  33 #define IMR 0xFFFFF304
  34
  35         .data
  36         .align 16
  37
  38 penguin_bits:
  39 #include "bootlogo.rh"
  40
  41 #endif
  42
  43 /*****************************************************************************/
  44
  45 .data
  46
  47 /*
  48  *      Set up the usable of RAM stuff. Size of RAM is determined then
  49  *      an initial stack set up at the end.
  50  */
  51 .align 4
  52 _ramvec:
  53 .long   0
  54 _rambase:
  55 .long   0
  56 _ramstart:
  57 .long   0
  58 _ramend:
  59 .long   0
  60
  61 .text
  62
  63 _start:
  64 _stext:
  65
  66
  67 #ifdef CONFIG_M68328
  68
  69 #ifdef CONFIG_PILOT
  70         .byte 0x4e, 0xfa, 0x00, 0x0a /* Jmp +X bytes */
  71         .byte 'b', 'o', 'o', 't'
  72         .word 10000
  73
  74         nop
  75 #endif
  76
  77         moveq   #0, %d0
  78         movew   %d0, 0xfffff618 /* Watchdog off */
  79         movel   #0x00011f07, 0xfffff114 /* CS A1 Mask */
  80
  81         movew   #0x0800, 0xfffff906 /* Ignore CTS */
  82         movew   #0x010b, 0xfffff902 /* BAUD to 9600 */
  83
  84         movew   #0x2410, 0xfffff200 /* PLLCR */
  85         movew   #0x123, 0xfffff202 /* PLLFSR */
  86
  87 #ifdef CONFIG_PILOT
  88         moveb   #0, 0xfffffA27 /* LCKCON */
  89         movel   #_start, 0xfffffA00 /* LSSA */
  90         moveb   #0xa, 0xfffffA05 /* LVPW */
  91         movew   #0x9f, 0xFFFFFa08 /* LXMAX */
  92         movew   #0x9f, 0xFFFFFa0a /* LYMAX */
  93         moveb   #9, 0xfffffa29 /* LBAR */
  94         moveb   #0, 0xfffffa25 /* LPXCD */
  95         moveb   #0x04, 0xFFFFFa20 /* LPICF */
  96         moveb   #0x58, 0xfffffA27 /* LCKCON */
  97         moveb   #0x85, 0xfffff429 /* PFDATA */
  98         moveb   #0xd8, 0xfffffA27 /* LCKCON */
  99         moveb   #0xc5, 0xfffff429 /* PFDATA */
 100         moveb   #0xd5, 0xfffff429 /* PFDATA */
 101
 102         moveal  #0x00100000, %a3
 103         moveal  #0x100ffc00, %a4
 104 #endif /* CONFIG_PILOT */
 105
 106 #endif /* CONFIG_M68328 */
 107
 108         movew   #0x2700, %sr
 109         lea     %a4@(-4), %sp
 110
 111         DBG_PUTC('\r')
 112         DBG_PUTC('\n')
 113         DBG_PUTC('A')
 114
 115         moveq   #0,%d0
 116         movew   #16384, %d0  /* PLL settle wait loop */
 117 L0:
 118         subw    #1, %d0
 119         bne     L0
 120
 121         DBG_PUTC('B')
 122
 123         /* Copy command line from beginning of RAM (+16) to end of bss */
 124         movel   #__ramvec, %d7
 125         addl    #16, %d7
 126         moveal  %d7, %a0
 127         moveal  #_ebss, %a1
 128         lea     %a1@(512), %a2
 129
 130         DBG_PUTC('C')
 131
 132         /* Copy %a0 to %a1 until %a1 == %a2 */
 133 L2:
 134         movel   %a0@+, %d0
 135         movel   %d0, %a1@+
 136         cmpal   %a1, %a2
 137         bhi     L2
 138
 139         /* Copy data+init segment from ROM to RAM */
 140         moveal  #_etext, %a0
 141         moveal  #_sdata, %a1
 142         moveal  #__init_end, %a2
 143
 144         DBG_PUTC('D')
 145
 146         /* Copy %a0 to %a1 until %a1 == %a2 */
 147 LD1:
 148         movel   %a0@+, %d0
 149         movel   %d0, %a1@+
 150         cmpal   %a1, %a2
 151         bhi     LD1
 152
 153         DBG_PUTC('E')
 154
 155         moveal  #_sbss, %a0
 156         moveal  #_ebss, %a1
 157
 158         /* Copy 0 to %a0 until %a0 == %a1 */
 159 L1:
 160         movel   #0, %a0@+
 161         cmpal   %a0, %a1
 162         bhi     L1
 163
 164         DBG_PUTC('F')
 165
 166         /* Copy command line from end of bss to command line */
 167         moveal  #_ebss, %a0
 168         moveal  #command_line, %a1
 169         lea     %a1@(512), %a2
 170
 171         DBG_PUTC('G')
 172
 173         /* Copy %a0 to %a1 until %a1 == %a2 */
 174 L3:
 175         movel   %a0@+, %d0
 176         movel   %d0, %a1@+
 177         cmpal   %a1, %a2
 178         bhi     L3
 179
 180         movel   #_sdata, %d0
 181         movel   %d0, _rambase
 182         movel   #_ebss, %d0
 183         movel   %d0, _ramstart
 184
 185         movel   %a4, %d0
 186         subl    #4096, %d0      /* Reserve 4K of stack */
 187         moveq   #79, %d7
 188         movel   %d0, _ramend
 189
 190         movel   %a3, %d0
 191         movel   %d0, rom_length
 192
 193         pea     0
 194         pea     env
 195         pea     %sp@(4)
 196         pea     0
 197
 198         DBG_PUTC('H')
 199
 200 #ifdef CONFIG_PILOT
 201         movel   #penguin_bits, 0xFFFFFA00
 202         moveb   #10, 0xFFFFFA05
 203         movew   #160, 0xFFFFFA08
 204         movew   #160, 0xFFFFFA0A
 205 #endif /* CONFIG_PILOT */
 206
 207         DBG_PUTC('I')
 208
 209         lea     init_thread_union, %a0
 210         lea     0x2000(%a0), %sp
 211
 212         DBG_PUTC('J')
 213         DBG_PUTC('\r')
 214         DBG_PUTC('\n')
 215
 216         jsr     start_kernel
 217 _exit:
 218
 219         jmp     _exit
 220
 221
 222         .data
 223 env:
 224         .long   0