arch/powerpc/kvm/book3s_interrupts.S

   1 /*
   2  * This program is free software; you can redistribute it and/or modify
   3  * it under the terms of the GNU General Public License, version 2, as
   4  * published by the Free Software Foundation.
   5  *
   6  * This program is distributed in the hope that it will be useful,
   7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   9  * GNU General Public License for more details.
  10  *
  11  * You should have received a copy of the GNU General Public License
  12  * along with this program; if not, write to the Free Software
  13  * Foundation, 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
  14  *
  15  * Copyright SUSE Linux Products GmbH 2009
  16  *
  17  * Authors: Alexander Graf <agraf@suse.de>
  18  */
  19
  20 #include <asm/ppc_asm.h>
  21 #include <asm/kvm_asm.h>
  22 #include <asm/reg.h>
  23 #include <asm/page.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/exception-64s.h>
  26
  27 #if defined(CONFIG_PPC_BOOK3S_64)
  28 #define FUNC(name)              GLUE(.,name)
  29 #elif defined(CONFIG_PPC_BOOK3S_32)
  30 #define FUNC(name)              name
  31 #endif /* CONFIG_PPC_BOOK3S_XX */
  32
  33 #define VCPU_LOAD_NVGPRS(vcpu) \
  34         PPC_LL  r14, VCPU_GPR(R14)(vcpu); \
  35         PPC_LL  r15, VCPU_GPR(R15)(vcpu); \
  36         PPC_LL  r16, VCPU_GPR(R16)(vcpu); \
  37         PPC_LL  r17, VCPU_GPR(R17)(vcpu); \
  38         PPC_LL  r18, VCPU_GPR(R18)(vcpu); \
  39         PPC_LL  r19, VCPU_GPR(R19)(vcpu); \
  40         PPC_LL  r20, VCPU_GPR(R20)(vcpu); \
  41         PPC_LL  r21, VCPU_GPR(R21)(vcpu); \
  42         PPC_LL  r22, VCPU_GPR(R22)(vcpu); \
  43         PPC_LL  r23, VCPU_GPR(R23)(vcpu); \
  44         PPC_LL  r24, VCPU_GPR(R24)(vcpu); \
  45         PPC_LL  r25, VCPU_GPR(R25)(vcpu); \
  46         PPC_LL  r26, VCPU_GPR(R26)(vcpu); \
  47         PPC_LL  r27, VCPU_GPR(R27)(vcpu); \
  48         PPC_LL  r28, VCPU_GPR(R28)(vcpu); \
  49         PPC_LL  r29, VCPU_GPR(R29)(vcpu); \
  50         PPC_LL  r30, VCPU_GPR(R30)(vcpu); \
  51         PPC_LL  r31, VCPU_GPR(R31)(vcpu); \
  52
  53 /*****************************************************************************
  54  *                                                                           *
  55  *     Guest entry / exit code that is in kernel module memory (highmem)     *
  56  *                                                                           *
  57  ****************************************************************************/
  58
  59 /* Registers:
  60  *  r3: kvm_run pointer
  61  *  r4: vcpu pointer
  62  */
  63 _GLOBAL(__kvmppc_vcpu_run)
  64
  65 kvm_start_entry:
  66         /* Write correct stack frame */
  67         mflr    r0
  68         PPC_STL r0,PPC_LR_STKOFF(r1)
  69
  70         /* Save host state to the stack */
  71         PPC_STLU r1, -SWITCH_FRAME_SIZE(r1)
  72
  73         /* Save r3 (kvm_run) and r4 (vcpu) */
  74         SAVE_2GPRS(3, r1)
  75
  76         /* Save non-volatile registers (r14 - r31) */
  77         SAVE_NVGPRS(r1)
  78
  79         /* Save CR */
  80         mfcr    r14
  81         stw     r14, _CCR(r1)
  82
  83         /* Save LR */
  84         PPC_STL r0, _LINK(r1)
  85
  86         /* Load non-volatile guest state from the vcpu */
  87         VCPU_LOAD_NVGPRS(r4)
  88
  89 kvm_start_lightweight:
  90
  91 #ifdef CONFIG_PPC_BOOK3S_64
  92         PPC_LL  r3, VCPU_HFLAGS(r4)
  93         rldicl  r3, r3, 0, 63           /* r3 &= 1 */
  94         stb     r3, HSTATE_RESTORE_HID5(r13)
  95
  96         /* Load up guest SPRG3 value, since it's user readable */
  97         ld      r3, VCPU_SHARED(r4)
  98         ld      r3, VCPU_SHARED_SPRG3(r3)
  99         mtspr   SPRN_SPRG3, r3
 100 #endif /* CONFIG_PPC_BOOK3S_64 */
 101
 102         PPC_LL  r4, VCPU_SHADOW_MSR(r4) /* get shadow_msr */
 103
 104         /* Jump to segment patching handler and into our guest */
 105         bl      FUNC(kvmppc_entry_trampoline)
 106         nop
 107
 108 /*
 109  * This is the handler in module memory. It gets jumped at from the
 110  * lowmem trampoline code, so it's basically the guest exit code.
 111  *
 112  */
 113
 114 .global kvmppc_handler_highmem
 115 kvmppc_handler_highmem:
 116
 117         /*
 118          * Register usage at this point:
 119          *
 120          * R1       = host R1
 121          * R2       = host R2
 122          * R12      = exit handler id
 123          * R13      = PACA
 124          * SVCPU.*  = guest *
 125          *
 126          */
 127
 128         /* R7 = vcpu */
 129         PPC_LL  r7, GPR4(r1)
 130
 131 #ifdef CONFIG_PPC_BOOK3S_64
 132         /*
 133          * Reload kernel SPRG3 value.
 134          * No need to save guest value as usermode can't modify SPRG3.
 135          */
 136         ld      r3, PACA_SPRG3(r13)
 137         mtspr   SPRN_SPRG3, r3
 138 #endif /* CONFIG_PPC_BOOK3S_64 */
 139
 140         PPC_STL r14, VCPU_GPR(R14)(r7)
 141         PPC_STL r15, VCPU_GPR(R15)(r7)
 142         PPC_STL r16, VCPU_GPR(R16)(r7)
 143         PPC_STL r17, VCPU_GPR(R17)(r7)
 144         PPC_STL r18, VCPU_GPR(R18)(r7)
 145         PPC_STL r19, VCPU_GPR(R19)(r7)
 146         PPC_STL r20, VCPU_GPR(R20)(r7)
 147         PPC_STL r21, VCPU_GPR(R21)(r7)
 148         PPC_STL r22, VCPU_GPR(R22)(r7)
 149         PPC_STL r23, VCPU_GPR(R23)(r7)
 150         PPC_STL r24, VCPU_GPR(R24)(r7)
 151         PPC_STL r25, VCPU_GPR(R25)(r7)
 152         PPC_STL r26, VCPU_GPR(R26)(r7)
 153         PPC_STL r27, VCPU_GPR(R27)(r7)
 154         PPC_STL r28, VCPU_GPR(R28)(r7)
 155         PPC_STL r29, VCPU_GPR(R29)(r7)
 156         PPC_STL r30, VCPU_GPR(R30)(r7)
 157         PPC_STL r31, VCPU_GPR(R31)(r7)
 158
 159         /* Pass the exit number as 3rd argument to kvmppc_handle_exit */
 160         mr      r5, r12
 161
 162         /* Restore r3 (kvm_run) and r4 (vcpu) */
 163         REST_2GPRS(3, r1)
 164         bl      FUNC(kvmppc_handle_exit)
 165
 166         /* If RESUME_GUEST, get back in the loop */
 167         cmpwi   r3, RESUME_GUEST
 168         beq     kvm_loop_lightweight
 169
 170         cmpwi   r3, RESUME_GUEST_NV
 171         beq     kvm_loop_heavyweight
 172
 173 kvm_exit_loop:
 174
 175         PPC_LL  r4, _LINK(r1)
 176         mtlr    r4
 177
 178         lwz     r14, _CCR(r1)
 179         mtcr    r14
 180
 181         /* Restore non-volatile host registers (r14 - r31) */
 182         REST_NVGPRS(r1)
 183
 184         addi    r1, r1, SWITCH_FRAME_SIZE
 185         blr
 186
 187 kvm_loop_heavyweight:
 188
 189         PPC_LL  r4, _LINK(r1)
 190         PPC_STL r4, (PPC_LR_STKOFF + SWITCH_FRAME_SIZE)(r1)
 191
 192         /* Load vcpu and cpu_run */
 193         REST_2GPRS(3, r1)
 194
 195         /* Load non-volatile guest state from the vcpu */
 196         VCPU_LOAD_NVGPRS(r4)
 197
 198         /* Jump back into the beginning of this function */
 199         b       kvm_start_lightweight
 200
 201 kvm_loop_lightweight:
 202
 203         /* We'll need the vcpu pointer */
 204         REST_GPR(4, r1)
 205
 206         /* Jump back into the beginning of this function */
 207         b       kvm_start_lightweight