arch/powerpc/kernel/tm.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * Transactional memory support routines to reclaim and recheckpoint
   4  * transactional process state.
   5  *
   6  * Copyright 2012 Matt Evans & Michael Neuling, IBM Corporation.
   7  */
   8
   9 #include <asm/asm-offsets.h>
  10 #include <asm/ppc_asm.h>
  11 #include <asm/ppc-opcode.h>
  12 #include <asm/ptrace.h>
  13 #include <asm/reg.h>
  14 #include <asm/bug.h>
  15 #include <asm/export.h>
  16 #include <asm/feature-fixups.h>
  17
  18 #ifdef CONFIG_VSX
  19 /* See fpu.S, this is borrowed from there */
  20 #define __SAVE_32FPRS_VSRS(n,c,base)            \
  21 BEGIN_FTR_SECTION                               \
  22         b       2f;                             \
  23 END_FTR_SECTION_IFSET(CPU_FTR_VSX);             \
  24         SAVE_32FPRS(n,base);                    \
  25         b       3f;                             \
  26 2:      SAVE_32VSRS(n,c,base);                  \
  27 3:
  28 #define __REST_32FPRS_VSRS(n,c,base)            \
  29 BEGIN_FTR_SECTION                               \
  30         b       2f;                             \
  31 END_FTR_SECTION_IFSET(CPU_FTR_VSX);             \
  32         REST_32FPRS(n,base);                    \
  33         b       3f;                             \
  34 2:      REST_32VSRS(n,c,base);                  \
  35 3:
  36 #else
  37 #define __SAVE_32FPRS_VSRS(n,c,base)    SAVE_32FPRS(n, base)
  38 #define __REST_32FPRS_VSRS(n,c,base)    REST_32FPRS(n, base)
  39 #endif
  40 #define SAVE_32FPRS_VSRS(n,c,base) \
  41         __SAVE_32FPRS_VSRS(n,__REG_##c,__REG_##base)
  42 #define REST_32FPRS_VSRS(n,c,base) \
  43         __REST_32FPRS_VSRS(n,__REG_##c,__REG_##base)
  44
  45 /* Stack frame offsets for local variables. */
  46 #define TM_FRAME_L0     TM_FRAME_SIZE-16
  47 #define TM_FRAME_L1     TM_FRAME_SIZE-8
  48
  49
  50 /* In order to access the TM SPRs, TM must be enabled.  So, do so: */
  51 _GLOBAL(tm_enable)
  52         mfmsr   r4
  53         li      r3, MSR_TM >> 32
  54         sldi    r3, r3, 32
  55         and.    r0, r4, r3
  56         bne     1f
  57         or      r4, r4, r3
  58         mtmsrd  r4
  59 1:      blr
  60 EXPORT_SYMBOL_GPL(tm_enable);
  61
  62 _GLOBAL(tm_disable)
  63         mfmsr   r4
  64         li      r3, MSR_TM >> 32
  65         sldi    r3, r3, 32
  66         andc    r4, r4, r3
  67         mtmsrd  r4
  68         blr
  69 EXPORT_SYMBOL_GPL(tm_disable);
  70
  71 _GLOBAL(tm_save_sprs)
  72         mfspr   r0, SPRN_TFHAR
  73         std     r0, THREAD_TM_TFHAR(r3)
  74         mfspr   r0, SPRN_TEXASR
  75         std     r0, THREAD_TM_TEXASR(r3)
  76         mfspr   r0, SPRN_TFIAR
  77         std     r0, THREAD_TM_TFIAR(r3)
  78         blr
  79
  80 _GLOBAL(tm_restore_sprs)
  81         ld      r0, THREAD_TM_TFHAR(r3)
  82         mtspr   SPRN_TFHAR, r0
  83         ld      r0, THREAD_TM_TEXASR(r3)
  84         mtspr   SPRN_TEXASR, r0
  85         ld      r0, THREAD_TM_TFIAR(r3)
  86         mtspr   SPRN_TFIAR, r0
  87         blr
  88
  89         /* Passed an 8-bit failure cause as first argument. */
  90 _GLOBAL(tm_abort)
  91         TABORT(R3)
  92         blr
  93 EXPORT_SYMBOL_GPL(tm_abort);
  94
  95 /*
  96  * void tm_reclaim(struct thread_struct *thread,
  97  *                 uint8_t cause)
  98  *
  99  *      - Performs a full reclaim.  This destroys outstanding
 100  *        transactions and updates thread.ckpt_regs, thread.ckfp_state and
 101  *        thread.ckvr_state with the original checkpointed state.  Note that
 102  *        thread->regs is unchanged.
 103  *
 104  * Purpose is to both abort transactions of, and preserve the state of,
 105  * a transactions at a context switch. We preserve/restore both sets of process
 106  * state to restore them when the thread's scheduled again.  We continue in
 107  * userland as though nothing happened, but when the transaction is resumed
 108  * they will abort back to the checkpointed state we save out here.
 109  *
 110  * Call with IRQs off, stacks get all out of sync for some periods in here!
 111  */
 112 _GLOBAL(tm_reclaim)
 113         mfcr    r5
 114         mflr    r0
 115         stw     r5, 8(r1)
 116         std     r0, 16(r1)
 117         std     r2, STK_GOT(r1)
 118         stdu    r1, -TM_FRAME_SIZE(r1)
 119
 120         /* We've a struct pt_regs at [r1+STACK_FRAME_OVERHEAD]. */
 121
 122         std     r3, STK_PARAM(R3)(r1)
 123         SAVE_NVGPRS(r1)
 124
 125         /*
 126          * Save kernel live AMR since it will be clobbered by treclaim
 127          * but can be used elsewhere later in kernel space.
 128          */
 129         mfspr   r3, SPRN_AMR
 130         std     r3, TM_FRAME_L1(r1)
 131
 132         /* We need to setup MSR for VSX register save instructions. */
 133         mfmsr   r14
 134         mr      r15, r14
 135         ori     r15, r15, MSR_FP
 136         li      r16, 0
 137         ori     r16, r16, MSR_EE /* IRQs hard off */
 138         andc    r15, r15, r16
 139         oris    r15, r15, MSR_VEC@h
 140 #ifdef CONFIG_VSX
 141         BEGIN_FTR_SECTION
 142         oris    r15,r15, MSR_VSX@h
 143         END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 144 #endif
 145         mtmsrd  r15
 146         std     r14, TM_FRAME_L0(r1)
 147
 148         /* Do sanity check on MSR to make sure we are suspended */
 149         li      r7, (MSR_TS_S)@higher
 150         srdi    r6, r14, 32
 151         and     r6, r6, r7
 152 1:      tdeqi   r6, 0
 153         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 154
 155         /* Stash the stack pointer away for use after reclaim */
 156         std     r1, PACAR1(r13)
 157
 158         /* Clear MSR RI since we are about to use SCRATCH0, EE is already off */
 159         li      r5, 0
 160         mtmsrd  r5, 1
 161
 162         /*
 163          * BE CAREFUL HERE:
 164          * At this point we can't take an SLB miss since we have MSR_RI
 165          * off. Load only to/from the stack/paca which are in SLB bolted regions
 166          * until we turn MSR RI back on.
 167          *
 168          * The moment we treclaim, ALL of our GPRs will switch
 169          * to user register state.  (FPRs, CCR etc. also!)
 170          * Use an sprg and a tm_scratch in the PACA to shuffle.
 171          */
 172         TRECLAIM(R4)                            /* Cause in r4 */
 173
 174         /*
 175          * ******************** GPRs ********************
 176          * Stash the checkpointed r13 in the scratch SPR and get the real paca.
 177          */
 178         SET_SCRATCH0(r13)
 179         GET_PACA(r13)
 180
 181         /*
 182          * Stash the checkpointed r1 away in paca->tm_scratch and get the real
 183          * stack pointer back into r1.
 184          */
 185         std     r1, PACATMSCRATCH(r13)
 186         ld      r1, PACAR1(r13)
 187
 188         std     r11, GPR11(r1)                  /* Temporary stash */
 189
 190         /*
 191          * Move the saved user r1 to the kernel stack in case PACATMSCRATCH is
 192          * clobbered by an exception once we turn on MSR_RI below.
 193          */
 194         ld      r11, PACATMSCRATCH(r13)
 195         std     r11, GPR1(r1)
 196
 197         /*
 198          * Store r13 away so we can free up the scratch SPR for the SLB fault
 199          * handler (needed once we start accessing the thread_struct).
 200          */
 201         GET_SCRATCH0(r11)
 202         std     r11, GPR13(r1)
 203
 204         /* Reset MSR RI so we can take SLB faults again */
 205         li      r11, MSR_RI
 206         mtmsrd  r11, 1
 207
 208         /* Store the PPR in r11 and reset to decent value */
 209         mfspr   r11, SPRN_PPR
 210         HMT_MEDIUM
 211
 212         /* Now get some more GPRS free */
 213         std     r7, GPR7(r1)                    /* Temporary stash */
 214         std     r12, GPR12(r1)                  /* ''   ''    ''   */
 215         ld      r12, STK_PARAM(R3)(r1)          /* Param 0, thread_struct * */
 216
 217         std     r11, THREAD_TM_PPR(r12)         /* Store PPR and free r11 */
 218
 219         addi    r7, r12, PT_CKPT_REGS           /* Thread's ckpt_regs */
 220
 221         /*
 222          * Make r7 look like an exception frame so that we can use the neat
 223          * GPRx(n) macros. r7 is NOT a pt_regs ptr!
 224          */
 225         subi    r7, r7, STACK_FRAME_OVERHEAD
 226
 227         /* Sync the userland GPRs 2-12, 14-31 to thread->regs: */
 228         SAVE_GPR(0, r7)                         /* user r0 */
 229         SAVE_GPR(2, r7)                         /* user r2 */
 230         SAVE_4GPRS(3, r7)                       /* user r3-r6 */
 231         SAVE_GPR(8, r7)                         /* user r8 */
 232         SAVE_GPR(9, r7)                         /* user r9 */
 233         SAVE_GPR(10, r7)                        /* user r10 */
 234         ld      r3, GPR1(r1)                    /* user r1 */
 235         ld      r4, GPR7(r1)                    /* user r7 */
 236         ld      r5, GPR11(r1)                   /* user r11 */
 237         ld      r6, GPR12(r1)                   /* user r12 */
 238         ld      r8, GPR13(r1)                   /* user r13 */
 239         std     r3, GPR1(r7)
 240         std     r4, GPR7(r7)
 241         std     r5, GPR11(r7)
 242         std     r6, GPR12(r7)
 243         std     r8, GPR13(r7)
 244
 245         SAVE_NVGPRS(r7)                         /* user r14-r31 */
 246
 247         /* ******************** NIP ******************** */
 248         mfspr   r3, SPRN_TFHAR
 249         std     r3, _NIP(r7)                    /* Returns to failhandler */
 250         /*
 251          * The checkpointed NIP is ignored when rescheduling/rechkpting,
 252          * but is used in signal return to 'wind back' to the abort handler.
 253          */
 254
 255         /* ***************** CTR, LR, CR, XER ********** */
 256         mfctr   r3
 257         mflr    r4
 258         mfcr    r5
 259         mfxer   r6
 260
 261         std     r3, _CTR(r7)
 262         std     r4, _LINK(r7)
 263         std     r5, _CCR(r7)
 264         std     r6, _XER(r7)
 265
 266         /* ******************** TAR, DSCR ********** */
 267         mfspr   r3, SPRN_TAR
 268         mfspr   r4, SPRN_DSCR
 269
 270         std     r3, THREAD_TM_TAR(r12)
 271         std     r4, THREAD_TM_DSCR(r12)
 272
 273         /* ******************** AMR **************** */
 274         mfspr   r3, SPRN_AMR
 275         std     r3, THREAD_TM_AMR(r12)
 276
 277         /*
 278          * MSR and flags: We don't change CRs, and we don't need to alter MSR.
 279          */
 280
 281
 282         /*
 283          * ******************** FPR/VR/VSRs ************
 284          * After reclaiming, capture the checkpointed FPRs/VRs.
 285          *
 286          * We enabled VEC/FP/VSX in the msr above, so we can execute these
 287          * instructions!
 288          */
 289         mr      r3, r12
 290
 291         /* Altivec (VEC/VMX/VR)*/
 292         addi    r7, r3, THREAD_CKVRSTATE
 293         SAVE_32VRS(0, r6, r7)   /* r6 scratch, r7 ckvr_state */
 294         mfvscr  v0
 295         li      r6, VRSTATE_VSCR
 296         stvx    v0, r7, r6
 297
 298         /* VRSAVE */
 299         mfspr   r0, SPRN_VRSAVE
 300         std     r0, THREAD_CKVRSAVE(r3)
 301
 302         /* Floating Point (FP) */
 303         addi    r7, r3, THREAD_CKFPSTATE
 304         SAVE_32FPRS_VSRS(0, R6, R7)     /* r6 scratch, r7 ckfp_state */
 305         mffs    fr0
 306         stfd    fr0,FPSTATE_FPSCR(r7)
 307
 308
 309         /*
 310          * TM regs, incl TEXASR -- these live in thread_struct.  Note they've
 311          * been updated by the treclaim, to explain to userland the failure
 312          * cause (aborted).
 313          */
 314         mfspr   r0, SPRN_TEXASR
 315         mfspr   r3, SPRN_TFHAR
 316         mfspr   r4, SPRN_TFIAR
 317         std     r0, THREAD_TM_TEXASR(r12)
 318         std     r3, THREAD_TM_TFHAR(r12)
 319         std     r4, THREAD_TM_TFIAR(r12)
 320
 321         /* Restore kernel live AMR */
 322         ld      r8, TM_FRAME_L1(r1)
 323         mtspr   SPRN_AMR, r8
 324
 325         /* Restore original MSR/IRQ state & clear TM mode */
 326         ld      r14, TM_FRAME_L0(r1)            /* Orig MSR */
 327
 328         li      r15, 0
 329         rldimi  r14, r15, MSR_TS_LG, (63-MSR_TS_LG)-1
 330         mtmsrd  r14
 331
 332         REST_NVGPRS(r1)
 333
 334         addi    r1, r1, TM_FRAME_SIZE
 335         lwz     r4, 8(r1)
 336         ld      r0, 16(r1)
 337         mtcr    r4
 338         mtlr    r0
 339         ld      r2, STK_GOT(r1)
 340
 341         /* Load CPU's default DSCR */
 342         ld      r0, PACA_DSCR_DEFAULT(r13)
 343         mtspr   SPRN_DSCR, r0
 344
 345         blr
 346
 347
 348         /*
 349          * void __tm_recheckpoint(struct thread_struct *thread)
 350          *      - Restore the checkpointed register state saved by tm_reclaim
 351          *        when we switch_to a process.
 352          *
 353          *      Call with IRQs off, stacks get all out of sync for
 354          *      some periods in here!
 355          */
 356 _GLOBAL(__tm_recheckpoint)
 357         mfcr    r5
 358         mflr    r0
 359         stw     r5, 8(r1)
 360         std     r0, 16(r1)
 361         std     r2, STK_GOT(r1)
 362         stdu    r1, -TM_FRAME_SIZE(r1)
 363
 364         /*
 365          * We've a struct pt_regs at [r1+STACK_FRAME_OVERHEAD].
 366          * This is used for backing up the NVGPRs:
 367          */
 368         SAVE_NVGPRS(r1)
 369
 370         /*
 371          * Save kernel live AMR since it will be clobbered for trechkpt
 372          * but can be used elsewhere later in kernel space.
 373          */
 374         mfspr   r8, SPRN_AMR
 375         std     r8, TM_FRAME_L0(r1)
 376
 377         /* Load complete register state from ts_ckpt* registers */
 378
 379         addi    r7, r3, PT_CKPT_REGS            /* Thread's ckpt_regs */
 380
 381         /*
 382          * Make r7 look like an exception frame so that we can use the neat
 383          * GPRx(n) macros. r7 is now NOT a pt_regs ptr!
 384          */
 385         subi    r7, r7, STACK_FRAME_OVERHEAD
 386
 387         /* We need to setup MSR for FP/VMX/VSX register save instructions. */
 388         mfmsr   r6
 389         mr      r5, r6
 390         ori     r5, r5, MSR_FP
 391 #ifdef CONFIG_ALTIVEC
 392         oris    r5, r5, MSR_VEC@h
 393 #endif
 394 #ifdef CONFIG_VSX
 395         BEGIN_FTR_SECTION
 396         oris    r5,r5, MSR_VSX@h
 397         END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 398 #endif
 399         mtmsrd  r5
 400
 401 #ifdef CONFIG_ALTIVEC
 402         /*
 403          * FP and VEC registers: These are recheckpointed from
 404          * thread.ckfp_state and thread.ckvr_state respectively. The
 405          * thread.fp_state[] version holds the 'live' (transactional)
 406          * and will be loaded subsequently by any FPUnavailable trap.
 407          */
 408         addi    r8, r3, THREAD_CKVRSTATE
 409         li      r5, VRSTATE_VSCR
 410         lvx     v0, r8, r5
 411         mtvscr  v0
 412         REST_32VRS(0, r5, r8)                   /* r5 scratch, r8 ptr */
 413         ld      r5, THREAD_CKVRSAVE(r3)
 414         mtspr   SPRN_VRSAVE, r5
 415 #endif
 416
 417         addi    r8, r3, THREAD_CKFPSTATE
 418         lfd     fr0, FPSTATE_FPSCR(r8)
 419         MTFSF_L(fr0)
 420         REST_32FPRS_VSRS(0, R4, R8)
 421
 422         mtmsr   r6                              /* FP/Vec off again! */
 423
 424 restore_gprs:
 425
 426         /* ****************** CTR, LR, XER ************* */
 427         ld      r4, _CTR(r7)
 428         ld      r5, _LINK(r7)
 429         ld      r8, _XER(r7)
 430
 431         mtctr   r4
 432         mtlr    r5
 433         mtxer   r8
 434
 435         /* ******************** TAR ******************** */
 436         ld      r4, THREAD_TM_TAR(r3)
 437         mtspr   SPRN_TAR,       r4
 438
 439         /* ******************** AMR ******************** */
 440         ld      r4, THREAD_TM_AMR(r3)
 441         mtspr   SPRN_AMR, r4
 442
 443         /* Load up the PPR and DSCR in GPRs only at this stage */
 444         ld      r5, THREAD_TM_DSCR(r3)
 445         ld      r6, THREAD_TM_PPR(r3)
 446
 447         REST_GPR(0, r7)                         /* GPR0 */
 448         REST_2GPRS(2, r7)                       /* GPR2-3 */
 449         REST_GPR(4, r7)                         /* GPR4 */
 450         REST_4GPRS(8, r7)                       /* GPR8-11 */
 451         REST_2GPRS(12, r7)                      /* GPR12-13 */
 452
 453         REST_NVGPRS(r7)                         /* GPR14-31 */
 454
 455         /* Load up PPR and DSCR here so we don't run with user values for long */
 456         mtspr   SPRN_DSCR, r5
 457         mtspr   SPRN_PPR, r6
 458
 459         /*
 460          * Do final sanity check on TEXASR to make sure FS is set. Do this
 461          * here before we load up the userspace r1 so any bugs we hit will get
 462          * a call chain.
 463          */
 464         mfspr   r5, SPRN_TEXASR
 465         srdi    r5, r5, 16
 466         li      r6, (TEXASR_FS)@h
 467         and     r6, r6, r5
 468 1:      tdeqi   r6, 0
 469         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 470
 471         /*
 472          * Do final sanity check on MSR to make sure we are not transactional
 473          * or suspended.
 474          */
 475         mfmsr   r6
 476         li      r5, (MSR_TS_MASK)@higher
 477         srdi    r6, r6, 32
 478         and     r6, r6, r5
 479 1:      tdnei   r6, 0
 480         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 481
 482         /* Restore CR */
 483         ld      r6, _CCR(r7)
 484         mtcr    r6
 485
 486         REST_GPR(6, r7)
 487
 488         /*
 489          * Store r1 and r5 on the stack so that we can access them after we
 490          * clear MSR RI.
 491          */
 492
 493         REST_GPR(5, r7)
 494         std     r5, -8(r1)
 495         ld      r5, GPR1(r7)
 496         std     r5, -16(r1)
 497
 498         REST_GPR(7, r7)
 499
 500         /* Clear MSR RI since we are about to use SCRATCH0. EE is already off */
 501         li      r5, 0
 502         mtmsrd  r5, 1
 503
 504         /*
 505          * BE CAREFUL HERE:
 506          * At this point we can't take an SLB miss since we have MSR_RI
 507          * off. Load only to/from the stack/paca which are in SLB bolted regions
 508          * until we turn MSR RI back on.
 509          */
 510
 511         SET_SCRATCH0(r1)
 512         ld      r5, -8(r1)
 513         ld      r1, -16(r1)
 514
 515         /* Commit register state as checkpointed state: */
 516         TRECHKPT
 517
 518         HMT_MEDIUM
 519
 520         /*
 521          * Our transactional state has now changed.
 522          *
 523          * Now just get out of here.  Transactional (current) state will be
 524          * updated once restore is called on the return path in the _switch-ed
 525          * -to process.
 526          */
 527
 528         GET_PACA(r13)
 529         GET_SCRATCH0(r1)
 530
 531         /* R1 is restored, so we are recoverable again.  EE is still off */
 532         li      r4, MSR_RI
 533         mtmsrd  r4, 1
 534
 535         /* Restore kernel live AMR */
 536         ld      r8, TM_FRAME_L0(r1)
 537         mtspr   SPRN_AMR, r8
 538
 539         REST_NVGPRS(r1)
 540
 541         addi    r1, r1, TM_FRAME_SIZE
 542         lwz     r4, 8(r1)
 543         ld      r0, 16(r1)
 544         mtcr    r4
 545         mtlr    r0
 546         ld      r2, STK_GOT(r1)
 547
 548         /* Load CPU's default DSCR */
 549         ld      r0, PACA_DSCR_DEFAULT(r13)
 550         mtspr   SPRN_DSCR, r0
 551
 552         blr
 553
 554         /* ****************************************************************** */