| blob | 721ac23251371bccd0e459c75d4a0d3e0acc58cd |
1 /*
2 *
3 * Copyright (C) 1991, 1992 Linus Torvalds
4 */
6 /*
7 * entry.S contains the system-call and fault low-level handling routines.
8 * This also contains the timer-interrupt handler, as well as all interrupts
9 * and faults that can result in a task-switch.
10 *
11 * NOTE: This code handles signal-recognition, which happens every time
12 * after a timer-interrupt and after each system call.
13 *
14 * I changed all the .align's to 4 (16 byte alignment), as that's faster
15 * on a 486.
16 *
17 * Stack layout in 'syscall_exit':
18 * ptrace needs to have all regs on the stack.
19 * if the order here is changed, it needs to be
20 * updated in fork.c:copy_process, signal.c:do_signal,
21 * ptrace.c and ptrace.h
22 *
23 * 0(%esp) - %ebx
24 * 4(%esp) - %ecx
25 * 8(%esp) - %edx
26 * C(%esp) - %esi
27 * 10(%esp) - %edi
28 * 14(%esp) - %ebp
29 * 18(%esp) - %eax
30 * 1C(%esp) - %ds
31 * 20(%esp) - %es
32 * 24(%esp) - %fs
33 * 28(%esp) - %gs saved iff !CONFIG_X86_32_LAZY_GS
34 * 2C(%esp) - orig_eax
35 * 30(%esp) - %eip
36 * 34(%esp) - %cs
37 * 38(%esp) - %eflags
38 * 3C(%esp) - %oldesp
39 * 40(%esp) - %oldss
40 *
41 * "current" is in register %ebx during any slow entries.
42 */
44 #include <linux/linkage.h>
45 #include <asm/thread_info.h>
46 #include <asm/irqflags.h>
47 #include <asm/errno.h>
48 #include <asm/segment.h>
49 #include <asm/smp.h>
50 #include <asm/page_types.h>
51 #include <asm/desc.h>
52 #include <asm/percpu.h>
53 #include <asm/dwarf2.h>
54 #include <asm/processor-flags.h>
55 #include <asm/ftrace.h>
56 #include <asm/irq_vectors.h>
58 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
59 #include <linux/elf-em.h>
60 #define AUDIT_ARCH_I386 (EM_386|__AUDIT_ARCH_LE)
61 #define __AUDIT_ARCH_LE 0x40000000
63 #ifndef CONFIG_AUDITSYSCALL
64 #define sysenter_audit syscall_trace_entry
65 #define sysexit_audit syscall_exit_work
66 #endif
68 /*
69 * We use macros for low-level operations which need to be overridden
70 * for paravirtualization. The following will never clobber any registers:
71 * INTERRUPT_RETURN (aka. "iret")
72 * GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
73 * ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
74 *
75 * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
76 * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
77 * Allowing a register to be clobbered can shrink the paravirt replacement
78 * enough to patch inline, increasing performance.
79 */
81 #define nr_syscalls ((syscall_table_size)/4)
83 #ifdef CONFIG_PREEMPT
84 #define preempt_stop(clobbers) DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
85 #else
86 #define preempt_stop(clobbers)
87 #define resume_kernel restore_nocheck
88 #endif
90 .macro TRACE_IRQS_IRET
91 #ifdef CONFIG_TRACE_IRQFLAGS
92 testl $X86_EFLAGS_IF,PT_EFLAGS(%esp) # interrupts off?
93 jz 1f
94 TRACE_IRQS_ON
95 1:
96 #endif
97 .endm
99 #ifdef CONFIG_VM86
100 #define resume_userspace_sig check_userspace
101 #else
102 #define resume_userspace_sig resume_userspace
103 #endif
105 /*
106 * User gs save/restore
107 *
108 * %gs is used for userland TLS and kernel only uses it for stack
109 * canary which is required to be at %gs:20 by gcc. Read the comment
110 * at the top of stackprotector.h for more info.
111 *
112 * Local labels 98 and 99 are used.
113 */
114 #ifdef CONFIG_X86_32_LAZY_GS
116 /* unfortunately push/pop can't be no-op */
117 .macro PUSH_GS
118 pushl $0
119 CFI_ADJUST_CFA_OFFSET 4
120 .endm
121 .macro POP_GS pop=0
122 addl $(4 + \pop), %esp
123 CFI_ADJUST_CFA_OFFSET -(4 + \pop)
124 .endm
125 .macro POP_GS_EX
126 .endm
128 /* all the rest are no-op */
129 .macro PTGS_TO_GS
130 .endm
131 .macro PTGS_TO_GS_EX
132 .endm
133 .macro GS_TO_REG reg
134 .endm
135 .macro REG_TO_PTGS reg
136 .endm
137 .macro SET_KERNEL_GS reg
138 .endm
140 #else /* CONFIG_X86_32_LAZY_GS */
142 .macro PUSH_GS
143 pushl %gs
144 CFI_ADJUST_CFA_OFFSET 4
145 /*CFI_REL_OFFSET gs, 0*/
146 .endm
148 .macro POP_GS pop=0
149 98: popl %gs
150 CFI_ADJUST_CFA_OFFSET -4
151 /*CFI_RESTORE gs*/
152 .if \pop <> 0
153 add $\pop, %esp
154 CFI_ADJUST_CFA_OFFSET -\pop
155 .endif
156 .endm
157 .macro POP_GS_EX
158 .pushsection .fixup, "ax"
159 99: movl $0, (%esp)
160 jmp 98b
161 .section __ex_table, "a"
162 .align 4
163 .long 98b, 99b
164 .popsection
165 .endm
167 .macro PTGS_TO_GS
168 98: mov PT_GS(%esp), %gs
169 .endm
170 .macro PTGS_TO_GS_EX
171 .pushsection .fixup, "ax"
172 99: movl $0, PT_GS(%esp)
173 jmp 98b
174 .section __ex_table, "a"
175 .align 4
176 .long 98b, 99b
177 .popsection
178 .endm
180 .macro GS_TO_REG reg
181 movl %gs, \reg
182 /*CFI_REGISTER gs, \reg*/
183 .endm
184 .macro REG_TO_PTGS reg
185 movl \reg, PT_GS(%esp)
186 /*CFI_REL_OFFSET gs, PT_GS*/
187 .endm
188 .macro SET_KERNEL_GS reg
189 movl $(__KERNEL_STACK_CANARY), \reg
190 movl \reg, %gs
191 .endm
193 #endif /* CONFIG_X86_32_LAZY_GS */
195 .macro SAVE_ALL
196 cld
197 PUSH_GS
198 pushl %fs
199 CFI_ADJUST_CFA_OFFSET 4
200 /*CFI_REL_OFFSET fs, 0;*/
201 pushl %es
202 CFI_ADJUST_CFA_OFFSET 4
203 /*CFI_REL_OFFSET es, 0;*/
204 pushl %ds
205 CFI_ADJUST_CFA_OFFSET 4
206 /*CFI_REL_OFFSET ds, 0;*/
207 pushl %eax
208 CFI_ADJUST_CFA_OFFSET 4
209 CFI_REL_OFFSET eax, 0
210 pushl %ebp
211 CFI_ADJUST_CFA_OFFSET 4
212 CFI_REL_OFFSET ebp, 0
213 pushl %edi
214 CFI_ADJUST_CFA_OFFSET 4
215 CFI_REL_OFFSET edi, 0
216 pushl %esi
217 CFI_ADJUST_CFA_OFFSET 4
218 CFI_REL_OFFSET esi, 0
219 pushl %edx
220 CFI_ADJUST_CFA_OFFSET 4
221 CFI_REL_OFFSET edx, 0
222 pushl %ecx
223 CFI_ADJUST_CFA_OFFSET 4
224 CFI_REL_OFFSET ecx, 0
225 pushl %ebx
226 CFI_ADJUST_CFA_OFFSET 4
227 CFI_REL_OFFSET ebx, 0
228 movl $(__USER_DS), %edx
229 movl %edx, %ds
230 movl %edx, %es
231 movl $(__KERNEL_PERCPU), %edx
232 movl %edx, %fs
233 SET_KERNEL_GS %edx
234 .endm
236 .macro RESTORE_INT_REGS
237 popl %ebx
238 CFI_ADJUST_CFA_OFFSET -4
239 CFI_RESTORE ebx
240 popl %ecx
241 CFI_ADJUST_CFA_OFFSET -4
242 CFI_RESTORE ecx
243 popl %edx
244 CFI_ADJUST_CFA_OFFSET -4
245 CFI_RESTORE edx
246 popl %esi
247 CFI_ADJUST_CFA_OFFSET -4
248 CFI_RESTORE esi
249 popl %edi
250 CFI_ADJUST_CFA_OFFSET -4
251 CFI_RESTORE edi
252 popl %ebp
253 CFI_ADJUST_CFA_OFFSET -4
254 CFI_RESTORE ebp
255 popl %eax
256 CFI_ADJUST_CFA_OFFSET -4
257 CFI_RESTORE eax
258 .endm
260 .macro RESTORE_REGS pop=0
261 RESTORE_INT_REGS
262 1: popl %ds
263 CFI_ADJUST_CFA_OFFSET -4
264 /*CFI_RESTORE ds;*/
265 2: popl %es
266 CFI_ADJUST_CFA_OFFSET -4
267 /*CFI_RESTORE es;*/
268 3: popl %fs
269 CFI_ADJUST_CFA_OFFSET -4
270 /*CFI_RESTORE fs;*/
271 POP_GS \pop
272 .pushsection .fixup, "ax"
273 4: movl $0, (%esp)
274 jmp 1b
275 5: movl $0, (%esp)
276 jmp 2b
277 6: movl $0, (%esp)
278 jmp 3b
279 .section __ex_table, "a"
280 .align 4
281 .long 1b, 4b
282 .long 2b, 5b
283 .long 3b, 6b
284 .popsection
285 POP_GS_EX
286 .endm
288 .macro RING0_INT_FRAME
289 CFI_STARTPROC simple
290 CFI_SIGNAL_FRAME
291 CFI_DEF_CFA esp, 3*4
292 /*CFI_OFFSET cs, -2*4;*/
293 CFI_OFFSET eip, -3*4
294 .endm
296 .macro RING0_EC_FRAME
297 CFI_STARTPROC simple
298 CFI_SIGNAL_FRAME
299 CFI_DEF_CFA esp, 4*4
300 /*CFI_OFFSET cs, -2*4;*/
301 CFI_OFFSET eip, -3*4
302 .endm
304 .macro RING0_PTREGS_FRAME
305 CFI_STARTPROC simple
306 CFI_SIGNAL_FRAME
307 CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
308 /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
309 CFI_OFFSET eip, PT_EIP-PT_OLDESP
310 /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
311 /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
312 CFI_OFFSET eax, PT_EAX-PT_OLDESP
313 CFI_OFFSET ebp, PT_EBP-PT_OLDESP
314 CFI_OFFSET edi, PT_EDI-PT_OLDESP
315 CFI_OFFSET esi, PT_ESI-PT_OLDESP
316 CFI_OFFSET edx, PT_EDX-PT_OLDESP
317 CFI_OFFSET ecx, PT_ECX-PT_OLDESP
318 CFI_OFFSET ebx, PT_EBX-PT_OLDESP
319 .endm
321 ENTRY(ret_from_fork)
322 CFI_STARTPROC
323 pushl %eax
324 CFI_ADJUST_CFA_OFFSET 4
325 call schedule_tail
326 GET_THREAD_INFO(%ebp)
327 popl %eax
328 CFI_ADJUST_CFA_OFFSET -4
329 pushl $0x0202 # Reset kernel eflags
330 CFI_ADJUST_CFA_OFFSET 4
331 popfl
332 CFI_ADJUST_CFA_OFFSET -4
333 jmp syscall_exit
334 CFI_ENDPROC
335 END(ret_from_fork)
337 /*
338 * Return to user mode is not as complex as all this looks,
339 * but we want the default path for a system call return to
340 * go as quickly as possible which is why some of this is
341 * less clear than it otherwise should be.
342 */
344 # userspace resumption stub bypassing syscall exit tracing
345 ALIGN
346 RING0_PTREGS_FRAME
347 ret_from_exception:
348 preempt_stop(CLBR_ANY)
349 ret_from_intr:
350 GET_THREAD_INFO(%ebp)
351 check_userspace:
352 movl PT_EFLAGS(%esp), %eax # mix EFLAGS and CS
353 movb PT_CS(%esp), %al
354 andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
355 cmpl $USER_RPL, %eax
356 jb resume_kernel # not returning to v8086 or userspace
358 ENTRY(resume_userspace)
359 LOCKDEP_SYS_EXIT
360 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
361 # setting need_resched or sigpending
362 # between sampling and the iret
363 TRACE_IRQS_OFF
364 movl TI_flags(%ebp), %ecx
365 andl $_TIF_WORK_MASK, %ecx # is there any work to be done on
366 # int/exception return?
367 jne work_pending
368 jmp restore_all
369 END(ret_from_exception)
371 #ifdef CONFIG_PREEMPT
372 ENTRY(resume_kernel)
373 DISABLE_INTERRUPTS(CLBR_ANY)
374 cmpl $0, kernel_preemption
375 jz restore_nocheck
376 cmpl $0,TI_preempt_count(%ebp) # non-zero preempt_count ?
377 jnz restore_nocheck
378 need_resched:
379 movl TI_flags(%ebp), %ecx # need_resched set ?
380 testb $_TIF_NEED_RESCHED, %cl
381 jz restore_nocheck
382 testl $X86_EFLAGS_IF,PT_EFLAGS(%esp) # interrupts off (exception path) ?
383 jz restore_nocheck
384 DISABLE_INTERRUPTS(CLBR_ANY)
386 call preempt_schedule_irq
387 jmp need_resched
388 END(resume_kernel)
389 #endif
390 CFI_ENDPROC
392 /* SYSENTER_RETURN points to after the "sysenter" instruction in
393 the vsyscall page. See vsyscall-sysentry.S, which defines the symbol. */
395 # sysenter call handler stub
396 ENTRY(ia32_sysenter_target)
397 CFI_STARTPROC simple
398 CFI_SIGNAL_FRAME
399 CFI_DEF_CFA esp, 0
400 CFI_REGISTER esp, ebp
401 movl TSS_sysenter_sp0(%esp),%esp
402 sysenter_past_esp:
403 /*
404 * Interrupts are disabled here, but we can't trace it until
405 * enough kernel state to call TRACE_IRQS_OFF can be called - but
406 * we immediately enable interrupts at that point anyway.
407 */
408 pushl $(__USER_DS)
409 CFI_ADJUST_CFA_OFFSET 4
410 /*CFI_REL_OFFSET ss, 0*/
411 pushl %ebp
412 CFI_ADJUST_CFA_OFFSET 4
413 CFI_REL_OFFSET esp, 0
414 pushfl
415 orl $X86_EFLAGS_IF, (%esp)
416 CFI_ADJUST_CFA_OFFSET 4
417 pushl $(__USER_CS)
418 CFI_ADJUST_CFA_OFFSET 4
419 /*CFI_REL_OFFSET cs, 0*/
420 /*
421 * Push current_thread_info()->sysenter_return to the stack.
422 * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
423 * pushed above; +8 corresponds to copy_thread's esp0 setting.
424 */
425 pushl (TI_sysenter_return-THREAD_SIZE+8+4*4)(%esp)
426 CFI_ADJUST_CFA_OFFSET 4
427 CFI_REL_OFFSET eip, 0
429 pushl %eax
430 CFI_ADJUST_CFA_OFFSET 4
431 SAVE_ALL
432 ENABLE_INTERRUPTS(CLBR_NONE)
434 /*
435 * Load the potential sixth argument from user stack.
436 * Careful about security.
437 */
438 cmpl $__PAGE_OFFSET-3,%ebp
439 jae syscall_fault
440 1: movl (%ebp),%ebp
441 movl %ebp,PT_EBP(%esp)
442 .section __ex_table,"a"
443 .align 4
444 .long 1b,syscall_fault
445 .previous
447 GET_THREAD_INFO(%ebp)
449 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
450 jnz sysenter_audit
451 sysenter_do_call:
452 cmpl $(nr_syscalls), %eax
453 jae syscall_badsys
454 call *sys_call_table(,%eax,4)
455 movl %eax,PT_EAX(%esp)
456 LOCKDEP_SYS_EXIT
457 DISABLE_INTERRUPTS(CLBR_ANY)
458 TRACE_IRQS_OFF
459 movl TI_flags(%ebp), %ecx
460 testl $_TIF_ALLWORK_MASK, %ecx
461 jne sysexit_audit
462 sysenter_exit:
463 /* if something modifies registers it must also disable sysexit */
464 movl PT_EIP(%esp), %edx
465 movl PT_OLDESP(%esp), %ecx
466 xorl %ebp,%ebp
467 TRACE_IRQS_ON
468 1: mov PT_FS(%esp), %fs
469 PTGS_TO_GS
470 ENABLE_INTERRUPTS_SYSEXIT
472 #ifdef CONFIG_AUDITSYSCALL
473 sysenter_audit:
474 testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
475 jnz syscall_trace_entry
476 addl $4,%esp
477 CFI_ADJUST_CFA_OFFSET -4
478 /* %esi already in 8(%esp) 6th arg: 4th syscall arg */
479 /* %edx already in 4(%esp) 5th arg: 3rd syscall arg */
480 /* %ecx already in 0(%esp) 4th arg: 2nd syscall arg */
481 movl %ebx,%ecx /* 3rd arg: 1st syscall arg */
482 movl %eax,%edx /* 2nd arg: syscall number */
483 movl $AUDIT_ARCH_I386,%eax /* 1st arg: audit arch */
484 call audit_syscall_entry
485 pushl %ebx
486 CFI_ADJUST_CFA_OFFSET 4
487 movl PT_EAX(%esp),%eax /* reload syscall number */
488 jmp sysenter_do_call
490 sysexit_audit:
491 testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
492 jne syscall_exit_work
493 TRACE_IRQS_ON
494 ENABLE_INTERRUPTS(CLBR_ANY)
495 movl %eax,%edx /* second arg, syscall return value */
496 cmpl $0,%eax /* is it < 0? */
497 setl %al /* 1 if so, 0 if not */
498 movzbl %al,%eax /* zero-extend that */
499 inc %eax /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
500 call audit_syscall_exit
501 DISABLE_INTERRUPTS(CLBR_ANY)
502 TRACE_IRQS_OFF
503 movl TI_flags(%ebp), %ecx
504 testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
505 jne syscall_exit_work
506 movl PT_EAX(%esp),%eax /* reload syscall return value */
507 jmp sysenter_exit
508 #endif
510 CFI_ENDPROC
511 .pushsection .fixup,"ax"
512 2: movl $0,PT_FS(%esp)
513 jmp 1b
514 .section __ex_table,"a"
515 .align 4
516 .long 1b,2b
517 .popsection
518 PTGS_TO_GS_EX
519 ENDPROC(ia32_sysenter_target)
521 # system call handler stub
522 ENTRY(system_call)
523 RING0_INT_FRAME # can't unwind into user space anyway
524 pushl %eax # save orig_eax
525 CFI_ADJUST_CFA_OFFSET 4
526 SAVE_ALL
527 GET_THREAD_INFO(%ebp)
528 # system call tracing in operation / emulation
529 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
530 jnz syscall_trace_entry
531 cmpl $(nr_syscalls), %eax
532 jae syscall_badsys
533 syscall_call:
534 call *sys_call_table(,%eax,4)
535 movl %eax,PT_EAX(%esp) # store the return value
536 syscall_exit:
537 LOCKDEP_SYS_EXIT
538 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
539 # setting need_resched or sigpending
540 # between sampling and the iret
541 TRACE_IRQS_OFF
542 movl TI_flags(%ebp), %ecx
543 testl $_TIF_ALLWORK_MASK, %ecx # current->work
544 jne syscall_exit_work
546 restore_all:
547 movl PT_EFLAGS(%esp), %eax # mix EFLAGS, SS and CS
548 # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
549 # are returning to the kernel.
550 # See comments in process.c:copy_thread() for details.
551 movb PT_OLDSS(%esp), %ah
552 movb PT_CS(%esp), %al
553 andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
554 cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
555 CFI_REMEMBER_STATE
556 je ldt_ss # returning to user-space with LDT SS
557 restore_nocheck:
558 TRACE_IRQS_IRET
559 restore_nocheck_notrace:
560 RESTORE_REGS 4 # skip orig_eax/error_code
561 CFI_ADJUST_CFA_OFFSET -4
562 irq_return:
563 INTERRUPT_RETURN
564 .section .fixup,"ax"
565 ENTRY(iret_exc)
566 pushl $0 # no error code
567 pushl $do_iret_error
568 jmp error_code
569 .previous
570 .section __ex_table,"a"
571 .align 4
572 .long irq_return,iret_exc
573 .previous
575 CFI_RESTORE_STATE
576 ldt_ss:
577 larl PT_OLDSS(%esp), %eax
578 jnz restore_nocheck
579 testl $0x00400000, %eax # returning to 32bit stack?
580 jnz restore_nocheck # allright, normal return
582 #ifdef CONFIG_PARAVIRT
583 /*
584 * The kernel can't run on a non-flat stack if paravirt mode
585 * is active. Rather than try to fixup the high bits of
586 * ESP, bypass this code entirely. This may break DOSemu
587 * and/or Wine support in a paravirt VM, although the option
588 * is still available to implement the setting of the high
589 * 16-bits in the INTERRUPT_RETURN paravirt-op.
590 */
591 cmpl $0, pv_info+PARAVIRT_enabled
592 jne restore_nocheck
593 #endif
595 /* If returning to userspace with 16bit stack,
596 * try to fix the higher word of ESP, as the CPU
597 * won't restore it.
598 * This is an "official" bug of all the x86-compatible
599 * CPUs, which we can try to work around to make
600 * dosemu and wine happy. */
601 movl PT_OLDESP(%esp), %eax
602 movl %esp, %edx
603 call patch_espfix_desc
604 pushl $__ESPFIX_SS
605 CFI_ADJUST_CFA_OFFSET 4
606 pushl %eax
607 CFI_ADJUST_CFA_OFFSET 4
608 DISABLE_INTERRUPTS(CLBR_EAX)
609 TRACE_IRQS_OFF
610 lss (%esp), %esp
611 CFI_ADJUST_CFA_OFFSET -8
612 jmp restore_nocheck
613 CFI_ENDPROC
614 ENDPROC(system_call)
616 # perform work that needs to be done immediately before resumption
617 ALIGN
618 RING0_PTREGS_FRAME # can't unwind into user space anyway
619 work_pending:
620 testl $(_TIF_NEED_RESCHED), %ecx
621 jz work_notifysig
622 work_resched:
623 call __schedule
624 LOCKDEP_SYS_EXIT
625 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
626 # setting need_resched or sigpending
627 # between sampling and the iret
628 movl TI_flags(%ebp), %ecx
629 andl $_TIF_WORK_MASK, %ecx # is there any work to be done other
630 # than syscall tracing?
631 jz restore_all
632 testl $(_TIF_NEED_RESCHED), %ecx
633 jnz work_resched
635 work_notifysig: # deal with pending signals and
636 # notify-resume requests
637 #ifdef CONFIG_VM86
638 testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
639 movl %esp, %eax
640 jne work_notifysig_v86 # returning to kernel-space or
641 # vm86-space
642 xorl %edx, %edx
643 call do_notify_resume
644 jmp resume_userspace_sig
646 ALIGN
647 work_notifysig_v86:
648 pushl %ecx # save ti_flags for do_notify_resume
649 CFI_ADJUST_CFA_OFFSET 4
650 call save_v86_state # %eax contains pt_regs pointer
651 popl %ecx
652 CFI_ADJUST_CFA_OFFSET -4
653 movl %eax, %esp
654 #else
655 movl %esp, %eax
656 #endif
657 xorl %edx, %edx
658 call do_notify_resume
659 jmp resume_userspace_sig
660 END(work_pending)
662 # perform syscall exit tracing
663 ALIGN
664 syscall_trace_entry:
665 movl $-ENOSYS,PT_EAX(%esp)
666 movl %esp, %eax
667 call syscall_trace_enter
668 /* What it returned is what we'll actually use. */
669 cmpl $(nr_syscalls), %eax
670 jnae syscall_call
671 jmp syscall_exit
672 END(syscall_trace_entry)
674 # perform syscall exit tracing
675 ALIGN
676 syscall_exit_work:
677 testl $_TIF_WORK_SYSCALL_EXIT, %ecx
678 jz work_pending
679 TRACE_IRQS_ON
680 ENABLE_INTERRUPTS(CLBR_ANY) # could let syscall_trace_leave() call
681 # schedule() instead
682 movl %esp, %eax
683 call syscall_trace_leave
684 jmp resume_userspace
685 END(syscall_exit_work)
686 CFI_ENDPROC
688 RING0_INT_FRAME # can't unwind into user space anyway
689 syscall_fault:
690 GET_THREAD_INFO(%ebp)
691 movl $-EFAULT,PT_EAX(%esp)
692 jmp resume_userspace
693 END(syscall_fault)
695 syscall_badsys:
696 movl $-ENOSYS,PT_EAX(%esp)
697 jmp resume_userspace
698 END(syscall_badsys)
699 CFI_ENDPROC
701 /*
702 * System calls that need a pt_regs pointer.
703 */
704 #define PTREGSCALL(name) \
705 ALIGN; \
706 ptregs_##name: \
707 leal 4(%esp),%eax; \
708 jmp sys_##name;
710 PTREGSCALL(iopl)
711 PTREGSCALL(fork)
712 PTREGSCALL(clone)
713 PTREGSCALL(vfork)
714 PTREGSCALL(execve)
715 PTREGSCALL(sigaltstack)
716 PTREGSCALL(sigreturn)
717 PTREGSCALL(rt_sigreturn)
718 PTREGSCALL(vm86)
719 PTREGSCALL(vm86old)
721 .macro FIXUP_ESPFIX_STACK
722 /* since we are on a wrong stack, we cant make it a C code :( */
723 PER_CPU(gdt_page, %ebx)
724 GET_DESC_BASE(GDT_ENTRY_ESPFIX_SS, %ebx, %eax, %ax, %al, %ah)
725 addl %esp, %eax
726 pushl $__KERNEL_DS
727 CFI_ADJUST_CFA_OFFSET 4
728 pushl %eax
729 CFI_ADJUST_CFA_OFFSET 4
730 lss (%esp), %esp
731 CFI_ADJUST_CFA_OFFSET -8
732 .endm
733 .macro UNWIND_ESPFIX_STACK
734 movl %ss, %eax
735 /* see if on espfix stack */
736 cmpw $__ESPFIX_SS, %ax
737 jne 27f
738 movl $__KERNEL_DS, %eax
739 movl %eax, %ds
740 movl %eax, %es
741 /* switch to normal stack */
742 FIXUP_ESPFIX_STACK
743 27:
744 .endm
746 /*
747 * Build the entry stubs and pointer table with some assembler magic.
748 * We pack 7 stubs into a single 32-byte chunk, which will fit in a
749 * single cache line on all modern x86 implementations.
750 */
751 .section .init.rodata,"a"
752 ENTRY(interrupt)
753 .text
754 .p2align 5
755 .p2align CONFIG_X86_L1_CACHE_SHIFT
756 ENTRY(irq_entries_start)
757 RING0_INT_FRAME
758 vector=FIRST_EXTERNAL_VECTOR
759 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
760 .balign 32
761 .rept 7
762 .if vector < NR_VECTORS
763 .if vector <> FIRST_EXTERNAL_VECTOR
764 CFI_ADJUST_CFA_OFFSET -4
765 .endif
766 1: pushl $(~vector+0x80) /* Note: always in signed byte range */
767 CFI_ADJUST_CFA_OFFSET 4
768 .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
769 jmp 2f
770 .endif
771 .previous
772 .long 1b
773 .text
774 vector=vector+1
775 .endif
776 .endr
777 2: jmp common_interrupt
778 .endr
779 END(irq_entries_start)
781 .previous
782 END(interrupt)
783 .previous
785 /*
786 * the CPU automatically disables interrupts when executing an IRQ vector,
787 * so IRQ-flags tracing has to follow that:
788 */
789 .p2align CONFIG_X86_L1_CACHE_SHIFT
790 common_interrupt:
791 addl $-0x80,(%esp) /* Adjust vector into the [-256,-1] range */
792 SAVE_ALL
793 TRACE_IRQS_OFF
794 movl %esp,%eax
795 call do_IRQ
796 jmp ret_from_intr
797 ENDPROC(common_interrupt)
798 CFI_ENDPROC
800 #define BUILD_INTERRUPT3(name, nr, fn) \
801 ENTRY(name) \
802 RING0_INT_FRAME; \
803 pushl $~(nr); \
804 CFI_ADJUST_CFA_OFFSET 4; \
805 SAVE_ALL; \
806 TRACE_IRQS_OFF \
807 movl %esp,%eax; \
808 call fn; \
809 jmp ret_from_intr; \
810 CFI_ENDPROC; \
811 ENDPROC(name)
813 #define BUILD_INTERRUPT(name, nr) BUILD_INTERRUPT3(name, nr, smp_##name)
815 /* The include is where all of the SMP etc. interrupts come from */
816 #include <asm/entry_arch.h>
818 ENTRY(coprocessor_error)
819 RING0_INT_FRAME
820 pushl $0
821 CFI_ADJUST_CFA_OFFSET 4
822 pushl $do_coprocessor_error
823 CFI_ADJUST_CFA_OFFSET 4
824 jmp error_code
825 CFI_ENDPROC
826 END(coprocessor_error)
828 ENTRY(simd_coprocessor_error)
829 RING0_INT_FRAME
830 pushl $0
831 CFI_ADJUST_CFA_OFFSET 4
832 pushl $do_simd_coprocessor_error
833 CFI_ADJUST_CFA_OFFSET 4
834 jmp error_code
835 CFI_ENDPROC
836 END(simd_coprocessor_error)
838 ENTRY(device_not_available)
839 RING0_INT_FRAME
840 pushl $-1 # mark this as an int
841 CFI_ADJUST_CFA_OFFSET 4
842 pushl $do_device_not_available
843 CFI_ADJUST_CFA_OFFSET 4
844 jmp error_code
845 CFI_ENDPROC
846 END(device_not_available)
848 #ifdef CONFIG_PARAVIRT
849 ENTRY(native_iret)
850 iret
851 .section __ex_table,"a"
852 .align 4
853 .long native_iret, iret_exc
854 .previous
855 END(native_iret)
857 ENTRY(native_irq_enable_sysexit)
858 sti
859 sysexit
860 END(native_irq_enable_sysexit)
861 #endif
863 ENTRY(overflow)
864 RING0_INT_FRAME
865 pushl $0
866 CFI_ADJUST_CFA_OFFSET 4
867 pushl $do_overflow
868 CFI_ADJUST_CFA_OFFSET 4
869 jmp error_code
870 CFI_ENDPROC
871 END(overflow)
873 ENTRY(bounds)
874 RING0_INT_FRAME
875 pushl $0
876 CFI_ADJUST_CFA_OFFSET 4
877 pushl $do_bounds
878 CFI_ADJUST_CFA_OFFSET 4
879 jmp error_code
880 CFI_ENDPROC
881 END(bounds)
883 ENTRY(invalid_op)
884 RING0_INT_FRAME
885 pushl $0
886 CFI_ADJUST_CFA_OFFSET 4
887 pushl $do_invalid_op
888 CFI_ADJUST_CFA_OFFSET 4
889 jmp error_code
890 CFI_ENDPROC
891 END(invalid_op)
893 ENTRY(coprocessor_segment_overrun)
894 RING0_INT_FRAME
895 pushl $0
896 CFI_ADJUST_CFA_OFFSET 4
897 pushl $do_coprocessor_segment_overrun
898 CFI_ADJUST_CFA_OFFSET 4
899 jmp error_code
900 CFI_ENDPROC
901 END(coprocessor_segment_overrun)
903 ENTRY(invalid_TSS)
904 RING0_EC_FRAME
905 pushl $do_invalid_TSS
906 CFI_ADJUST_CFA_OFFSET 4
907 jmp error_code
908 CFI_ENDPROC
909 END(invalid_TSS)
911 ENTRY(segment_not_present)
912 RING0_EC_FRAME
913 pushl $do_segment_not_present
914 CFI_ADJUST_CFA_OFFSET 4
915 jmp error_code
916 CFI_ENDPROC
917 END(segment_not_present)
919 ENTRY(stack_segment)
920 RING0_EC_FRAME
921 pushl $do_stack_segment
922 CFI_ADJUST_CFA_OFFSET 4
923 jmp error_code
924 CFI_ENDPROC
925 END(stack_segment)
927 ENTRY(alignment_check)
928 RING0_EC_FRAME
929 pushl $do_alignment_check
930 CFI_ADJUST_CFA_OFFSET 4
931 jmp error_code
932 CFI_ENDPROC
933 END(alignment_check)
935 ENTRY(divide_error)
936 RING0_INT_FRAME
937 pushl $0 # no error code
938 CFI_ADJUST_CFA_OFFSET 4
939 pushl $do_divide_error
940 CFI_ADJUST_CFA_OFFSET 4
941 jmp error_code
942 CFI_ENDPROC
943 END(divide_error)
945 #ifdef CONFIG_X86_MCE
946 ENTRY(machine_check)
947 RING0_INT_FRAME
948 pushl $0
949 CFI_ADJUST_CFA_OFFSET 4
950 pushl machine_check_vector
951 CFI_ADJUST_CFA_OFFSET 4
952 jmp error_code
953 CFI_ENDPROC
954 END(machine_check)
955 #endif
957 ENTRY(spurious_interrupt_bug)
958 RING0_INT_FRAME
959 pushl $0
960 CFI_ADJUST_CFA_OFFSET 4
961 pushl $do_spurious_interrupt_bug
962 CFI_ADJUST_CFA_OFFSET 4
963 jmp error_code
964 CFI_ENDPROC
965 END(spurious_interrupt_bug)
967 ENTRY(kernel_thread_helper)
968 pushl $0 # fake return address for unwinder
969 CFI_STARTPROC
970 movl %edx,%eax
971 push %edx
972 CFI_ADJUST_CFA_OFFSET 4
973 call *%ebx
974 push %eax
975 CFI_ADJUST_CFA_OFFSET 4
976 call do_exit
977 ud2 # padding for call trace
978 CFI_ENDPROC
979 ENDPROC(kernel_thread_helper)
981 #ifdef CONFIG_XEN
982 /* Xen doesn't set %esp to be precisely what the normal sysenter
983 entrypoint expects, so fix it up before using the normal path. */
984 ENTRY(xen_sysenter_target)
985 RING0_INT_FRAME
986 addl $5*4, %esp /* remove xen-provided frame */
987 CFI_ADJUST_CFA_OFFSET -5*4
988 jmp sysenter_past_esp
989 CFI_ENDPROC
991 ENTRY(xen_hypervisor_callback)
992 CFI_STARTPROC
993 pushl $0
994 CFI_ADJUST_CFA_OFFSET 4
995 SAVE_ALL
996 TRACE_IRQS_OFF
998 /* Check to see if we got the event in the critical
999 region in xen_iret_direct, after we've reenabled
1000 events and checked for pending events. This simulates
1001 iret instruction's behaviour where it delivers a
1002 pending interrupt when enabling interrupts. */
1003 movl PT_EIP(%esp),%eax
1004 cmpl $xen_iret_start_crit,%eax
1005 jb 1f
1006 cmpl $xen_iret_end_crit,%eax
1007 jae 1f
1009 jmp xen_iret_crit_fixup
1011 ENTRY(xen_do_upcall)
1012 1: mov %esp, %eax
1013 call xen_evtchn_do_upcall
1014 jmp ret_from_intr
1015 CFI_ENDPROC
1016 ENDPROC(xen_hypervisor_callback)
1018 # Hypervisor uses this for application faults while it executes.
1019 # We get here for two reasons:
1020 # 1. Fault while reloading DS, ES, FS or GS
1021 # 2. Fault while executing IRET
1022 # Category 1 we fix up by reattempting the load, and zeroing the segment
1023 # register if the load fails.
1024 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1025 # normal Linux return path in this case because if we use the IRET hypercall
1026 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1027 # We distinguish between categories by maintaining a status value in EAX.
1028 ENTRY(xen_failsafe_callback)
1029 CFI_STARTPROC
1030 pushl %eax
1031 CFI_ADJUST_CFA_OFFSET 4
1032 movl $1,%eax
1033 1: mov 4(%esp),%ds
1034 2: mov 8(%esp),%es
1035 3: mov 12(%esp),%fs
1036 4: mov 16(%esp),%gs
1037 testl %eax,%eax
1038 popl %eax
1039 CFI_ADJUST_CFA_OFFSET -4
1040 lea 16(%esp),%esp
1041 CFI_ADJUST_CFA_OFFSET -16
1042 jz 5f
1043 addl $16,%esp
1044 jmp iret_exc # EAX != 0 => Category 2 (Bad IRET)
1045 5: pushl $0 # EAX == 0 => Category 1 (Bad segment)
1046 CFI_ADJUST_CFA_OFFSET 4
1047 SAVE_ALL
1048 jmp ret_from_exception
1049 CFI_ENDPROC
1051 .section .fixup,"ax"
1052 6: xorl %eax,%eax
1053 movl %eax,4(%esp)
1054 jmp 1b
1055 7: xorl %eax,%eax
1056 movl %eax,8(%esp)
1057 jmp 2b
1058 8: xorl %eax,%eax
1059 movl %eax,12(%esp)
1060 jmp 3b
1061 9: xorl %eax,%eax
1062 movl %eax,16(%esp)
1063 jmp 4b
1064 .previous
1065 .section __ex_table,"a"
1066 .align 4
1067 .long 1b,6b
1068 .long 2b,7b
1069 .long 3b,8b
1070 .long 4b,9b
1071 .previous
1072 ENDPROC(xen_failsafe_callback)
1074 #endif /* CONFIG_XEN */
1076 #ifdef CONFIG_FUNCTION_TRACER
1077 #ifdef CONFIG_DYNAMIC_FTRACE
1079 ENTRY(mcount)
1080 ret
1081 END(mcount)
1083 ENTRY(ftrace_caller)
1084 cmpl $0, function_trace_stop
1085 jne ftrace_stub
1087 pushl %eax
1088 pushl %ecx
1089 pushl %edx
1090 movl 0xc(%esp), %eax
1091 movl 0x4(%ebp), %edx
1092 subl $MCOUNT_INSN_SIZE, %eax
1094 .globl ftrace_call
1095 ftrace_call:
1096 call ftrace_stub
1098 popl %edx
1099 popl %ecx
1100 popl %eax
1101 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1102 .globl ftrace_graph_call
1103 ftrace_graph_call:
1104 jmp ftrace_stub
1105 #endif
1107 .globl ftrace_stub
1108 ftrace_stub:
1109 ret
1110 END(ftrace_caller)
1112 #else /* ! CONFIG_DYNAMIC_FTRACE */
1114 ENTRY(mcount)
1115 cmpl $0, function_trace_stop
1116 jne ftrace_stub
1118 cmpl $ftrace_stub, ftrace_trace_function
1119 jnz trace
1120 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1121 cmpl $ftrace_stub, ftrace_graph_return
1122 jnz ftrace_graph_caller
1124 cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1125 jnz ftrace_graph_caller
1126 #endif
1127 .globl ftrace_stub
1128 ftrace_stub:
1129 ret
1131 /* taken from glibc */
1132 trace:
1133 pushl %eax
1134 pushl %ecx
1135 pushl %edx
1136 movl 0xc(%esp), %eax
1137 movl 0x4(%ebp), %edx
1138 subl $MCOUNT_INSN_SIZE, %eax
1140 call *ftrace_trace_function
1142 popl %edx
1143 popl %ecx
1144 popl %eax
1145 jmp ftrace_stub
1146 END(mcount)
1147 #endif /* CONFIG_DYNAMIC_FTRACE */
1148 #endif /* CONFIG_FUNCTION_TRACER */
1150 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1151 ENTRY(ftrace_graph_caller)
1152 cmpl $0, function_trace_stop
1153 jne ftrace_stub
1155 pushl %eax
1156 pushl %ecx
1157 pushl %edx
1158 movl 0xc(%esp), %edx
1159 lea 0x4(%ebp), %eax
1160 subl $MCOUNT_INSN_SIZE, %edx
1161 call prepare_ftrace_return
1162 popl %edx
1163 popl %ecx
1164 popl %eax
1165 ret
1166 END(ftrace_graph_caller)
1168 .globl return_to_handler
1169 return_to_handler:
1170 pushl $0
1171 pushl %eax
1172 pushl %ecx
1173 pushl %edx
1174 call ftrace_return_to_handler
1175 movl %eax, 0xc(%esp)
1176 popl %edx
1177 popl %ecx
1178 popl %eax
1179 ret
1180 #endif
1182 .section .rodata,"a"
1183 #include "syscall_table_32.S"
1185 syscall_table_size=(.-sys_call_table)
1187 /*
1188 * Some functions should be protected against kprobes
1189 */
1190 .pushsection .kprobes.text, "ax"
1192 ENTRY(page_fault)
1193 RING0_EC_FRAME
1194 pushl $do_page_fault
1195 CFI_ADJUST_CFA_OFFSET 4
1196 ALIGN
1197 error_code:
1198 /* the function address is in %gs's slot on the stack */
1199 pushl %fs
1200 CFI_ADJUST_CFA_OFFSET 4
1201 /*CFI_REL_OFFSET fs, 0*/
1202 pushl %es
1203 CFI_ADJUST_CFA_OFFSET 4
1204 /*CFI_REL_OFFSET es, 0*/
1205 pushl %ds
1206 CFI_ADJUST_CFA_OFFSET 4
1207 /*CFI_REL_OFFSET ds, 0*/
1208 pushl %eax
1209 CFI_ADJUST_CFA_OFFSET 4
1210 CFI_REL_OFFSET eax, 0
1211 pushl %ebp
1212 CFI_ADJUST_CFA_OFFSET 4
1213 CFI_REL_OFFSET ebp, 0
1214 pushl %edi
1215 CFI_ADJUST_CFA_OFFSET 4
1216 CFI_REL_OFFSET edi, 0
1217 pushl %esi
1218 CFI_ADJUST_CFA_OFFSET 4
1219 CFI_REL_OFFSET esi, 0
1220 pushl %edx
1221 CFI_ADJUST_CFA_OFFSET 4
1222 CFI_REL_OFFSET edx, 0
1223 pushl %ecx
1224 CFI_ADJUST_CFA_OFFSET 4
1225 CFI_REL_OFFSET ecx, 0
1226 pushl %ebx
1227 CFI_ADJUST_CFA_OFFSET 4
1228 CFI_REL_OFFSET ebx, 0
1229 cld
1230 movl $(__KERNEL_PERCPU), %ecx
1231 movl %ecx, %fs
1232 UNWIND_ESPFIX_STACK
1233 GS_TO_REG %ecx
1234 movl PT_GS(%esp), %edi # get the function address
1235 movl PT_ORIG_EAX(%esp), %edx # get the error code
1236 movl $-1, PT_ORIG_EAX(%esp) # no syscall to restart
1237 REG_TO_PTGS %ecx
1238 SET_KERNEL_GS %ecx
1239 movl $(__USER_DS), %ecx
1240 movl %ecx, %ds
1241 movl %ecx, %es
1242 TRACE_IRQS_OFF
1243 movl %esp,%eax # pt_regs pointer
1244 call *%edi
1245 jmp ret_from_exception
1246 CFI_ENDPROC
1247 END(page_fault)
1249 /*
1250 * Debug traps and NMI can happen at the one SYSENTER instruction
1251 * that sets up the real kernel stack. Check here, since we can't
1252 * allow the wrong stack to be used.
1253 *
1254 * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1255 * already pushed 3 words if it hits on the sysenter instruction:
1256 * eflags, cs and eip.
1257 *
1258 * We just load the right stack, and push the three (known) values
1259 * by hand onto the new stack - while updating the return eip past
1260 * the instruction that would have done it for sysenter.
1261 */
1262 .macro FIX_STACK offset ok label
1263 cmpw $__KERNEL_CS, 4(%esp)
1264 jne \ok
1265 \label:
1266 movl TSS_sysenter_sp0 + \offset(%esp), %esp
1267 CFI_DEF_CFA esp, 0
1268 CFI_UNDEFINED eip
1269 pushfl
1270 CFI_ADJUST_CFA_OFFSET 4
1271 pushl $__KERNEL_CS
1272 CFI_ADJUST_CFA_OFFSET 4
1273 pushl $sysenter_past_esp
1274 CFI_ADJUST_CFA_OFFSET 4
1275 CFI_REL_OFFSET eip, 0
1276 .endm
1278 ENTRY(debug)
1279 RING0_INT_FRAME
1280 cmpl $ia32_sysenter_target,(%esp)
1281 jne debug_stack_correct
1282 FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1283 debug_stack_correct:
1284 pushl $-1 # mark this as an int
1285 CFI_ADJUST_CFA_OFFSET 4
1286 SAVE_ALL
1287 TRACE_IRQS_OFF
1288 xorl %edx,%edx # error code 0
1289 movl %esp,%eax # pt_regs pointer
1290 call do_debug
1291 jmp ret_from_exception
1292 CFI_ENDPROC
1293 END(debug)
1295 /*
1296 * NMI is doubly nasty. It can happen _while_ we're handling
1297 * a debug fault, and the debug fault hasn't yet been able to
1298 * clear up the stack. So we first check whether we got an
1299 * NMI on the sysenter entry path, but after that we need to
1300 * check whether we got an NMI on the debug path where the debug
1301 * fault happened on the sysenter path.
1302 */
1303 ENTRY(nmi)
1304 RING0_INT_FRAME
1305 pushl %eax
1306 CFI_ADJUST_CFA_OFFSET 4
1307 movl %ss, %eax
1308 cmpw $__ESPFIX_SS, %ax
1309 popl %eax
1310 CFI_ADJUST_CFA_OFFSET -4
1311 je nmi_espfix_stack
1312 cmpl $ia32_sysenter_target,(%esp)
1313 je nmi_stack_fixup
1314 pushl %eax
1315 CFI_ADJUST_CFA_OFFSET 4
1316 movl %esp,%eax
1317 /* Do not access memory above the end of our stack page,
1318 * it might not exist.
1319 */
1320 andl $(THREAD_SIZE-1),%eax
1321 cmpl $(THREAD_SIZE-20),%eax
1322 popl %eax
1323 CFI_ADJUST_CFA_OFFSET -4
1324 jae nmi_stack_correct
1325 cmpl $ia32_sysenter_target,12(%esp)
1326 je nmi_debug_stack_check
1327 nmi_stack_correct:
1328 /* We have a RING0_INT_FRAME here */
1329 pushl %eax
1330 CFI_ADJUST_CFA_OFFSET 4
1331 SAVE_ALL
1332 xorl %edx,%edx # zero error code
1333 movl %esp,%eax # pt_regs pointer
1334 call do_nmi
1335 jmp restore_nocheck_notrace
1336 CFI_ENDPROC
1338 nmi_stack_fixup:
1339 RING0_INT_FRAME
1340 FIX_STACK 12, nmi_stack_correct, 1
1341 jmp nmi_stack_correct
1343 nmi_debug_stack_check:
1344 /* We have a RING0_INT_FRAME here */
1345 cmpw $__KERNEL_CS,16(%esp)
1346 jne nmi_stack_correct
1347 cmpl $debug,(%esp)
1348 jb nmi_stack_correct
1349 cmpl $debug_esp_fix_insn,(%esp)
1350 ja nmi_stack_correct
1351 FIX_STACK 24, nmi_stack_correct, 1
1352 jmp nmi_stack_correct
1354 nmi_espfix_stack:
1355 /* We have a RING0_INT_FRAME here.
1356 *
1357 * create the pointer to lss back
1358 */
1359 pushl %ss
1360 CFI_ADJUST_CFA_OFFSET 4
1361 pushl %esp
1362 CFI_ADJUST_CFA_OFFSET 4
1363 addl $4, (%esp)
1364 /* copy the iret frame of 12 bytes */
1365 .rept 3
1366 pushl 16(%esp)
1367 CFI_ADJUST_CFA_OFFSET 4
1368 .endr
1369 pushl %eax
1370 CFI_ADJUST_CFA_OFFSET 4
1371 SAVE_ALL
1372 FIXUP_ESPFIX_STACK # %eax == %esp
1373 xorl %edx,%edx # zero error code
1374 call do_nmi
1375 RESTORE_REGS
1376 lss 12+4(%esp), %esp # back to espfix stack
1377 CFI_ADJUST_CFA_OFFSET -24
1378 jmp irq_return
1379 CFI_ENDPROC
1380 END(nmi)
1382 ENTRY(int3)
1383 RING0_INT_FRAME
1384 pushl $-1 # mark this as an int
1385 CFI_ADJUST_CFA_OFFSET 4
1386 SAVE_ALL
1387 TRACE_IRQS_OFF
1388 xorl %edx,%edx # zero error code
1389 movl %esp,%eax # pt_regs pointer
1390 call do_int3
1391 jmp ret_from_exception
1392 CFI_ENDPROC
1393 END(int3)
1395 ENTRY(general_protection)
1396 RING0_EC_FRAME
1397 pushl $do_general_protection
1398 CFI_ADJUST_CFA_OFFSET 4
1399 jmp error_code
1400 CFI_ENDPROC
1401 END(general_protection)
1403 /*
1404 * End of kprobes section
1405 */
1406 .popsection