| blob | 1f1c33d0a13c2097b7209dd420c01b244ab94df1 |
1 /*
2 *
3 * Copyright (C) 1991, 1992 Linus Torvalds
4 */
6 /*
7 * entry.S contains the system-call and fault low-level handling routines.
8 * This also contains the timer-interrupt handler, as well as all interrupts
9 * and faults that can result in a task-switch.
10 *
11 * NOTE: This code handles signal-recognition, which happens every time
12 * after a timer-interrupt and after each system call.
13 *
14 * I changed all the .align's to 4 (16 byte alignment), as that's faster
15 * on a 486.
16 *
17 * Stack layout in 'syscall_exit':
18 * ptrace needs to have all regs on the stack.
19 * if the order here is changed, it needs to be
20 * updated in fork.c:copy_process, signal.c:do_signal,
21 * ptrace.c and ptrace.h
22 *
23 * 0(%esp) - %ebx
24 * 4(%esp) - %ecx
25 * 8(%esp) - %edx
26 * C(%esp) - %esi
27 * 10(%esp) - %edi
28 * 14(%esp) - %ebp
29 * 18(%esp) - %eax
30 * 1C(%esp) - %ds
31 * 20(%esp) - %es
32 * 24(%esp) - %fs
33 * 28(%esp) - %gs saved iff !CONFIG_X86_32_LAZY_GS
34 * 2C(%esp) - orig_eax
35 * 30(%esp) - %eip
36 * 34(%esp) - %cs
37 * 38(%esp) - %eflags
38 * 3C(%esp) - %oldesp
39 * 40(%esp) - %oldss
40 *
41 * "current" is in register %ebx during any slow entries.
42 */
44 #include <linux/linkage.h>
45 #include <linux/err.h>
46 #include <asm/thread_info.h>
47 #include <asm/irqflags.h>
48 #include <asm/errno.h>
49 #include <asm/segment.h>
50 #include <asm/smp.h>
51 #include <asm/page_types.h>
52 #include <asm/percpu.h>
53 #include <asm/dwarf2.h>
54 #include <asm/processor-flags.h>
55 #include <asm/ftrace.h>
56 #include <asm/irq_vectors.h>
57 #include <asm/cpufeature.h>
58 #include <asm/alternative-asm.h>
59 #include <asm/asm.h>
60 #include <asm/smap.h>
62 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
63 #include <linux/elf-em.h>
64 #define AUDIT_ARCH_I386 (EM_386|__AUDIT_ARCH_LE)
65 #define __AUDIT_ARCH_LE 0x40000000
67 #ifndef CONFIG_AUDITSYSCALL
68 #define sysenter_audit syscall_trace_entry
69 #define sysexit_audit syscall_exit_work
70 #endif
72 .section .entry.text, "ax"
74 /*
75 * We use macros for low-level operations which need to be overridden
76 * for paravirtualization. The following will never clobber any registers:
77 * INTERRUPT_RETURN (aka. "iret")
78 * GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
79 * ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
80 *
81 * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
82 * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
83 * Allowing a register to be clobbered can shrink the paravirt replacement
84 * enough to patch inline, increasing performance.
85 */
87 #ifdef CONFIG_PREEMPT
88 #define preempt_stop(clobbers) DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
89 #else
90 #define preempt_stop(clobbers)
91 #define resume_kernel restore_all
92 #endif
94 .macro TRACE_IRQS_IRET
95 #ifdef CONFIG_TRACE_IRQFLAGS
96 testl $X86_EFLAGS_IF,PT_EFLAGS(%esp) # interrupts off?
97 jz 1f
98 TRACE_IRQS_ON
99 1:
100 #endif
101 .endm
103 /*
104 * User gs save/restore
105 *
106 * %gs is used for userland TLS and kernel only uses it for stack
107 * canary which is required to be at %gs:20 by gcc. Read the comment
108 * at the top of stackprotector.h for more info.
109 *
110 * Local labels 98 and 99 are used.
111 */
112 #ifdef CONFIG_X86_32_LAZY_GS
114 /* unfortunately push/pop can't be no-op */
115 .macro PUSH_GS
116 pushl_cfi $0
117 .endm
118 .macro POP_GS pop=0
119 addl $(4 + \pop), %esp
120 CFI_ADJUST_CFA_OFFSET -(4 + \pop)
121 .endm
122 .macro POP_GS_EX
123 .endm
125 /* all the rest are no-op */
126 .macro PTGS_TO_GS
127 .endm
128 .macro PTGS_TO_GS_EX
129 .endm
130 .macro GS_TO_REG reg
131 .endm
132 .macro REG_TO_PTGS reg
133 .endm
134 .macro SET_KERNEL_GS reg
135 .endm
137 #else /* CONFIG_X86_32_LAZY_GS */
139 .macro PUSH_GS
140 pushl_cfi %gs
141 /*CFI_REL_OFFSET gs, 0*/
142 .endm
144 .macro POP_GS pop=0
145 98: popl_cfi %gs
146 /*CFI_RESTORE gs*/
147 .if \pop <> 0
148 add $\pop, %esp
149 CFI_ADJUST_CFA_OFFSET -\pop
150 .endif
151 .endm
152 .macro POP_GS_EX
153 .pushsection .fixup, "ax"
154 99: movl $0, (%esp)
155 jmp 98b
156 .popsection
157 _ASM_EXTABLE(98b,99b)
158 .endm
160 .macro PTGS_TO_GS
161 98: mov PT_GS(%esp), %gs
162 .endm
163 .macro PTGS_TO_GS_EX
164 .pushsection .fixup, "ax"
165 99: movl $0, PT_GS(%esp)
166 jmp 98b
167 .popsection
168 _ASM_EXTABLE(98b,99b)
169 .endm
171 .macro GS_TO_REG reg
172 movl %gs, \reg
173 /*CFI_REGISTER gs, \reg*/
174 .endm
175 .macro REG_TO_PTGS reg
176 movl \reg, PT_GS(%esp)
177 /*CFI_REL_OFFSET gs, PT_GS*/
178 .endm
179 .macro SET_KERNEL_GS reg
180 movl $(__KERNEL_STACK_CANARY), \reg
181 movl \reg, %gs
182 .endm
184 #endif /* CONFIG_X86_32_LAZY_GS */
186 .macro SAVE_ALL
187 cld
188 PUSH_GS
189 pushl_cfi %fs
190 /*CFI_REL_OFFSET fs, 0;*/
191 pushl_cfi %es
192 /*CFI_REL_OFFSET es, 0;*/
193 pushl_cfi %ds
194 /*CFI_REL_OFFSET ds, 0;*/
195 pushl_cfi %eax
196 CFI_REL_OFFSET eax, 0
197 pushl_cfi %ebp
198 CFI_REL_OFFSET ebp, 0
199 pushl_cfi %edi
200 CFI_REL_OFFSET edi, 0
201 pushl_cfi %esi
202 CFI_REL_OFFSET esi, 0
203 pushl_cfi %edx
204 CFI_REL_OFFSET edx, 0
205 pushl_cfi %ecx
206 CFI_REL_OFFSET ecx, 0
207 pushl_cfi %ebx
208 CFI_REL_OFFSET ebx, 0
209 movl $(__USER_DS), %edx
210 movl %edx, %ds
211 movl %edx, %es
212 movl $(__KERNEL_PERCPU), %edx
213 movl %edx, %fs
214 SET_KERNEL_GS %edx
215 .endm
217 .macro RESTORE_INT_REGS
218 popl_cfi %ebx
219 CFI_RESTORE ebx
220 popl_cfi %ecx
221 CFI_RESTORE ecx
222 popl_cfi %edx
223 CFI_RESTORE edx
224 popl_cfi %esi
225 CFI_RESTORE esi
226 popl_cfi %edi
227 CFI_RESTORE edi
228 popl_cfi %ebp
229 CFI_RESTORE ebp
230 popl_cfi %eax
231 CFI_RESTORE eax
232 .endm
234 .macro RESTORE_REGS pop=0
235 RESTORE_INT_REGS
236 1: popl_cfi %ds
237 /*CFI_RESTORE ds;*/
238 2: popl_cfi %es
239 /*CFI_RESTORE es;*/
240 3: popl_cfi %fs
241 /*CFI_RESTORE fs;*/
242 POP_GS \pop
243 .pushsection .fixup, "ax"
244 4: movl $0, (%esp)
245 jmp 1b
246 5: movl $0, (%esp)
247 jmp 2b
248 6: movl $0, (%esp)
249 jmp 3b
250 .popsection
251 _ASM_EXTABLE(1b,4b)
252 _ASM_EXTABLE(2b,5b)
253 _ASM_EXTABLE(3b,6b)
254 POP_GS_EX
255 .endm
257 .macro RING0_INT_FRAME
258 CFI_STARTPROC simple
259 CFI_SIGNAL_FRAME
260 CFI_DEF_CFA esp, 3*4
261 /*CFI_OFFSET cs, -2*4;*/
262 CFI_OFFSET eip, -3*4
263 .endm
265 .macro RING0_EC_FRAME
266 CFI_STARTPROC simple
267 CFI_SIGNAL_FRAME
268 CFI_DEF_CFA esp, 4*4
269 /*CFI_OFFSET cs, -2*4;*/
270 CFI_OFFSET eip, -3*4
271 .endm
273 .macro RING0_PTREGS_FRAME
274 CFI_STARTPROC simple
275 CFI_SIGNAL_FRAME
276 CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
277 /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
278 CFI_OFFSET eip, PT_EIP-PT_OLDESP
279 /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
280 /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
281 CFI_OFFSET eax, PT_EAX-PT_OLDESP
282 CFI_OFFSET ebp, PT_EBP-PT_OLDESP
283 CFI_OFFSET edi, PT_EDI-PT_OLDESP
284 CFI_OFFSET esi, PT_ESI-PT_OLDESP
285 CFI_OFFSET edx, PT_EDX-PT_OLDESP
286 CFI_OFFSET ecx, PT_ECX-PT_OLDESP
287 CFI_OFFSET ebx, PT_EBX-PT_OLDESP
288 .endm
290 ENTRY(ret_from_fork)
291 CFI_STARTPROC
292 pushl_cfi %eax
293 call schedule_tail
294 GET_THREAD_INFO(%ebp)
295 popl_cfi %eax
296 pushl_cfi $0x0202 # Reset kernel eflags
297 popfl_cfi
298 jmp syscall_exit
299 CFI_ENDPROC
300 END(ret_from_fork)
302 ENTRY(ret_from_kernel_thread)
303 CFI_STARTPROC
304 pushl_cfi %eax
305 call schedule_tail
306 GET_THREAD_INFO(%ebp)
307 popl_cfi %eax
308 pushl_cfi $0x0202 # Reset kernel eflags
309 popfl_cfi
310 movl PT_EBP(%esp),%eax
311 call *PT_EBX(%esp)
312 movl $0,PT_EAX(%esp)
313 jmp syscall_exit
314 CFI_ENDPROC
315 ENDPROC(ret_from_kernel_thread)
317 /*
318 * Interrupt exit functions should be protected against kprobes
319 */
320 .pushsection .kprobes.text, "ax"
321 /*
322 * Return to user mode is not as complex as all this looks,
323 * but we want the default path for a system call return to
324 * go as quickly as possible which is why some of this is
325 * less clear than it otherwise should be.
326 */
328 # userspace resumption stub bypassing syscall exit tracing
329 ALIGN
330 RING0_PTREGS_FRAME
331 ret_from_exception:
332 preempt_stop(CLBR_ANY)
333 ret_from_intr:
334 GET_THREAD_INFO(%ebp)
335 #ifdef CONFIG_VM86
336 movl PT_EFLAGS(%esp), %eax # mix EFLAGS and CS
337 movb PT_CS(%esp), %al
338 andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
339 #else
340 /*
341 * We can be coming here from child spawned by kernel_thread().
342 */
343 movl PT_CS(%esp), %eax
344 andl $SEGMENT_RPL_MASK, %eax
345 #endif
346 cmpl $USER_RPL, %eax
347 jb resume_kernel # not returning to v8086 or userspace
349 ENTRY(resume_userspace)
350 LOCKDEP_SYS_EXIT
351 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
352 # setting need_resched or sigpending
353 # between sampling and the iret
354 TRACE_IRQS_OFF
355 movl TI_flags(%ebp), %ecx
356 andl $_TIF_WORK_MASK, %ecx # is there any work to be done on
357 # int/exception return?
358 jne work_pending
359 jmp restore_all
360 END(ret_from_exception)
362 #ifdef CONFIG_PREEMPT
363 ENTRY(resume_kernel)
364 DISABLE_INTERRUPTS(CLBR_ANY)
365 cmpl $0,TI_preempt_count(%ebp) # non-zero preempt_count ?
366 jnz restore_all
367 need_resched:
368 movl TI_flags(%ebp), %ecx # need_resched set ?
369 testb $_TIF_NEED_RESCHED, %cl
370 jz restore_all
371 testl $X86_EFLAGS_IF,PT_EFLAGS(%esp) # interrupts off (exception path) ?
372 jz restore_all
373 call preempt_schedule_irq
374 jmp need_resched
375 END(resume_kernel)
376 #endif
377 CFI_ENDPROC
378 /*
379 * End of kprobes section
380 */
381 .popsection
383 /* SYSENTER_RETURN points to after the "sysenter" instruction in
384 the vsyscall page. See vsyscall-sysentry.S, which defines the symbol. */
386 # sysenter call handler stub
387 ENTRY(ia32_sysenter_target)
388 CFI_STARTPROC simple
389 CFI_SIGNAL_FRAME
390 CFI_DEF_CFA esp, 0
391 CFI_REGISTER esp, ebp
392 movl TSS_sysenter_sp0(%esp),%esp
393 sysenter_past_esp:
394 /*
395 * Interrupts are disabled here, but we can't trace it until
396 * enough kernel state to call TRACE_IRQS_OFF can be called - but
397 * we immediately enable interrupts at that point anyway.
398 */
399 pushl_cfi $__USER_DS
400 /*CFI_REL_OFFSET ss, 0*/
401 pushl_cfi %ebp
402 CFI_REL_OFFSET esp, 0
403 pushfl_cfi
404 orl $X86_EFLAGS_IF, (%esp)
405 pushl_cfi $__USER_CS
406 /*CFI_REL_OFFSET cs, 0*/
407 /*
408 * Push current_thread_info()->sysenter_return to the stack.
409 * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
410 * pushed above; +8 corresponds to copy_thread's esp0 setting.
411 */
412 pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
413 CFI_REL_OFFSET eip, 0
415 pushl_cfi %eax
416 SAVE_ALL
417 ENABLE_INTERRUPTS(CLBR_NONE)
419 /*
420 * Load the potential sixth argument from user stack.
421 * Careful about security.
422 */
423 cmpl $__PAGE_OFFSET-3,%ebp
424 jae syscall_fault
425 ASM_STAC
426 1: movl (%ebp),%ebp
427 ASM_CLAC
428 movl %ebp,PT_EBP(%esp)
429 _ASM_EXTABLE(1b,syscall_fault)
431 GET_THREAD_INFO(%ebp)
433 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
434 jnz sysenter_audit
435 sysenter_do_call:
436 cmpl $(NR_syscalls), %eax
437 jae sysenter_badsys
438 call *sys_call_table(,%eax,4)
439 sysenter_after_call:
440 movl %eax,PT_EAX(%esp)
441 LOCKDEP_SYS_EXIT
442 DISABLE_INTERRUPTS(CLBR_ANY)
443 TRACE_IRQS_OFF
444 movl TI_flags(%ebp), %ecx
445 testl $_TIF_ALLWORK_MASK, %ecx
446 jne sysexit_audit
447 sysenter_exit:
448 /* if something modifies registers it must also disable sysexit */
449 movl PT_EIP(%esp), %edx
450 movl PT_OLDESP(%esp), %ecx
451 xorl %ebp,%ebp
452 TRACE_IRQS_ON
453 1: mov PT_FS(%esp), %fs
454 PTGS_TO_GS
455 ENABLE_INTERRUPTS_SYSEXIT
457 #ifdef CONFIG_AUDITSYSCALL
458 sysenter_audit:
459 testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
460 jnz syscall_trace_entry
461 addl $4,%esp
462 CFI_ADJUST_CFA_OFFSET -4
463 /* %esi already in 8(%esp) 6th arg: 4th syscall arg */
464 /* %edx already in 4(%esp) 5th arg: 3rd syscall arg */
465 /* %ecx already in 0(%esp) 4th arg: 2nd syscall arg */
466 movl %ebx,%ecx /* 3rd arg: 1st syscall arg */
467 movl %eax,%edx /* 2nd arg: syscall number */
468 movl $AUDIT_ARCH_I386,%eax /* 1st arg: audit arch */
469 call __audit_syscall_entry
470 pushl_cfi %ebx
471 movl PT_EAX(%esp),%eax /* reload syscall number */
472 jmp sysenter_do_call
474 sysexit_audit:
475 testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
476 jne syscall_exit_work
477 TRACE_IRQS_ON
478 ENABLE_INTERRUPTS(CLBR_ANY)
479 movl %eax,%edx /* second arg, syscall return value */
480 cmpl $-MAX_ERRNO,%eax /* is it an error ? */
481 setbe %al /* 1 if so, 0 if not */
482 movzbl %al,%eax /* zero-extend that */
483 call __audit_syscall_exit
484 DISABLE_INTERRUPTS(CLBR_ANY)
485 TRACE_IRQS_OFF
486 movl TI_flags(%ebp), %ecx
487 testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
488 jne syscall_exit_work
489 movl PT_EAX(%esp),%eax /* reload syscall return value */
490 jmp sysenter_exit
491 #endif
493 CFI_ENDPROC
494 .pushsection .fixup,"ax"
495 2: movl $0,PT_FS(%esp)
496 jmp 1b
497 .popsection
498 _ASM_EXTABLE(1b,2b)
499 PTGS_TO_GS_EX
500 ENDPROC(ia32_sysenter_target)
502 /*
503 * syscall stub including irq exit should be protected against kprobes
504 */
505 .pushsection .kprobes.text, "ax"
506 # system call handler stub
507 ENTRY(system_call)
508 RING0_INT_FRAME # can't unwind into user space anyway
509 ASM_CLAC
510 pushl_cfi %eax # save orig_eax
511 SAVE_ALL
512 GET_THREAD_INFO(%ebp)
513 # system call tracing in operation / emulation
514 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
515 jnz syscall_trace_entry
516 cmpl $(NR_syscalls), %eax
517 jae syscall_badsys
518 syscall_call:
519 call *sys_call_table(,%eax,4)
520 syscall_after_call:
521 movl %eax,PT_EAX(%esp) # store the return value
522 syscall_exit:
523 LOCKDEP_SYS_EXIT
524 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
525 # setting need_resched or sigpending
526 # between sampling and the iret
527 TRACE_IRQS_OFF
528 movl TI_flags(%ebp), %ecx
529 testl $_TIF_ALLWORK_MASK, %ecx # current->work
530 jne syscall_exit_work
532 restore_all:
533 TRACE_IRQS_IRET
534 restore_all_notrace:
535 #ifdef CONFIG_X86_ESPFIX32
536 movl PT_EFLAGS(%esp), %eax # mix EFLAGS, SS and CS
537 # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
538 # are returning to the kernel.
539 # See comments in process.c:copy_thread() for details.
540 movb PT_OLDSS(%esp), %ah
541 movb PT_CS(%esp), %al
542 andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
543 cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
544 CFI_REMEMBER_STATE
545 je ldt_ss # returning to user-space with LDT SS
546 #endif
547 restore_nocheck:
548 RESTORE_REGS 4 # skip orig_eax/error_code
549 irq_return:
550 INTERRUPT_RETURN
551 .section .fixup,"ax"
552 ENTRY(iret_exc)
553 pushl $0 # no error code
554 pushl $do_iret_error
555 jmp error_code
556 .previous
557 _ASM_EXTABLE(irq_return,iret_exc)
559 #ifdef CONFIG_X86_ESPFIX32
560 CFI_RESTORE_STATE
561 ldt_ss:
562 #ifdef CONFIG_PARAVIRT
563 /*
564 * The kernel can't run on a non-flat stack if paravirt mode
565 * is active. Rather than try to fixup the high bits of
566 * ESP, bypass this code entirely. This may break DOSemu
567 * and/or Wine support in a paravirt VM, although the option
568 * is still available to implement the setting of the high
569 * 16-bits in the INTERRUPT_RETURN paravirt-op.
570 */
571 cmpl $0, pv_info+PARAVIRT_enabled
572 jne restore_nocheck
573 #endif
575 /*
576 * Setup and switch to ESPFIX stack
577 *
578 * We're returning to userspace with a 16 bit stack. The CPU will not
579 * restore the high word of ESP for us on executing iret... This is an
580 * "official" bug of all the x86-compatible CPUs, which we can work
581 * around to make dosemu and wine happy. We do this by preloading the
582 * high word of ESP with the high word of the userspace ESP while
583 * compensating for the offset by changing to the ESPFIX segment with
584 * a base address that matches for the difference.
585 */
586 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
587 mov %esp, %edx /* load kernel esp */
588 mov PT_OLDESP(%esp), %eax /* load userspace esp */
589 mov %dx, %ax /* eax: new kernel esp */
590 sub %eax, %edx /* offset (low word is 0) */
591 shr $16, %edx
592 mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
593 mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
594 pushl_cfi $__ESPFIX_SS
595 pushl_cfi %eax /* new kernel esp */
596 /* Disable interrupts, but do not irqtrace this section: we
597 * will soon execute iret and the tracer was already set to
598 * the irqstate after the iret */
599 DISABLE_INTERRUPTS(CLBR_EAX)
600 lss (%esp), %esp /* switch to espfix segment */
601 CFI_ADJUST_CFA_OFFSET -8
602 jmp restore_nocheck
603 #endif
604 CFI_ENDPROC
605 ENDPROC(system_call)
607 # perform work that needs to be done immediately before resumption
608 ALIGN
609 RING0_PTREGS_FRAME # can't unwind into user space anyway
610 work_pending:
611 testb $_TIF_NEED_RESCHED, %cl
612 jz work_notifysig
613 work_resched:
614 call schedule
615 LOCKDEP_SYS_EXIT
616 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
617 # setting need_resched or sigpending
618 # between sampling and the iret
619 TRACE_IRQS_OFF
620 movl TI_flags(%ebp), %ecx
621 andl $_TIF_WORK_MASK, %ecx # is there any work to be done other
622 # than syscall tracing?
623 jz restore_all
624 testb $_TIF_NEED_RESCHED, %cl
625 jnz work_resched
627 work_notifysig: # deal with pending signals and
628 # notify-resume requests
629 #ifdef CONFIG_VM86
630 testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
631 movl %esp, %eax
632 jne work_notifysig_v86 # returning to kernel-space or
633 # vm86-space
634 1:
635 #else
636 movl %esp, %eax
637 #endif
638 TRACE_IRQS_ON
639 ENABLE_INTERRUPTS(CLBR_NONE)
640 movb PT_CS(%esp), %bl
641 andb $SEGMENT_RPL_MASK, %bl
642 cmpb $USER_RPL, %bl
643 jb resume_kernel
644 xorl %edx, %edx
645 call do_notify_resume
646 jmp resume_userspace
648 #ifdef CONFIG_VM86
649 ALIGN
650 work_notifysig_v86:
651 pushl_cfi %ecx # save ti_flags for do_notify_resume
652 call save_v86_state # %eax contains pt_regs pointer
653 popl_cfi %ecx
654 movl %eax, %esp
655 jmp 1b
656 #endif
657 END(work_pending)
659 # perform syscall exit tracing
660 ALIGN
661 syscall_trace_entry:
662 movl $-ENOSYS,PT_EAX(%esp)
663 movl %esp, %eax
664 call syscall_trace_enter
665 /* What it returned is what we'll actually use. */
666 cmpl $(NR_syscalls), %eax
667 jnae syscall_call
668 jmp syscall_exit
669 END(syscall_trace_entry)
671 # perform syscall exit tracing
672 ALIGN
673 syscall_exit_work:
674 testl $_TIF_WORK_SYSCALL_EXIT, %ecx
675 jz work_pending
676 TRACE_IRQS_ON
677 ENABLE_INTERRUPTS(CLBR_ANY) # could let syscall_trace_leave() call
678 # schedule() instead
679 movl %esp, %eax
680 call syscall_trace_leave
681 jmp resume_userspace
682 END(syscall_exit_work)
683 CFI_ENDPROC
685 RING0_INT_FRAME # can't unwind into user space anyway
686 syscall_fault:
687 ASM_CLAC
688 GET_THREAD_INFO(%ebp)
689 movl $-EFAULT,PT_EAX(%esp)
690 jmp resume_userspace
691 END(syscall_fault)
693 syscall_badsys:
694 movl $-ENOSYS,%eax
695 jmp syscall_after_call
696 END(syscall_badsys)
698 sysenter_badsys:
699 movl $-ENOSYS,%eax
700 jmp sysenter_after_call
701 END(syscall_badsys)
702 CFI_ENDPROC
703 /*
704 * End of kprobes section
705 */
706 .popsection
708 .macro FIXUP_ESPFIX_STACK
709 /*
710 * Switch back for ESPFIX stack to the normal zerobased stack
711 *
712 * We can't call C functions using the ESPFIX stack. This code reads
713 * the high word of the segment base from the GDT and swiches to the
714 * normal stack and adjusts ESP with the matching offset.
715 */
716 #ifdef CONFIG_X86_ESPFIX32
717 /* fixup the stack */
718 mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
719 mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
720 shl $16, %eax
721 addl %esp, %eax /* the adjusted stack pointer */
722 pushl_cfi $__KERNEL_DS
723 pushl_cfi %eax
724 lss (%esp), %esp /* switch to the normal stack segment */
725 CFI_ADJUST_CFA_OFFSET -8
726 #endif
727 .endm
728 .macro UNWIND_ESPFIX_STACK
729 #ifdef CONFIG_X86_ESPFIX32
730 movl %ss, %eax
731 /* see if on espfix stack */
732 cmpw $__ESPFIX_SS, %ax
733 jne 27f
734 movl $__KERNEL_DS, %eax
735 movl %eax, %ds
736 movl %eax, %es
737 /* switch to normal stack */
738 FIXUP_ESPFIX_STACK
739 27:
740 #endif
741 .endm
743 /*
744 * Build the entry stubs and pointer table with some assembler magic.
745 * We pack 7 stubs into a single 32-byte chunk, which will fit in a
746 * single cache line on all modern x86 implementations.
747 */
748 .section .init.rodata,"a"
749 ENTRY(interrupt)
750 .section .entry.text, "ax"
751 .p2align 5
752 .p2align CONFIG_X86_L1_CACHE_SHIFT
753 ENTRY(irq_entries_start)
754 RING0_INT_FRAME
755 vector=FIRST_EXTERNAL_VECTOR
756 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
757 .balign 32
758 .rept 7
759 .if vector < NR_VECTORS
760 .if vector <> FIRST_EXTERNAL_VECTOR
761 CFI_ADJUST_CFA_OFFSET -4
762 .endif
763 1: pushl_cfi $(~vector+0x80) /* Note: always in signed byte range */
764 .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
765 jmp 2f
766 .endif
767 .previous
768 .long 1b
769 .section .entry.text, "ax"
770 vector=vector+1
771 .endif
772 .endr
773 2: jmp common_interrupt
774 .endr
775 END(irq_entries_start)
777 .previous
778 END(interrupt)
779 .previous
781 /*
782 * the CPU automatically disables interrupts when executing an IRQ vector,
783 * so IRQ-flags tracing has to follow that:
784 */
785 .p2align CONFIG_X86_L1_CACHE_SHIFT
786 common_interrupt:
787 ASM_CLAC
788 addl $-0x80,(%esp) /* Adjust vector into the [-256,-1] range */
789 SAVE_ALL
790 TRACE_IRQS_OFF
791 movl %esp,%eax
792 call do_IRQ
793 jmp ret_from_intr
794 ENDPROC(common_interrupt)
795 CFI_ENDPROC
797 /*
798 * Irq entries should be protected against kprobes
799 */
800 .pushsection .kprobes.text, "ax"
801 #define BUILD_INTERRUPT3(name, nr, fn) \
802 ENTRY(name) \
803 RING0_INT_FRAME; \
804 ASM_CLAC; \
805 pushl_cfi $~(nr); \
806 SAVE_ALL; \
807 TRACE_IRQS_OFF \
808 movl %esp,%eax; \
809 call fn; \
810 jmp ret_from_intr; \
811 CFI_ENDPROC; \
812 ENDPROC(name)
815 #ifdef CONFIG_TRACING
816 #define TRACE_BUILD_INTERRUPT(name, nr) \
817 BUILD_INTERRUPT3(trace_##name, nr, smp_trace_##name)
818 #else
819 #define TRACE_BUILD_INTERRUPT(name, nr)
820 #endif
822 #define BUILD_INTERRUPT(name, nr) \
823 BUILD_INTERRUPT3(name, nr, smp_##name); \
824 TRACE_BUILD_INTERRUPT(name, nr)
826 /* The include is where all of the SMP etc. interrupts come from */
827 #include <asm/entry_arch.h>
829 ENTRY(coprocessor_error)
830 RING0_INT_FRAME
831 ASM_CLAC
832 pushl_cfi $0
833 pushl_cfi $do_coprocessor_error
834 jmp error_code
835 CFI_ENDPROC
836 END(coprocessor_error)
838 ENTRY(simd_coprocessor_error)
839 RING0_INT_FRAME
840 ASM_CLAC
841 pushl_cfi $0
842 #ifdef CONFIG_X86_INVD_BUG
843 /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
844 661: pushl_cfi $do_general_protection
845 662:
846 .section .altinstructions,"a"
847 altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
848 .previous
849 .section .altinstr_replacement,"ax"
850 663: pushl $do_simd_coprocessor_error
851 664:
852 .previous
853 #else
854 pushl_cfi $do_simd_coprocessor_error
855 #endif
856 jmp error_code
857 CFI_ENDPROC
858 END(simd_coprocessor_error)
860 ENTRY(device_not_available)
861 RING0_INT_FRAME
862 ASM_CLAC
863 pushl_cfi $-1 # mark this as an int
864 pushl_cfi $do_device_not_available
865 jmp error_code
866 CFI_ENDPROC
867 END(device_not_available)
869 #ifdef CONFIG_PARAVIRT
870 ENTRY(native_iret)
871 iret
872 _ASM_EXTABLE(native_iret, iret_exc)
873 END(native_iret)
875 ENTRY(native_irq_enable_sysexit)
876 sti
877 sysexit
878 END(native_irq_enable_sysexit)
879 #endif
881 ENTRY(overflow)
882 RING0_INT_FRAME
883 ASM_CLAC
884 pushl_cfi $0
885 pushl_cfi $do_overflow
886 jmp error_code
887 CFI_ENDPROC
888 END(overflow)
890 ENTRY(bounds)
891 RING0_INT_FRAME
892 ASM_CLAC
893 pushl_cfi $0
894 pushl_cfi $do_bounds
895 jmp error_code
896 CFI_ENDPROC
897 END(bounds)
899 ENTRY(invalid_op)
900 RING0_INT_FRAME
901 ASM_CLAC
902 pushl_cfi $0
903 pushl_cfi $do_invalid_op
904 jmp error_code
905 CFI_ENDPROC
906 END(invalid_op)
908 ENTRY(coprocessor_segment_overrun)
909 RING0_INT_FRAME
910 ASM_CLAC
911 pushl_cfi $0
912 pushl_cfi $do_coprocessor_segment_overrun
913 jmp error_code
914 CFI_ENDPROC
915 END(coprocessor_segment_overrun)
917 ENTRY(invalid_TSS)
918 RING0_EC_FRAME
919 ASM_CLAC
920 pushl_cfi $do_invalid_TSS
921 jmp error_code
922 CFI_ENDPROC
923 END(invalid_TSS)
925 ENTRY(segment_not_present)
926 RING0_EC_FRAME
927 ASM_CLAC
928 pushl_cfi $do_segment_not_present
929 jmp error_code
930 CFI_ENDPROC
931 END(segment_not_present)
933 ENTRY(stack_segment)
934 RING0_EC_FRAME
935 ASM_CLAC
936 pushl_cfi $do_stack_segment
937 jmp error_code
938 CFI_ENDPROC
939 END(stack_segment)
941 ENTRY(alignment_check)
942 RING0_EC_FRAME
943 ASM_CLAC
944 pushl_cfi $do_alignment_check
945 jmp error_code
946 CFI_ENDPROC
947 END(alignment_check)
949 ENTRY(divide_error)
950 RING0_INT_FRAME
951 ASM_CLAC
952 pushl_cfi $0 # no error code
953 pushl_cfi $do_divide_error
954 jmp error_code
955 CFI_ENDPROC
956 END(divide_error)
958 #ifdef CONFIG_X86_MCE
959 ENTRY(machine_check)
960 RING0_INT_FRAME
961 ASM_CLAC
962 pushl_cfi $0
963 pushl_cfi machine_check_vector
964 jmp error_code
965 CFI_ENDPROC
966 END(machine_check)
967 #endif
969 ENTRY(spurious_interrupt_bug)
970 RING0_INT_FRAME
971 ASM_CLAC
972 pushl_cfi $0
973 pushl_cfi $do_spurious_interrupt_bug
974 jmp error_code
975 CFI_ENDPROC
976 END(spurious_interrupt_bug)
977 /*
978 * End of kprobes section
979 */
980 .popsection
982 #ifdef CONFIG_XEN
983 /* Xen doesn't set %esp to be precisely what the normal sysenter
984 entrypoint expects, so fix it up before using the normal path. */
985 ENTRY(xen_sysenter_target)
986 RING0_INT_FRAME
987 addl $5*4, %esp /* remove xen-provided frame */
988 CFI_ADJUST_CFA_OFFSET -5*4
989 jmp sysenter_past_esp
990 CFI_ENDPROC
992 ENTRY(xen_hypervisor_callback)
993 CFI_STARTPROC
994 pushl_cfi $-1 /* orig_ax = -1 => not a system call */
995 SAVE_ALL
996 TRACE_IRQS_OFF
998 /* Check to see if we got the event in the critical
999 region in xen_iret_direct, after we've reenabled
1000 events and checked for pending events. This simulates
1001 iret instruction's behaviour where it delivers a
1002 pending interrupt when enabling interrupts. */
1003 movl PT_EIP(%esp),%eax
1004 cmpl $xen_iret_start_crit,%eax
1005 jb 1f
1006 cmpl $xen_iret_end_crit,%eax
1007 jae 1f
1009 jmp xen_iret_crit_fixup
1011 ENTRY(xen_do_upcall)
1012 1: mov %esp, %eax
1013 call xen_evtchn_do_upcall
1014 jmp ret_from_intr
1015 CFI_ENDPROC
1016 ENDPROC(xen_hypervisor_callback)
1018 # Hypervisor uses this for application faults while it executes.
1019 # We get here for two reasons:
1020 # 1. Fault while reloading DS, ES, FS or GS
1021 # 2. Fault while executing IRET
1022 # Category 1 we fix up by reattempting the load, and zeroing the segment
1023 # register if the load fails.
1024 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1025 # normal Linux return path in this case because if we use the IRET hypercall
1026 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1027 # We distinguish between categories by maintaining a status value in EAX.
1028 ENTRY(xen_failsafe_callback)
1029 CFI_STARTPROC
1030 pushl_cfi %eax
1031 movl $1,%eax
1032 1: mov 4(%esp),%ds
1033 2: mov 8(%esp),%es
1034 3: mov 12(%esp),%fs
1035 4: mov 16(%esp),%gs
1036 /* EAX == 0 => Category 1 (Bad segment)
1037 EAX != 0 => Category 2 (Bad IRET) */
1038 testl %eax,%eax
1039 popl_cfi %eax
1040 lea 16(%esp),%esp
1041 CFI_ADJUST_CFA_OFFSET -16
1042 jz 5f
1043 jmp iret_exc
1044 5: pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1045 SAVE_ALL
1046 jmp ret_from_exception
1047 CFI_ENDPROC
1049 .section .fixup,"ax"
1050 6: xorl %eax,%eax
1051 movl %eax,4(%esp)
1052 jmp 1b
1053 7: xorl %eax,%eax
1054 movl %eax,8(%esp)
1055 jmp 2b
1056 8: xorl %eax,%eax
1057 movl %eax,12(%esp)
1058 jmp 3b
1059 9: xorl %eax,%eax
1060 movl %eax,16(%esp)
1061 jmp 4b
1062 .previous
1063 _ASM_EXTABLE(1b,6b)
1064 _ASM_EXTABLE(2b,7b)
1065 _ASM_EXTABLE(3b,8b)
1066 _ASM_EXTABLE(4b,9b)
1067 ENDPROC(xen_failsafe_callback)
1069 BUILD_INTERRUPT3(xen_hvm_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1070 xen_evtchn_do_upcall)
1072 #endif /* CONFIG_XEN */
1074 #if IS_ENABLED(CONFIG_HYPERV)
1076 BUILD_INTERRUPT3(hyperv_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1077 hyperv_vector_handler)
1079 #endif /* CONFIG_HYPERV */
1081 #ifdef CONFIG_FUNCTION_TRACER
1082 #ifdef CONFIG_DYNAMIC_FTRACE
1084 ENTRY(mcount)
1085 ret
1086 END(mcount)
1088 ENTRY(ftrace_caller)
1089 cmpl $0, function_trace_stop
1090 jne ftrace_stub
1092 pushl %eax
1093 pushl %ecx
1094 pushl %edx
1095 pushl $0 /* Pass NULL as regs pointer */
1096 movl 4*4(%esp), %eax
1097 movl 0x4(%ebp), %edx
1098 movl function_trace_op, %ecx
1099 subl $MCOUNT_INSN_SIZE, %eax
1101 .globl ftrace_call
1102 ftrace_call:
1103 call ftrace_stub
1105 addl $4,%esp /* skip NULL pointer */
1106 popl %edx
1107 popl %ecx
1108 popl %eax
1109 ftrace_ret:
1110 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1111 .globl ftrace_graph_call
1112 ftrace_graph_call:
1113 jmp ftrace_stub
1114 #endif
1116 .globl ftrace_stub
1117 ftrace_stub:
1118 ret
1119 END(ftrace_caller)
1121 ENTRY(ftrace_regs_caller)
1122 pushf /* push flags before compare (in cs location) */
1123 cmpl $0, function_trace_stop
1124 jne ftrace_restore_flags
1126 /*
1127 * i386 does not save SS and ESP when coming from kernel.
1128 * Instead, to get sp, ®s->sp is used (see ptrace.h).
1129 * Unfortunately, that means eflags must be at the same location
1130 * as the current return ip is. We move the return ip into the
1131 * ip location, and move flags into the return ip location.
1132 */
1133 pushl 4(%esp) /* save return ip into ip slot */
1135 pushl $0 /* Load 0 into orig_ax */
1136 pushl %gs
1137 pushl %fs
1138 pushl %es
1139 pushl %ds
1140 pushl %eax
1141 pushl %ebp
1142 pushl %edi
1143 pushl %esi
1144 pushl %edx
1145 pushl %ecx
1146 pushl %ebx
1148 movl 13*4(%esp), %eax /* Get the saved flags */
1149 movl %eax, 14*4(%esp) /* Move saved flags into regs->flags location */
1150 /* clobbering return ip */
1151 movl $__KERNEL_CS,13*4(%esp)
1153 movl 12*4(%esp), %eax /* Load ip (1st parameter) */
1154 subl $MCOUNT_INSN_SIZE, %eax /* Adjust ip */
1155 movl 0x4(%ebp), %edx /* Load parent ip (2nd parameter) */
1156 movl function_trace_op, %ecx /* Save ftrace_pos in 3rd parameter */
1157 pushl %esp /* Save pt_regs as 4th parameter */
1159 GLOBAL(ftrace_regs_call)
1160 call ftrace_stub
1162 addl $4, %esp /* Skip pt_regs */
1163 movl 14*4(%esp), %eax /* Move flags back into cs */
1164 movl %eax, 13*4(%esp) /* Needed to keep addl from modifying flags */
1165 movl 12*4(%esp), %eax /* Get return ip from regs->ip */
1166 movl %eax, 14*4(%esp) /* Put return ip back for ret */
1168 popl %ebx
1169 popl %ecx
1170 popl %edx
1171 popl %esi
1172 popl %edi
1173 popl %ebp
1174 popl %eax
1175 popl %ds
1176 popl %es
1177 popl %fs
1178 popl %gs
1179 addl $8, %esp /* Skip orig_ax and ip */
1180 popf /* Pop flags at end (no addl to corrupt flags) */
1181 jmp ftrace_ret
1183 ftrace_restore_flags:
1184 popf
1185 jmp ftrace_stub
1186 #else /* ! CONFIG_DYNAMIC_FTRACE */
1188 ENTRY(mcount)
1189 cmpl $__PAGE_OFFSET, %esp
1190 jb ftrace_stub /* Paging not enabled yet? */
1192 cmpl $0, function_trace_stop
1193 jne ftrace_stub
1195 cmpl $ftrace_stub, ftrace_trace_function
1196 jnz trace
1197 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1198 cmpl $ftrace_stub, ftrace_graph_return
1199 jnz ftrace_graph_caller
1201 cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1202 jnz ftrace_graph_caller
1203 #endif
1204 .globl ftrace_stub
1205 ftrace_stub:
1206 ret
1208 /* taken from glibc */
1209 trace:
1210 pushl %eax
1211 pushl %ecx
1212 pushl %edx
1213 movl 0xc(%esp), %eax
1214 movl 0x4(%ebp), %edx
1215 subl $MCOUNT_INSN_SIZE, %eax
1217 call *ftrace_trace_function
1219 popl %edx
1220 popl %ecx
1221 popl %eax
1222 jmp ftrace_stub
1223 END(mcount)
1224 #endif /* CONFIG_DYNAMIC_FTRACE */
1225 #endif /* CONFIG_FUNCTION_TRACER */
1227 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1228 ENTRY(ftrace_graph_caller)
1229 pushl %eax
1230 pushl %ecx
1231 pushl %edx
1232 movl 0xc(%esp), %edx
1233 lea 0x4(%ebp), %eax
1234 movl (%ebp), %ecx
1235 subl $MCOUNT_INSN_SIZE, %edx
1236 call prepare_ftrace_return
1237 popl %edx
1238 popl %ecx
1239 popl %eax
1240 ret
1241 END(ftrace_graph_caller)
1243 .globl return_to_handler
1244 return_to_handler:
1245 pushl %eax
1246 pushl %edx
1247 movl %ebp, %eax
1248 call ftrace_return_to_handler
1249 movl %eax, %ecx
1250 popl %edx
1251 popl %eax
1252 jmp *%ecx
1253 #endif
1255 /*
1256 * Some functions should be protected against kprobes
1257 */
1258 .pushsection .kprobes.text, "ax"
1260 ENTRY(page_fault)
1261 RING0_EC_FRAME
1262 ASM_CLAC
1263 pushl_cfi $do_page_fault
1264 ALIGN
1265 error_code:
1266 /* the function address is in %gs's slot on the stack */
1267 pushl_cfi %fs
1268 /*CFI_REL_OFFSET fs, 0*/
1269 pushl_cfi %es
1270 /*CFI_REL_OFFSET es, 0*/
1271 pushl_cfi %ds
1272 /*CFI_REL_OFFSET ds, 0*/
1273 pushl_cfi %eax
1274 CFI_REL_OFFSET eax, 0
1275 pushl_cfi %ebp
1276 CFI_REL_OFFSET ebp, 0
1277 pushl_cfi %edi
1278 CFI_REL_OFFSET edi, 0
1279 pushl_cfi %esi
1280 CFI_REL_OFFSET esi, 0
1281 pushl_cfi %edx
1282 CFI_REL_OFFSET edx, 0
1283 pushl_cfi %ecx
1284 CFI_REL_OFFSET ecx, 0
1285 pushl_cfi %ebx
1286 CFI_REL_OFFSET ebx, 0
1287 cld
1288 movl $(__KERNEL_PERCPU), %ecx
1289 movl %ecx, %fs
1290 UNWIND_ESPFIX_STACK
1291 GS_TO_REG %ecx
1292 movl PT_GS(%esp), %edi # get the function address
1293 movl PT_ORIG_EAX(%esp), %edx # get the error code
1294 movl $-1, PT_ORIG_EAX(%esp) # no syscall to restart
1295 REG_TO_PTGS %ecx
1296 SET_KERNEL_GS %ecx
1297 movl $(__USER_DS), %ecx
1298 movl %ecx, %ds
1299 movl %ecx, %es
1300 TRACE_IRQS_OFF
1301 movl %esp,%eax # pt_regs pointer
1302 call *%edi
1303 jmp ret_from_exception
1304 CFI_ENDPROC
1305 END(page_fault)
1307 /*
1308 * Debug traps and NMI can happen at the one SYSENTER instruction
1309 * that sets up the real kernel stack. Check here, since we can't
1310 * allow the wrong stack to be used.
1311 *
1312 * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1313 * already pushed 3 words if it hits on the sysenter instruction:
1314 * eflags, cs and eip.
1315 *
1316 * We just load the right stack, and push the three (known) values
1317 * by hand onto the new stack - while updating the return eip past
1318 * the instruction that would have done it for sysenter.
1319 */
1320 .macro FIX_STACK offset ok label
1321 cmpw $__KERNEL_CS, 4(%esp)
1322 jne \ok
1323 \label:
1324 movl TSS_sysenter_sp0 + \offset(%esp), %esp
1325 CFI_DEF_CFA esp, 0
1326 CFI_UNDEFINED eip
1327 pushfl_cfi
1328 pushl_cfi $__KERNEL_CS
1329 pushl_cfi $sysenter_past_esp
1330 CFI_REL_OFFSET eip, 0
1331 .endm
1333 ENTRY(debug)
1334 RING0_INT_FRAME
1335 ASM_CLAC
1336 cmpl $ia32_sysenter_target,(%esp)
1337 jne debug_stack_correct
1338 FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1339 debug_stack_correct:
1340 pushl_cfi $-1 # mark this as an int
1341 SAVE_ALL
1342 TRACE_IRQS_OFF
1343 xorl %edx,%edx # error code 0
1344 movl %esp,%eax # pt_regs pointer
1345 call do_debug
1346 jmp ret_from_exception
1347 CFI_ENDPROC
1348 END(debug)
1350 /*
1351 * NMI is doubly nasty. It can happen _while_ we're handling
1352 * a debug fault, and the debug fault hasn't yet been able to
1353 * clear up the stack. So we first check whether we got an
1354 * NMI on the sysenter entry path, but after that we need to
1355 * check whether we got an NMI on the debug path where the debug
1356 * fault happened on the sysenter path.
1357 */
1358 ENTRY(nmi)
1359 RING0_INT_FRAME
1360 ASM_CLAC
1361 #ifdef CONFIG_X86_ESPFIX32
1362 pushl_cfi %eax
1363 movl %ss, %eax
1364 cmpw $__ESPFIX_SS, %ax
1365 popl_cfi %eax
1366 je nmi_espfix_stack
1367 #endif
1368 cmpl $ia32_sysenter_target,(%esp)
1369 je nmi_stack_fixup
1370 pushl_cfi %eax
1371 movl %esp,%eax
1372 /* Do not access memory above the end of our stack page,
1373 * it might not exist.
1374 */
1375 andl $(THREAD_SIZE-1),%eax
1376 cmpl $(THREAD_SIZE-20),%eax
1377 popl_cfi %eax
1378 jae nmi_stack_correct
1379 cmpl $ia32_sysenter_target,12(%esp)
1380 je nmi_debug_stack_check
1381 nmi_stack_correct:
1382 /* We have a RING0_INT_FRAME here */
1383 pushl_cfi %eax
1384 SAVE_ALL
1385 xorl %edx,%edx # zero error code
1386 movl %esp,%eax # pt_regs pointer
1387 call do_nmi
1388 jmp restore_all_notrace
1389 CFI_ENDPROC
1391 nmi_stack_fixup:
1392 RING0_INT_FRAME
1393 FIX_STACK 12, nmi_stack_correct, 1
1394 jmp nmi_stack_correct
1396 nmi_debug_stack_check:
1397 /* We have a RING0_INT_FRAME here */
1398 cmpw $__KERNEL_CS,16(%esp)
1399 jne nmi_stack_correct
1400 cmpl $debug,(%esp)
1401 jb nmi_stack_correct
1402 cmpl $debug_esp_fix_insn,(%esp)
1403 ja nmi_stack_correct
1404 FIX_STACK 24, nmi_stack_correct, 1
1405 jmp nmi_stack_correct
1407 #ifdef CONFIG_X86_ESPFIX32
1408 nmi_espfix_stack:
1409 /* We have a RING0_INT_FRAME here.
1410 *
1411 * create the pointer to lss back
1412 */
1413 pushl_cfi %ss
1414 pushl_cfi %esp
1415 addl $4, (%esp)
1416 /* copy the iret frame of 12 bytes */
1417 .rept 3
1418 pushl_cfi 16(%esp)
1419 .endr
1420 pushl_cfi %eax
1421 SAVE_ALL
1422 FIXUP_ESPFIX_STACK # %eax == %esp
1423 xorl %edx,%edx # zero error code
1424 call do_nmi
1425 RESTORE_REGS
1426 lss 12+4(%esp), %esp # back to espfix stack
1427 CFI_ADJUST_CFA_OFFSET -24
1428 jmp irq_return
1429 #endif
1430 CFI_ENDPROC
1431 END(nmi)
1433 ENTRY(int3)
1434 RING0_INT_FRAME
1435 ASM_CLAC
1436 pushl_cfi $-1 # mark this as an int
1437 SAVE_ALL
1438 TRACE_IRQS_OFF
1439 xorl %edx,%edx # zero error code
1440 movl %esp,%eax # pt_regs pointer
1441 call do_int3
1442 jmp ret_from_exception
1443 CFI_ENDPROC
1444 END(int3)
1446 ENTRY(general_protection)
1447 RING0_EC_FRAME
1448 pushl_cfi $do_general_protection
1449 jmp error_code
1450 CFI_ENDPROC
1451 END(general_protection)
1453 #ifdef CONFIG_KVM_GUEST
1454 ENTRY(async_page_fault)
1455 RING0_EC_FRAME
1456 ASM_CLAC
1457 pushl_cfi $do_async_page_fault
1458 jmp error_code
1459 CFI_ENDPROC
1460 END(async_page_fault)
1461 #endif
1463 /*
1464 * End of kprobes section
1465 */
1466 .popsection