arch/sparc/crypto/sha512_asm.S

   1 #include <linux/linkage.h>
   2 #include <asm/visasm.h>
   3
   4 #include "opcodes.h"
   5
   6 ENTRY(sha512_sparc64_transform)
   7         /* %o0 = digest, %o1 = data, %o2 = rounds */
   8         VISEntry
   9         ldd     [%o0 + 0x00], %f0
  10         ldd     [%o0 + 0x08], %f2
  11         ldd     [%o0 + 0x10], %f4
  12         ldd     [%o0 + 0x18], %f6
  13         ldd     [%o0 + 0x20], %f8
  14         ldd     [%o0 + 0x28], %f10
  15         andcc   %o1, 0x7, %g0
  16         ldd     [%o0 + 0x30], %f12
  17         bne,pn  %xcc, 10f
  18          ldd    [%o0 + 0x38], %f14
  19
  20 1:
  21         ldd     [%o1 + 0x00], %f16
  22         ldd     [%o1 + 0x08], %f18
  23         ldd     [%o1 + 0x10], %f20
  24         ldd     [%o1 + 0x18], %f22
  25         ldd     [%o1 + 0x20], %f24
  26         ldd     [%o1 + 0x28], %f26
  27         ldd     [%o1 + 0x30], %f28
  28         ldd     [%o1 + 0x38], %f30
  29         ldd     [%o1 + 0x40], %f32
  30         ldd     [%o1 + 0x48], %f34
  31         ldd     [%o1 + 0x50], %f36
  32         ldd     [%o1 + 0x58], %f38
  33         ldd     [%o1 + 0x60], %f40
  34         ldd     [%o1 + 0x68], %f42
  35         ldd     [%o1 + 0x70], %f44
  36         ldd     [%o1 + 0x78], %f46
  37
  38         SHA512
  39
  40         subcc   %o2, 1, %o2
  41         bne,pt  %xcc, 1b
  42          add    %o1, 0x80, %o1
  43
  44 5:
  45         std     %f0, [%o0 + 0x00]
  46         std     %f2, [%o0 + 0x08]
  47         std     %f4, [%o0 + 0x10]
  48         std     %f6, [%o0 + 0x18]
  49         std     %f8, [%o0 + 0x20]
  50         std     %f10, [%o0 + 0x28]
  51         std     %f12, [%o0 + 0x30]
  52         std     %f14, [%o0 + 0x38]
  53         retl
  54          VISExit
  55 10:
  56         alignaddr %o1, %g0, %o1
  57
  58         ldd     [%o1 + 0x00], %f18
  59 1:
  60         ldd     [%o1 + 0x08], %f20
  61         ldd     [%o1 + 0x10], %f22
  62         ldd     [%o1 + 0x18], %f24
  63         ldd     [%o1 + 0x20], %f26
  64         ldd     [%o1 + 0x28], %f28
  65         ldd     [%o1 + 0x30], %f30
  66         ldd     [%o1 + 0x38], %f32
  67         ldd     [%o1 + 0x40], %f34
  68         ldd     [%o1 + 0x48], %f36
  69         ldd     [%o1 + 0x50], %f38
  70         ldd     [%o1 + 0x58], %f40
  71         ldd     [%o1 + 0x60], %f42
  72         ldd     [%o1 + 0x68], %f44
  73         ldd     [%o1 + 0x70], %f46
  74         ldd     [%o1 + 0x78], %f48
  75         ldd     [%o1 + 0x80], %f50
  76
  77         faligndata %f18, %f20, %f16
  78         faligndata %f20, %f22, %f18
  79         faligndata %f22, %f24, %f20
  80         faligndata %f24, %f26, %f22
  81         faligndata %f26, %f28, %f24
  82         faligndata %f28, %f30, %f26
  83         faligndata %f30, %f32, %f28
  84         faligndata %f32, %f34, %f30
  85         faligndata %f34, %f36, %f32
  86         faligndata %f36, %f38, %f34
  87         faligndata %f38, %f40, %f36
  88         faligndata %f40, %f42, %f38
  89         faligndata %f42, %f44, %f40
  90         faligndata %f44, %f46, %f42
  91         faligndata %f46, %f48, %f44
  92         faligndata %f48, %f50, %f46
  93
  94         SHA512
  95
  96         subcc   %o2, 1, %o2
  97         fsrc2   %f50, %f18
  98         bne,pt  %xcc, 1b
  99          add    %o1, 0x80, %o1
 100
 101         ba,a,pt %xcc, 5b
 102 ENDPROC(sha512_sparc64_transform)