scripts/coccinelle/free/ifnullfree.cocci

   1 // SPDX-License-Identifier: GPL-2.0-only
   2 /// NULL check before some freeing functions is not needed.
   3 ///
   4 /// Based on checkpatch warning
   5 /// "kfree(NULL) is safe this check is probably not required"
   6 /// and kfreeaddr.cocci by Julia Lawall.
   7 ///
   8 // Copyright: (C) 2014 Fabian Frederick.
   9 // Comments: -
  10 // Options: --no-includes --include-headers
  11
  12 virtual patch
  13 virtual org
  14 virtual report
  15 virtual context
  16
  17 @r2 depends on patch@
  18 expression E;
  19 @@
  20 - if (E != NULL)
  21 (
  22   kfree(E);
  23 |
  24   kzfree(E);
  25 |
  26   debugfs_remove(E);
  27 |
  28   debugfs_remove_recursive(E);
  29 |
  30   usb_free_urb(E);
  31 |
  32   kmem_cache_destroy(E);
  33 |
  34   mempool_destroy(E);
  35 |
  36   dma_pool_destroy(E);
  37 )
  38
  39 @r depends on context || report || org @
  40 expression E;
  41 position p;
  42 @@
  43
  44 * if (E != NULL)
  45 *       \(kfree@p\|kzfree@p\|debugfs_remove@p\|debugfs_remove_recursive@p\|
  46 *         usb_free_urb@p\|kmem_cache_destroy@p\|mempool_destroy@p\|
  47 *         dma_pool_destroy@p\)(E);
  48
  49 @script:python depends on org@
  50 p << r.p;
  51 @@
  52
  53 cocci.print_main("NULL check before that freeing function is not needed", p)
  54
  55 @script:python depends on report@
  56 p << r.p;
  57 @@
  58
  59 msg = "WARNING: NULL check before some freeing functions is not needed."
  60 coccilib.report.print_report(p[0], msg)