arch/um/kernel/uml.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2 #include <asm/page.h>
   3
   4 OUTPUT_FORMAT(ELF_FORMAT)
   5 OUTPUT_ARCH(ELF_ARCH)
   6 ENTRY(_start)
   7 jiffies = jiffies_64;
   8
   9 SECTIONS
  10 {
  11   /* This must contain the right address - not quite the default ELF one.*/
  12   PROVIDE (__executable_start = START);
  13   /* Static binaries stick stuff here, like the sigreturn trampoline,
  14    * invisibly to objdump.  So, just make __binary_start equal to the very
  15    * beginning of the executable, and if there are unmapped pages after this,
  16    * they are forever unusable.
  17    */
  18   __binary_start = START;
  19
  20   . = START + SIZEOF_HEADERS;
  21
  22   _text = .;
  23   _stext = .;
  24   __init_begin = .;
  25   .init.text : {
  26         _sinittext = .;
  27         INIT_TEXT
  28         _einittext = .;
  29   }
  30   . = ALIGN(PAGE_SIZE);
  31
  32   .text      :
  33   {
  34     TEXT_TEXT
  35     SCHED_TEXT
  36     LOCK_TEXT
  37     *(.fixup)
  38     /* .gnu.warning sections are handled specially by elf32.em.  */
  39     *(.gnu.warning)
  40     *(.gnu.linkonce.t*)
  41   }
  42
  43   . = ALIGN(PAGE_SIZE);
  44   .syscall_stub : {
  45         __syscall_stub_start = .;
  46         *(.__syscall_stub*)
  47         __syscall_stub_end = .;
  48   }
  49
  50   #include "asm/common.lds.S"
  51
  52   init.data : { INIT_DATA }
  53   .data    :
  54   {
  55     . = ALIGN(KERNEL_STACK_SIZE);               /* init_task */
  56     *(.data.init_task)
  57     . = ALIGN(KERNEL_STACK_SIZE);
  58     *(.data.init_irqstack)
  59     DATA_DATA
  60     *(.gnu.linkonce.d*)
  61     CONSTRUCTORS
  62   }
  63   .data1   : { *(.data1) }
  64   .ctors         :
  65   {
  66     *(.ctors)
  67   }
  68   .dtors         :
  69   {
  70     *(.dtors)
  71   }
  72
  73   .got           : { *(.got.plt) *(.got) }
  74   .dynamic       : { *(.dynamic) }
  75   .tdata          : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
  76   .tbss           : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
  77   /* We want the small data sections together, so single-instruction offsets
  78      can access them all, and initialized data all before uninitialized, so
  79      we can shorten the on-disk segment size.  */
  80   .sdata     : { *(.sdata) }
  81   _edata  =  .;
  82   PROVIDE (edata = .);
  83   . = ALIGN(PAGE_SIZE);
  84   .sbss      :
  85   {
  86    __bss_start = .;
  87    PROVIDE(_bss_start = .);
  88    *(.sbss)
  89    *(.scommon)
  90   }
  91   .bss       :
  92   {
  93    *(.dynbss)
  94    *(.bss)
  95    *(COMMON)
  96   }
  97   _end = .;
  98   PROVIDE (end = .);
  99
 100   STABS_DEBUG
 101
 102   DWARF_DEBUG
 103 }