arch/sh/kernel/vmlinux.lds.S

   1 /*
   2  * ld script to make SuperH Linux kernel
   3  * Written by Niibe Yutaka and Paul Mundt
   4  */
   5 #ifdef CONFIG_SUPERH64
   6 #define LOAD_OFFSET     PAGE_OFFSET
   7 OUTPUT_ARCH(sh:sh5)
   8 #else
   9 #define LOAD_OFFSET     0
  10 OUTPUT_ARCH(sh)
  11 #endif
  12
  13 #include <asm/thread_info.h>
  14 #include <asm/cache.h>
  15 #include <asm/vmlinux.lds.h>
  16
  17 #ifdef CONFIG_PMB
  18  #define MEMORY_OFFSET  0
  19 #else
  20  #define MEMORY_OFFSET  __MEMORY_START
  21 #endif
  22
  23 ENTRY(_start)
  24 SECTIONS
  25 {
  26         . = PAGE_OFFSET + MEMORY_OFFSET + PHYSICAL_OFFSET + CONFIG_ZERO_PAGE_OFFSET;
  27
  28         _text = .;              /* Text and read-only data */
  29
  30         .empty_zero_page : AT(ADDR(.empty_zero_page) - LOAD_OFFSET) {
  31                 *(.empty_zero_page)
  32         } = 0
  33
  34         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  35                 HEAD_TEXT
  36                 TEXT_TEXT
  37                 EXTRA_TEXT
  38                 SCHED_TEXT
  39                 LOCK_TEXT
  40                 KPROBES_TEXT
  41                 IRQENTRY_TEXT
  42                 SOFTIRQENTRY_TEXT
  43                 *(.fixup)
  44                 *(.gnu.warning)
  45                 _etext = .;             /* End of text section */
  46         } = 0x0009
  47
  48         EXCEPTION_TABLE(16)
  49         NOTES
  50
  51         _sdata = .;
  52         RO_DATA(PAGE_SIZE)
  53         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
  54         _edata = .;
  55
  56         DWARF_EH_FRAME
  57
  58         . = ALIGN(PAGE_SIZE);           /* Init code and data */
  59         __init_begin = .;
  60         INIT_TEXT_SECTION(PAGE_SIZE)
  61         INIT_DATA_SECTION(16)
  62
  63         . = ALIGN(4);
  64         .machvec.init : AT(ADDR(.machvec.init) - LOAD_OFFSET) {
  65                 __machvec_start = .;
  66                 *(.machvec.init)
  67                 __machvec_end = .;
  68         }
  69
  70         PERCPU_SECTION(L1_CACHE_BYTES)
  71
  72         /*
  73          * .exit.text is discarded at runtime, not link time, to deal with
  74          * references from __bug_table
  75          */
  76         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { EXIT_TEXT }
  77         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { EXIT_DATA }
  78
  79         . = ALIGN(PAGE_SIZE);
  80         __init_end = .;
  81         BSS_SECTION(0, PAGE_SIZE, 4)
  82         _end = . ;
  83
  84         STABS_DEBUG
  85         DWARF_DEBUG
  86
  87         DISCARDS
  88 }