arch/mips/kernel/scall64-n64.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * Copyright (C) 1995, 96, 97, 98, 99, 2000, 01, 02 by Ralf Baechle
   7  * Copyright (C) 1999, 2000 Silicon Graphics, Inc.
   8  * Copyright (C) 2001 MIPS Technologies, Inc.
   9  */
  10 #include <linux/errno.h>
  11 #include <asm/asm.h>
  12 #include <asm/asmmacro.h>
  13 #include <asm/irqflags.h>
  14 #include <asm/mipsregs.h>
  15 #include <asm/regdef.h>
  16 #include <asm/stackframe.h>
  17 #include <asm/asm-offsets.h>
  18 #include <asm/sysmips.h>
  19 #include <asm/thread_info.h>
  20 #include <asm/unistd.h>
  21 #include <asm/war.h>
  22
  23 #ifndef CONFIG_BINFMT_ELF32
  24 /* Neither O32 nor N32, so define handle_sys here */
  25 #define handle_sys64 handle_sys
  26 #endif
  27
  28         .align  5
  29 NESTED(handle_sys64, PT_SIZE, sp)
  30 #if !defined(CONFIG_MIPS32_O32) && !defined(CONFIG_MIPS32_N32)
  31         /*
  32          * When 32-bit compatibility is configured scall_o32.S
  33          * already did this.
  34          */
  35         .set    noat
  36         SAVE_SOME
  37         TRACE_IRQS_ON_RELOAD
  38         STI
  39         .set    at
  40 #endif
  41
  42 #if !defined(CONFIG_MIPS32_O32) && !defined(CONFIG_MIPS32_N32)
  43         ld      t1, PT_EPC(sp)          # skip syscall on return
  44         daddiu  t1, 4                   # skip to next instruction
  45         sd      t1, PT_EPC(sp)
  46 #endif
  47
  48         sd      a3, PT_R26(sp)          # save a3 for syscall restarting
  49
  50         li      t1, _TIF_WORK_SYSCALL_ENTRY
  51         LONG_L  t0, TI_FLAGS($28)       # syscall tracing enabled?
  52         and     t0, t1, t0
  53         bnez    t0, syscall_trace_entry
  54
  55 syscall_common:
  56         dsubu   t2, v0, __NR_64_Linux
  57         sltiu   t0, t2, __NR_64_Linux_syscalls
  58         beqz    t0, illegal_syscall
  59
  60         dsll    t0, t2, 3               # offset into table
  61         dla     t2, sys_call_table
  62         daddu   t0, t2, t0
  63         ld      t2, (t0)                # syscall routine
  64         beqz    t2, illegal_syscall
  65
  66         jalr    t2                      # Do The Real Thing (TM)
  67
  68         li      t0, -EMAXERRNO - 1      # error?
  69         sltu    t0, t0, v0
  70         sd      t0, PT_R7(sp)           # set error flag
  71         beqz    t0, 1f
  72
  73         ld      t1, PT_R2(sp)           # syscall number
  74         dnegu   v0                      # error
  75         sd      t1, PT_R0(sp)           # save it for syscall restarting
  76 1:      sd      v0, PT_R2(sp)           # result
  77
  78 n64_syscall_exit:
  79         j       syscall_exit_partial
  80
  81 /* ------------------------------------------------------------------------ */
  82
  83 syscall_trace_entry:
  84         SAVE_STATIC
  85         move    a0, sp
  86         move    a1, v0
  87         jal     syscall_trace_enter
  88
  89         bltz    v0, 1f                  # seccomp failed? Skip syscall
  90
  91         RESTORE_STATIC
  92         ld      v0, PT_R2(sp)           # Restore syscall (maybe modified)
  93         ld      a0, PT_R4(sp)           # Restore argument registers
  94         ld      a1, PT_R5(sp)
  95         ld      a2, PT_R6(sp)
  96         ld      a3, PT_R7(sp)
  97         ld      a4, PT_R8(sp)
  98         ld      a5, PT_R9(sp)
  99         j       syscall_common
 100
 101 1:      j       syscall_exit
 102
 103 illegal_syscall:
 104         /* This also isn't a 64-bit syscall, throw an error.  */
 105         li      v0, ENOSYS                      # error
 106         sd      v0, PT_R2(sp)
 107         li      t0, 1                           # set error flag
 108         sd      t0, PT_R7(sp)
 109         j       n64_syscall_exit
 110         END(handle_sys64)
 111
 112 #define __SYSCALL(nr, entry)    PTR entry
 113         .align  3
 114         .type   sys_call_table, @object
 115 EXPORT(sys_call_table)
 116 #include <asm/syscall_table_64_n64.h>
 117 #undef __SYSCALL