arch/sh/boards/mach-se/7724/sdram.S

   1 /*
   2  * MS7724SE sdram self/auto-refresh setup code
   3  *
   4  *  Copyright (C) 2009 Magnus Damm
   5  *
   6  * This file is subject to the terms and conditions of the GNU General Public
   7  * License.  See the file "COPYING" in the main directory of this archive
   8  * for more details.
   9  */
  10
  11 #include <linux/sys.h>
  12 #include <linux/errno.h>
  13 #include <linux/linkage.h>
  14 #include <asm/asm-offsets.h>
  15 #include <asm/suspend.h>
  16 #include <asm/romimage-macros.h>
  17
  18 /* code to enter and leave self-refresh. must be self-contained.
  19  * this code will be copied to on-chip memory and executed from there.
  20  */
  21         .balign 4
  22 ENTRY(ms7724se_sdram_enter_start)
  23
  24         /* DBSC: put memory in self-refresh mode */
  25
  26         ED 0xFD000010, 0x00000000 /* DBEN */
  27         ED 0xFD000040, 0x00000000 /* DBRFPDN0 */
  28         ED 0xFD000014, 0x00000002 /* DBCMDCNT (PALL) */
  29         ED 0xFD000014, 0x00000004 /* DBCMDCNT (REF) */
  30         ED 0xFD000040, 0x00000001 /* DBRFPDN0 */
  31
  32         rts
  33          nop
  34
  35 ENTRY(ms7724se_sdram_enter_end)
  36
  37         .balign 4
  38 ENTRY(ms7724se_sdram_leave_start)
  39
  40         /* DBSC: put memory in auto-refresh mode */
  41
  42         mov.l   @(SH_SLEEP_MODE, r5), r0
  43         tst     #SUSP_SH_RSTANDBY, r0
  44         bf      resume_rstandby
  45
  46         ED 0xFD000040, 0x00000000 /* DBRFPDN0 */
  47         WAIT 1
  48         ED 0xFD000014, 0x00000002 /* DBCMDCNT (PALL) */
  49         ED 0xFD000014, 0x00000004 /* DBCMDCNT (REF) */
  50         ED 0xFD000010, 0x00000001 /* DBEN */
  51         ED 0xFD000040, 0x00010000 /* DBRFPDN0 */
  52
  53         rts
  54          nop
  55
  56 resume_rstandby:
  57
  58         /* CPG: setup clocks before restarting external memory */
  59
  60         ED 0xA4150024, 0x00004000 /* PLLCR */
  61
  62         mov.l   FRQCRA,r0
  63         mov.l   @r0,r3
  64         mov.l   KICK,r1
  65         or      r1, r3
  66         mov.l   r3, @r0
  67
  68         mov.l   LSTATS,r0
  69         mov     #1,r1
  70 WAIT_LSTATS:
  71         mov.l   @r0,r3
  72         tst     r1,r3
  73         bf      WAIT_LSTATS
  74
  75         /* DBSC: re-initialize and put in auto-refresh */
  76
  77         ED 0xFD000108, 0x00000181 /* DBPDCNT0 */
  78         ED 0xFD000020, 0x015B0002 /* DBCONF */
  79         ED 0xFD000030, 0x03071502 /* DBTR0 */
  80         ED 0xFD000034, 0x02020102 /* DBTR1 */
  81         ED 0xFD000038, 0x01090405 /* DBTR2 */
  82         ED 0xFD00003C, 0x00000002 /* DBTR3 */
  83         ED 0xFD000008, 0x00000005 /* DBKIND */
  84         ED 0xFD000040, 0x00000001 /* DBRFPDN0 */
  85         ED 0xFD000040, 0x00000000 /* DBRFPDN0 */
  86         ED 0xFD000018, 0x00000001 /* DBCKECNT */
  87
  88         mov     #100,r0
  89 WAIT_400NS:
  90         dt      r0
  91         bf      WAIT_400NS
  92
  93         ED 0xFD000014, 0x00000002 /* DBCMDCNT (PALL) */
  94         ED 0xFD000060, 0x00020000 /* DBMRCNT (EMR2) */
  95         ED 0xFD000060, 0x00030000 /* DBMRCNT (EMR3) */
  96         ED 0xFD000060, 0x00010004 /* DBMRCNT (EMR) */
  97         ED 0xFD000060, 0x00000532 /* DBMRCNT (MRS) */
  98         ED 0xFD000014, 0x00000002 /* DBCMDCNT (PALL) */
  99         ED 0xFD000014, 0x00000004 /* DBCMDCNT (REF) */
 100         ED 0xFD000014, 0x00000004 /* DBCMDCNT (REF) */
 101         ED 0xFD000060, 0x00000432 /* DBMRCNT (MRS) */
 102         ED 0xFD000060, 0x000103c0 /* DBMRCNT (EMR) */
 103         ED 0xFD000060, 0x00010040 /* DBMRCNT (EMR) */
 104
 105         mov     #100,r0
 106 WAIT_400NS_2:
 107         dt      r0
 108         bf      WAIT_400NS_2
 109
 110         ED 0xFD000010, 0x00000001 /* DBEN */
 111         ED 0xFD000044, 0x0000050f /* DBRFPDN1 */
 112         ED 0xFD000048, 0x236800e6 /* DBRFPDN2 */
 113
 114         mov.l   DUMMY,r0
 115         mov.l   @r0, r1 /* force single dummy read */
 116
 117         ED 0xFD000014, 0x00000002 /* DBCMDCNT (PALL) */
 118         ED 0xFD000014, 0x00000004 /* DBCMDCNT (REF) */
 119         ED 0xFD000108, 0x00000080 /* DBPDCNT0 */
 120         ED 0xFD000040, 0x00010000 /* DBRFPDN0 */
 121
 122         rts
 123          nop
 124
 125         .balign 4
 126 DUMMY:  .long   0xac400000
 127 FRQCRA: .long   0xa4150000
 128 KICK:   .long   0x80000000
 129 LSTATS: .long   0xa4150060
 130
 131 ENTRY(ms7724se_sdram_leave_end)