arch/arm/lib/putuser.S

   1 /*
   2  *  linux/arch/arm/lib/putuser.S
   3  *
   4  *  Copyright (C) 2001 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  11  *
  12  * These functions have a non-standard call interface to make
  13  * them more efficient, especially as they return an error
  14  * value in addition to the "real" return value.
  15  *
  16  * __put_user_X
  17  *
  18  * Inputs:      r0 contains the address
  19  *              r2, r3 contains the value
  20  * Outputs:     r0 is the error code
  21  *              lr corrupted
  22  *
  23  * No other registers must be altered.  (see <asm/uaccess.h>
  24  * for specific ASM register usage).
  25  *
  26  * Note that ADDR_LIMIT is either 0 or 0xc0000000
  27  * Note also that it is intended that __put_user_bad is not global.
  28  */
  29 #include <linux/linkage.h>
  30 #include <asm/errno.h>
  31
  32 ENTRY(__put_user_1)
  33 1:      strbt   r2, [r0]
  34         mov     r0, #0
  35         mov     pc, lr
  36 ENDPROC(__put_user_1)
  37
  38 ENTRY(__put_user_2)
  39         mov     ip, r2, lsr #8
  40 #ifdef CONFIG_THUMB2_KERNEL
  41 #ifndef __ARMEB__
  42 2:      strbt   r2, [r0]
  43 3:      strbt   ip, [r0, #1]
  44 #else
  45 2:      strbt   ip, [r0]
  46 3:      strbt   r2, [r0, #1]
  47 #endif
  48 #else   /* !CONFIG_THUMB2_KERNEL */
  49 #ifndef __ARMEB__
  50 2:      strbt   r2, [r0], #1
  51 3:      strbt   ip, [r0]
  52 #else
  53 2:      strbt   ip, [r0], #1
  54 3:      strbt   r2, [r0]
  55 #endif
  56 #endif  /* CONFIG_THUMB2_KERNEL */
  57         mov     r0, #0
  58         mov     pc, lr
  59 ENDPROC(__put_user_2)
  60
  61 ENTRY(__put_user_4)
  62 4:      strt    r2, [r0]
  63         mov     r0, #0
  64         mov     pc, lr
  65 ENDPROC(__put_user_4)
  66
  67 ENTRY(__put_user_8)
  68 #ifdef CONFIG_THUMB2_KERNEL
  69 5:      strt    r2, [r0]
  70 6:      strt    r3, [r0, #4]
  71 #else
  72 5:      strt    r2, [r0], #4
  73 6:      strt    r3, [r0]
  74 #endif
  75         mov     r0, #0
  76         mov     pc, lr
  77 ENDPROC(__put_user_8)
  78
  79 __put_user_bad:
  80         mov     r0, #-EFAULT
  81         mov     pc, lr
  82 ENDPROC(__put_user_bad)
  83
  84 .section __ex_table, "a"
  85         .long   1b, __put_user_bad
  86         .long   2b, __put_user_bad
  87         .long   3b, __put_user_bad
  88         .long   4b, __put_user_bad
  89         .long   5b, __put_user_bad
  90         .long   6b, __put_user_bad
  91 .previous