arch/powerpc/kernel/vdso32/vdso32.lds.S

   1 /*
   2  * This is the infamous ld script for the 32 bits vdso
   3  * library
   4  */
   5 #include <asm/vdso.h>
   6
   7 #ifdef __LITTLE_ENDIAN__
   8 OUTPUT_FORMAT("elf32-powerpcle", "elf32-powerpcle", "elf32-powerpcle")
   9 #else
  10 OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc", "elf32-powerpc")
  11 #endif
  12 OUTPUT_ARCH(powerpc:common)
  13 ENTRY(_start)
  14
  15 SECTIONS
  16 {
  17         . = VDSO32_LBASE + SIZEOF_HEADERS;
  18
  19         .hash           : { *(.hash) }                  :text
  20         .gnu.hash       : { *(.gnu.hash) }
  21         .dynsym         : { *(.dynsym) }
  22         .dynstr         : { *(.dynstr) }
  23         .gnu.version    : { *(.gnu.version) }
  24         .gnu.version_d  : { *(.gnu.version_d) }
  25         .gnu.version_r  : { *(.gnu.version_r) }
  26
  27         .note           : { *(.note.*) }                :text   :note
  28
  29         . = ALIGN(16);
  30         .text           : {
  31                 *(.text .stub .text.* .gnu.linkonce.t.* __ftr_alt_*)
  32         }                                               :text
  33         PROVIDE(__etext = .);
  34         PROVIDE(_etext = .);
  35         PROVIDE(etext = .);
  36
  37         . = ALIGN(8);
  38         __ftr_fixup     : { *(__ftr_fixup) }
  39
  40         . = ALIGN(8);
  41         __mmu_ftr_fixup : { *(__mmu_ftr_fixup) }
  42
  43         . = ALIGN(8);
  44         __lwsync_fixup  : { *(__lwsync_fixup) }
  45
  46 #ifdef CONFIG_PPC64
  47         . = ALIGN(8);
  48         __fw_ftr_fixup  : { *(__fw_ftr_fixup) }
  49 #endif
  50
  51         /*
  52          * Other stuff is appended to the text segment:
  53          */
  54         .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  55         .rodata1        : { *(.rodata1) }
  56
  57         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  58         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  59         .gcc_except_table : { *(.gcc_except_table) }
  60         .fixup          : { *(.fixup) }
  61
  62         .dynamic        : { *(.dynamic) }               :text   :dynamic
  63         .got            : { *(.got) }                   :text
  64         .plt            : { *(.plt) }
  65
  66         _end = .;
  67         __end = .;
  68         PROVIDE(end = .);
  69
  70         /*
  71          * Stabs debugging sections are here too.
  72          */
  73         .stab 0 : { *(.stab) }
  74         .stabstr 0 : { *(.stabstr) }
  75         .stab.excl 0 : { *(.stab.excl) }
  76         .stab.exclstr 0 : { *(.stab.exclstr) }
  77         .stab.index 0 : { *(.stab.index) }
  78         .stab.indexstr 0 : { *(.stab.indexstr) }
  79         .comment       0 : { *(.comment) }
  80
  81         /*
  82          * DWARF debug sections.
  83          * Symbols in the DWARF debugging sections are relative to the beginning
  84          * of the section so we begin them at 0.
  85          */
  86         /* DWARF 1 */
  87         .debug          0 : { *(.debug) }
  88         .line           0 : { *(.line) }
  89         /* GNU DWARF 1 extensions */
  90         .debug_srcinfo  0 : { *(.debug_srcinfo) }
  91         .debug_sfnames  0 : { *(.debug_sfnames) }
  92         /* DWARF 1.1 and DWARF 2 */
  93         .debug_aranges  0 : { *(.debug_aranges) }
  94         .debug_pubnames 0 : { *(.debug_pubnames) }
  95         /* DWARF 2 */
  96         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  97         .debug_abbrev   0 : { *(.debug_abbrev) }
  98         .debug_line     0 : { *(.debug_line) }
  99         .debug_frame    0 : { *(.debug_frame) }
 100         .debug_str      0 : { *(.debug_str) }
 101         .debug_loc      0 : { *(.debug_loc) }
 102         .debug_macinfo  0 : { *(.debug_macinfo) }
 103         /* SGI/MIPS DWARF 2 extensions */
 104         .debug_weaknames 0 : { *(.debug_weaknames) }
 105         .debug_funcnames 0 : { *(.debug_funcnames) }
 106         .debug_typenames 0 : { *(.debug_typenames) }
 107         .debug_varnames  0 : { *(.debug_varnames) }
 108
 109         /DISCARD/       : {
 110                 *(.note.GNU-stack)
 111                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
 112                 *(.bss .sbss .dynbss .dynsbss)
 113         }
 114 }
 115
 116 /*
 117  * Very old versions of ld do not recognize this name token; use the constant.
 118  */
 119 #define PT_GNU_EH_FRAME 0x6474e550
 120
 121 /*
 122  * We must supply the ELF program headers explicitly to get just one
 123  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 124  */
 125 PHDRS
 126 {
 127         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
 128         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
 129         note            PT_NOTE FLAGS(4);               /* PF_R */
 130         eh_frame_hdr    PT_GNU_EH_FRAME;
 131 }
 132
 133 /*
 134  * This controls what symbols we export from the DSO.
 135  */
 136 VERSION
 137 {
 138         VDSO_VERSION_STRING {
 139         global:
 140                 /*
 141                  * Has to be there for the kernel to find
 142                  */
 143                 __kernel_datapage_offset;
 144
 145                 __kernel_get_syscall_map;
 146                 __kernel_gettimeofday;
 147                 __kernel_clock_gettime;
 148                 __kernel_clock_getres;
 149                 __kernel_get_tbfreq;
 150                 __kernel_sync_dicache;
 151                 __kernel_sync_dicache_p5;
 152                 __kernel_sigtramp32;
 153                 __kernel_sigtramp_rt32;
 154 #ifdef CONFIG_PPC64
 155                 __kernel_getcpu;
 156 #endif
 157                 __kernel_time;
 158
 159         local: *;
 160         };
 161 }