arch/openrisc/kernel/vmlinux.lds.S

   1 /*
   2  * OpenRISC vmlinux.lds.S
   3  *
   4  * Linux architectural port borrowing liberally from similar works of
   5  * others.  All original copyrights apply as per the original source
   6  * declaration.
   7  *
   8  * Modifications for the OpenRISC architecture:
   9  * Copyright (C) 2003 Matjaz Breskvar <phoenix@bsemi.com>
  10  * Copyright (C) 2010-2011 Jonas Bonn <jonas@southpole.se>
  11  *
  12  *      This program is free software; you can redistribute it and/or
  13  *      modify it under the terms of the GNU General Public License
  14  *      as published by the Free Software Foundation; either version
  15  *      2 of the License, or (at your option) any later version.
  16  *
  17  * ld script for OpenRISC architecture
  18  */
  19
  20 /* TODO
  21  *              - clean up __offset & stuff
  22  *              - change all 8192 aligment to PAGE !!!
  23  *              - recheck if all aligments are really needed
  24  */
  25
  26 #  define LOAD_OFFSET  PAGE_OFFSET
  27 #  define LOAD_BASE    PAGE_OFFSET
  28
  29 #include <asm/page.h>
  30 #include <asm/cache.h>
  31 #include <asm-generic/vmlinux.lds.h>
  32
  33 OUTPUT_FORMAT("elf32-or32", "elf32-or32", "elf32-or32")
  34 jiffies = jiffies_64 + 4;
  35
  36 SECTIONS
  37 {
  38         /* Read-only sections, merged into text segment: */
  39         . = LOAD_BASE ;
  40
  41         _text = .;
  42
  43         /* _s_kernel_ro must be page aligned */
  44         . = ALIGN(PAGE_SIZE);
  45         _s_kernel_ro = .;
  46
  47         .text                   : AT(ADDR(.text) - LOAD_OFFSET)
  48         {
  49           _stext = .;
  50           TEXT_TEXT
  51           SCHED_TEXT
  52           CPUIDLE_TEXT
  53           LOCK_TEXT
  54           KPROBES_TEXT
  55           IRQENTRY_TEXT
  56           SOFTIRQENTRY_TEXT
  57           *(.fixup)
  58           *(.text.__*)
  59           _etext = .;
  60         }
  61         /* TODO: Check if fixup and text.__* are really necessary
  62          * fixup is definitely necessary
  63          */
  64
  65         _sdata = .;
  66
  67         /* Page alignment required for RO_DATA_SECTION */
  68         RO_DATA_SECTION(PAGE_SIZE)
  69         _e_kernel_ro = .;
  70
  71         /* Whatever comes after _e_kernel_ro had better be page-aligend, too */
  72
  73         /* 32 here is cacheline size... recheck this */
  74         RW_DATA_SECTION(32, PAGE_SIZE, PAGE_SIZE)
  75
  76         _edata  =  .;
  77
  78         EXCEPTION_TABLE(4)
  79         NOTES
  80
  81         /* Init code and data */
  82         . = ALIGN(PAGE_SIZE);
  83         __init_begin = .;
  84
  85         HEAD_TEXT_SECTION
  86
  87         /* Page aligned */
  88         INIT_TEXT_SECTION(PAGE_SIZE)
  89
  90         /* Align __setup_start on 16 byte boundary */
  91         INIT_DATA_SECTION(16)
  92
  93         PERCPU_SECTION(L1_CACHE_BYTES)
  94
  95         __init_end = .;
  96
  97         . = ALIGN(PAGE_SIZE);
  98         .initrd                 : AT(ADDR(.initrd) - LOAD_OFFSET)
  99         {
 100                 __initrd_start = .;
 101                 *(.initrd)
 102                 __initrd_end = .;
 103                 FILL (0);
 104                 . = ALIGN (PAGE_SIZE);
 105         }
 106
 107         __vmlinux_end = .;            /* last address of the physical file */
 108
 109         BSS_SECTION(0, 0, 0x20)
 110
 111         _end = .;
 112
 113         /* Throw in the debugging sections */
 114         STABS_DEBUG
 115         DWARF_DEBUG
 116
 117         /* Sections to be discarded -- must be last */
 118         DISCARDS
 119 }