arch/arm/mach-shmobile/headsmp.S

   1 /*
   2  * SMP support for R-Mobile / SH-Mobile
   3  *
   4  * Copyright (C) 2010  Magnus Damm
   5  * Copyright (C) 2010  Takashi Yoshii
   6  *
   7  * Based on vexpress, Copyright (c) 2003 ARM Limited, All Rights Reserved
   8  *
   9  * This program is free software; you can redistribute it and/or modify
  10  * it under the terms of the GNU General Public License version 2 as
  11  * published by the Free Software Foundation.
  12  */
  13 #include <linux/linkage.h>
  14 #include <linux/init.h>
  15 #include <asm/memory.h>
  16
  17 ENTRY(shmobile_invalidate_start)
  18         bl      v7_invalidate_l1
  19         b       secondary_startup
  20 ENDPROC(shmobile_invalidate_start)
  21
  22 /*
  23  * Reset vector for secondary CPUs.
  24  * This will be mapped at address 0 by SBAR register.
  25  * We need _long_ jump to the physical address.
  26  */
  27         .arm
  28         .align  12
  29 ENTRY(shmobile_boot_vector)
  30         ldr     r0, 2f
  31         ldr     r1, 1f
  32         bx      r1
  33
  34 ENDPROC(shmobile_boot_vector)
  35
  36         .align  2
  37         .globl  shmobile_boot_fn
  38 shmobile_boot_fn:
  39 1:      .space  4
  40         .globl  shmobile_boot_arg
  41 shmobile_boot_arg:
  42 2:      .space  4
  43         .globl  shmobile_boot_size
  44 shmobile_boot_size:
  45         .long   . - shmobile_boot_vector
  46
  47 /*
  48  * Per-CPU SMP boot function/argument selection code based on MPIDR
  49  */
  50
  51 ENTRY(shmobile_smp_boot)
  52                                                 @ r0 = MPIDR_HWID_BITMASK
  53         mrc     p15, 0, r1, c0, c0, 5           @ r1 = MPIDR
  54         and     r0, r1, r0                      @ r0 = cpu_logical_map() value
  55         mov     r1, #0                          @ r1 = CPU index
  56         adr     r5, 1f                          @ array of per-cpu mpidr values
  57         adr     r6, 2f                          @ array of per-cpu functions
  58         adr     r7, 3f                          @ array of per-cpu arguments
  59
  60 shmobile_smp_boot_find_mpidr:
  61         ldr     r8, [r5, r1, lsl #2]
  62         cmp     r8, r0
  63         bne     shmobile_smp_boot_next
  64
  65         ldr     r9, [r6, r1, lsl #2]
  66         cmp     r9, #0
  67         bne     shmobile_smp_boot_found
  68
  69 shmobile_smp_boot_next:
  70         add     r1, r1, #1
  71         cmp     r1, #CONFIG_NR_CPUS
  72         blo     shmobile_smp_boot_find_mpidr
  73
  74         b       shmobile_smp_sleep
  75
  76 shmobile_smp_boot_found:
  77         ldr     r0, [r7, r1, lsl #2]
  78         mov     pc, r9
  79 ENDPROC(shmobile_smp_boot)
  80
  81 ENTRY(shmobile_smp_sleep)
  82         wfi
  83         b       shmobile_smp_boot
  84 ENDPROC(shmobile_smp_sleep)
  85
  86         .globl  shmobile_smp_mpidr
  87 shmobile_smp_mpidr:
  88 1:      .space  CONFIG_NR_CPUS * 4
  89         .globl  shmobile_smp_fn
  90 shmobile_smp_fn:
  91 2:      .space  CONFIG_NR_CPUS * 4
  92         .globl  shmobile_smp_arg
  93 shmobile_smp_arg:
  94 3:      .space  CONFIG_NR_CPUS * 4