arch/arm64/kernel/efi-entry.S

   1 /*
   2  * EFI entry point.
   3  *
   4  * Copyright (C) 2013, 2014 Red Hat, Inc.
   5  * Author: Mark Salter <msalter@redhat.com>
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License version 2 as
   9  * published by the Free Software Foundation.
  10  *
  11  */
  12 #include <linux/linkage.h>
  13 #include <linux/init.h>
  14
  15 #include <asm/assembler.h>
  16
  17 #define EFI_LOAD_ERROR 0x8000000000000001
  18
  19         __INIT
  20
  21         /*
  22          * We arrive here from the EFI boot manager with:
  23          *
  24          *    * CPU in little-endian mode
  25          *    * MMU on with identity-mapped RAM
  26          *    * Icache and Dcache on
  27          *
  28          * We will most likely be running from some place other than where
  29          * we want to be. The kernel image wants to be placed at TEXT_OFFSET
  30          * from start of RAM.
  31          */
  32 ENTRY(entry)
  33         /*
  34          * Create a stack frame to save FP/LR with extra space
  35          * for image_addr variable passed to efi_entry().
  36          */
  37         stp     x29, x30, [sp, #-32]!
  38         mov     x29, sp
  39
  40         /*
  41          * Call efi_entry to do the real work.
  42          * x0 and x1 are already set up by firmware. Current runtime
  43          * address of image is calculated and passed via *image_addr.
  44          *
  45          * unsigned long efi_entry(void *handle,
  46          *                         efi_system_table_t *sys_table,
  47          *                         unsigned long *image_addr) ;
  48          */
  49         adr_l   x8, _text
  50         add     x2, sp, 16
  51         str     x8, [x2]
  52         bl      efi_entry
  53         cmn     x0, #1
  54         b.eq    efi_load_fail
  55
  56         /*
  57          * efi_entry() will have copied the kernel image if necessary and we
  58          * return here with device tree address in x0 and the kernel entry
  59          * point stored at *image_addr. Save those values in registers which
  60          * are callee preserved.
  61          */
  62         mov     x20, x0         // DTB address
  63         ldr     x0, [sp, #16]   // relocated _text address
  64         ldr     w21, =stext_offset
  65         add     x21, x0, x21
  66
  67         /*
  68          * Calculate size of the kernel Image (same for original and copy).
  69          */
  70         adr_l   x1, _text
  71         adr_l   x2, _edata
  72         sub     x1, x2, x1
  73
  74         /*
  75          * Flush the copied Image to the PoC, and ensure it is not shadowed by
  76          * stale icache entries from before relocation.
  77          */
  78         bl      __flush_dcache_area
  79         ic      ialluis
  80
  81         /*
  82          * Ensure that the rest of this function (in the original Image) is
  83          * visible when the caches are disabled. The I-cache can't have stale
  84          * entries for the VA range of the current image, so no maintenance is
  85          * necessary.
  86          */
  87         adr     x0, entry
  88         adr     x1, entry_end
  89         sub     x1, x1, x0
  90         bl      __flush_dcache_area
  91
  92         /* Turn off Dcache and MMU */
  93         mrs     x0, CurrentEL
  94         cmp     x0, #CurrentEL_EL2
  95         b.ne    1f
  96         mrs     x0, sctlr_el2
  97         bic     x0, x0, #1 << 0 // clear SCTLR.M
  98         bic     x0, x0, #1 << 2 // clear SCTLR.C
  99         pre_disable_mmu_workaround
 100         msr     sctlr_el2, x0
 101         isb
 102         b       2f
 103 1:
 104         mrs     x0, sctlr_el1
 105         bic     x0, x0, #1 << 0 // clear SCTLR.M
 106         bic     x0, x0, #1 << 2 // clear SCTLR.C
 107         pre_disable_mmu_workaround
 108         msr     sctlr_el1, x0
 109         isb
 110 2:
 111         /* Jump to kernel entry point */
 112         mov     x0, x20
 113         mov     x1, xzr
 114         mov     x2, xzr
 115         mov     x3, xzr
 116         br      x21
 117
 118 efi_load_fail:
 119         mov     x0, #EFI_LOAD_ERROR
 120         ldp     x29, x30, [sp], #32
 121         ret
 122
 123 entry_end:
 124 ENDPROC(entry)