scripts/stackdelta

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0
   3
   4 # Read two files produced by the stackusage script, and show the
   5 # delta between them.
   6 #
   7 # Currently, only shows changes for functions listed in both files. We
   8 # could add an option to show also functions which have vanished or
   9 # appeared (which would often be due to gcc making other inlining
  10 # decisions).
  11 #
  12 # Another possible option would be a minimum absolute value for the
  13 # delta.
  14 #
  15 # A third possibility is for sorting by delta, but that can be
  16 # achieved by piping to sort -k5,5g.
  17
  18 sub read_stack_usage_file {
  19     my %su;
  20     my $f = shift;
  21     open(my $fh, '<', $f)
  22         or die "cannot open $f: $!";
  23     while (<$fh>) {
  24         chomp;
  25         my ($file, $func, $size, $type) = split;
  26         # Old versions of gcc (at least 4.7) have an annoying quirk in
  27         # that a (static) function whose name has been changed into
  28         # for example ext4_find_unwritten_pgoff.isra.11 will show up
  29         # in the .su file with a name of just "11". Since such a
  30         # numeric suffix is likely to change across different
  31         # commits/compilers/.configs or whatever else we're trying to
  32         # tweak, we can't really track those functions, so we just
  33         # silently skip them.
  34         #
  35         # Newer gcc (at least 5.0) report the full name, so again,
  36         # since the suffix is likely to change, we strip it.
  37         next if $func =~ m/^[0-9]+$/;
  38         $func =~ s/\..*$//;
  39         # Line numbers are likely to change; strip those.
  40         $file =~ s/:[0-9]+$//;
  41         $su{"${file}\t${func}"} = {size => $size, type => $type};
  42     }
  43     close($fh);
  44     return \%su;
  45 }
  46
  47 @ARGV == 2
  48     or die "usage: $0 <old> <new>";
  49
  50 my $old = read_stack_usage_file($ARGV[0]);
  51 my $new = read_stack_usage_file($ARGV[1]);
  52 my @common = sort grep {exists $new->{$_}} keys %$old;
  53 for (@common) {
  54     my $x = $old->{$_}{size};
  55     my $y = $new->{$_}{size};
  56     my $delta = $y - $x;
  57     if ($delta) {
  58         printf "%s\t%d\t%d\t%+d\n", $_, $x, $y, $delta;
  59     }
  60 }