arch/m68k/kernel/vmlinux-std.lds

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /* ld script to make m68k Linux kernel */
   3
   4 #include <asm-generic/vmlinux.lds.h>
   5 #include <asm/page.h>
   6 #include <asm/thread_info.h>
   7
   8 OUTPUT_FORMAT("elf32-m68k", "elf32-m68k", "elf32-m68k")
   9 OUTPUT_ARCH(m68k)
  10 ENTRY(_start)
  11 jiffies = jiffies_64 + 4;
  12 SECTIONS
  13 {
  14   . = 0x1000;
  15   _text = .;                    /* Text and read-only data */
  16   .text : {
  17         HEAD_TEXT
  18         TEXT_TEXT
  19         IRQENTRY_TEXT
  20         SOFTIRQENTRY_TEXT
  21         SCHED_TEXT
  22         CPUIDLE_TEXT
  23         LOCK_TEXT
  24         *(.fixup)
  25         *(.gnu.warning)
  26         } :text = 0x4e75
  27
  28   _etext = .;                   /* End of text section */
  29
  30   EXCEPTION_TABLE(16)
  31
  32   _sdata = .;                   /* Start of data section */
  33
  34   RO_DATA(4096)
  35
  36   RW_DATA(16, PAGE_SIZE, THREAD_SIZE)
  37
  38   BSS_SECTION(0, 0, 0)
  39
  40   _edata = .;                   /* End of data section */
  41
  42   /* will be freed after init */
  43   . = ALIGN(PAGE_SIZE);         /* Init code and data */
  44   __init_begin = .;
  45   INIT_TEXT_SECTION(PAGE_SIZE) :data
  46   INIT_DATA_SECTION(16)
  47   .m68k_fixup : {
  48         __start_fixup = .;
  49         *(.m68k_fixup)
  50         __stop_fixup = .;
  51   }
  52   .init_end : {
  53         /* This ALIGN be in a section so that _end is at the end of the
  54            load segment. */
  55         . = ALIGN(PAGE_SIZE);
  56         __init_end = .;
  57   }
  58
  59   _end = . ;
  60
  61   STABS_DEBUG
  62   ELF_DETAILS
  63
  64   /* Sections to be discarded */
  65   DISCARDS
  66 }