arch/arm/mach-omap2/include/mach/entry-macro.S

   1 /*
   2  * arch/arm/plat-omap/include/mach/entry-macro.S
   3  *
   4  * Low-level IRQ helper macros for OMAP-based platforms
   5  *
   6  * Copyright (C) 2009 Texas Instruments
   7  * Added OMAP4 support - Santosh Shilimkar <santosh.shilimkar@ti.com>
   8  *
   9  * This file is licensed under  the terms of the GNU General Public
  10  * License version 2. This program is licensed "as is" without any
  11  * warranty of any kind, whether express or implied.
  12  */
  13 #include <mach/hardware.h>
  14 #include <mach/io.h>
  15 #include <mach/irqs.h>
  16 #include <asm/hardware/gic.h>
  17
  18 #include <plat/omap24xx.h>
  19 #include <plat/omap34xx.h>
  20 #include <plat/omap44xx.h>
  21
  22 #include <plat/multi.h>
  23
  24 #define OMAP2_IRQ_BASE          OMAP2_L4_IO_ADDRESS(OMAP24XX_IC_BASE)
  25 #define OMAP3_IRQ_BASE          OMAP2_L4_IO_ADDRESS(OMAP34XX_IC_BASE)
  26 #define OMAP4_IRQ_BASE          OMAP2_L4_IO_ADDRESS(OMAP44XX_GIC_CPU_BASE)
  27 #define INTCPS_SIR_IRQ_OFFSET   0x0040  /* omap2/3 active interrupt offset */
  28 #define ACTIVEIRQ_MASK          0x7f    /* omap2/3 active interrupt bits */
  29
  30                 .macro  disable_fiq
  31                 .endm
  32
  33                 .macro  arch_ret_to_user, tmp1, tmp2
  34                 .endm
  35
  36 /*
  37  * Unoptimized irq functions for multi-omap2, 3 and 4
  38  */
  39
  40 #ifdef MULTI_OMAP2
  41                 /*
  42                  * Configure the interrupt base on the first interrupt.
  43                  * See also omap_irq_base_init for setting omap_irq_base.
  44                  */
  45                 .macro  get_irqnr_preamble, base, tmp
  46                 ldr     \base, =omap_irq_base   @ irq base address
  47                 ldr     \base, [\base, #0]      @ irq base value
  48                 .endm
  49
  50                 /* Check the pending interrupts. Note that base already set */
  51                 .macro  get_irqnr_and_base, irqnr, irqstat, base, tmp
  52                 tst     \base, #0x100           @ gic address?
  53                 bne     4401f                   @ found gic
  54
  55                 /* Handle omap2 and omap3 */
  56                 ldr     \irqnr, [\base, #0x98] /* IRQ pending reg 1 */
  57                 cmp     \irqnr, #0x0
  58                 bne     9998f
  59                 ldr     \irqnr, [\base, #0xb8] /* IRQ pending reg 2 */
  60                 cmp     \irqnr, #0x0
  61                 bne     9998f
  62                 ldr     \irqnr, [\base, #0xd8] /* IRQ pending reg 3 */
  63                 cmp     \irqnr, #0x0
  64 9998:
  65                 ldrne   \irqnr, [\base, #INTCPS_SIR_IRQ_OFFSET]
  66                 and     \irqnr, \irqnr, #ACTIVEIRQ_MASK /* Clear spurious bits */
  67                 b       9999f
  68
  69                 /* Handle omap4 */
  70 4401:           ldr     \irqstat, [\base, #GIC_CPU_INTACK]
  71                 ldr     \tmp, =1021
  72                 bic     \irqnr, \irqstat, #0x1c00
  73                 cmp     \irqnr, #29
  74                 cmpcc   \irqnr, \irqnr
  75                 cmpne   \irqnr, \tmp
  76                 cmpcs   \irqnr, \irqnr
  77 9999:
  78                 .endm
  79
  80 #ifdef CONFIG_SMP
  81                 /* We assume that irqstat (the raw value of the IRQ acknowledge
  82                  * register) is preserved from the macro above.
  83                  * If there is an IPI, we immediately signal end of interrupt
  84                  * on the controller, since this requires the original irqstat
  85                  * value which we won't easily be able to recreate later.
  86                  */
  87
  88                 .macro test_for_ipi, irqnr, irqstat, base, tmp
  89                 bic     \irqnr, \irqstat, #0x1c00
  90                 cmp     \irqnr, #16
  91                 it      cc
  92                 strcc   \irqstat, [\base, #GIC_CPU_EOI]
  93                 it      cs
  94                 cmpcs   \irqnr, \irqnr
  95                 .endm
  96
  97                 /* As above, this assumes that irqstat and base are preserved */
  98
  99                 .macro test_for_ltirq, irqnr, irqstat, base, tmp
 100                 bic     \irqnr, \irqstat, #0x1c00
 101                 mov     \tmp, #0
 102                 cmp     \irqnr, #29
 103                 itt     eq
 104                 moveq   \tmp, #1
 105                 streq   \irqstat, [\base, #GIC_CPU_EOI]
 106                 cmp     \tmp, #0
 107                 .endm
 108 #endif  /* CONFIG_SMP */
 109
 110 #else   /* MULTI_OMAP2 */
 111
 112
 113 /*
 114  * Optimized irq functions for omap2, 3 and 4
 115  */
 116
 117 #if defined(CONFIG_ARCH_OMAP2) || defined(CONFIG_ARCH_OMAP3)
 118                 .macro  get_irqnr_preamble, base, tmp
 119 #ifdef CONFIG_ARCH_OMAP2
 120                 ldr     \base, =OMAP2_IRQ_BASE
 121 #else
 122                 ldr     \base, =OMAP3_IRQ_BASE
 123 #endif
 124                 .endm
 125
 126                 /* Check the pending interrupts. Note that base already set */
 127                 .macro  get_irqnr_and_base, irqnr, irqstat, base, tmp
 128                 ldr     \irqnr, [\base, #0x98] /* IRQ pending reg 1 */
 129                 cmp     \irqnr, #0x0
 130                 bne     9999f
 131                 ldr     \irqnr, [\base, #0xb8] /* IRQ pending reg 2 */
 132                 cmp     \irqnr, #0x0
 133                 bne     9999f
 134                 ldr     \irqnr, [\base, #0xd8] /* IRQ pending reg 3 */
 135                 cmp     \irqnr, #0x0
 136 9999:
 137                 ldrne   \irqnr, [\base, #INTCPS_SIR_IRQ_OFFSET]
 138                 and     \irqnr, \irqnr, #ACTIVEIRQ_MASK /* Clear spurious bits */
 139
 140                 .endm
 141 #endif
 142
 143
 144 #ifdef CONFIG_ARCH_OMAP4
 145 #define HAVE_GET_IRQNR_PREAMBLE
 146 #include <asm/hardware/entry-macro-gic.S>
 147
 148                 .macro  get_irqnr_preamble, base, tmp
 149                 ldr     \base, =OMAP4_IRQ_BASE
 150                 .endm
 151
 152 #endif
 153
 154 #endif  /* MULTI_OMAP2 */
 155
 156                 .macro  irq_prio_table
 157                 .endm