scripts/dtc/dtc-lexer.l

   1 /*
   2  * (C) Copyright David Gibson <dwg@au1.ibm.com>, IBM Corporation.  2005.
   3  *
   4  *
   5  * This program is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU General Public License as
   7  * published by the Free Software Foundation; either version 2 of the
   8  * License, or (at your option) any later version.
   9  *
  10  *  This program is distributed in the hope that it will be useful,
  11  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  *  General Public License for more details.
  14  *
  15  *  You should have received a copy of the GNU General Public License
  16  *  along with this program; if not, write to the Free Software
  17  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307
  18  *                                                                   USA
  19  */
  20
  21 %option noyywrap nounput noinput never-interactive
  22
  23 %x BYTESTRING
  24 %x PROPNODENAME
  25 %s V1
  26
  27 PROPNODECHAR    [a-zA-Z0-9,._+*#?@-]
  28 PATHCHAR        ({PROPNODECHAR}|[/])
  29 LABEL           [a-zA-Z_][a-zA-Z0-9_]*
  30 STRING          \"([^\\"]|\\.)*\"
  31 CHAR_LITERAL    '([^']|\\')*'
  32 WS              [[:space:]]
  33 COMMENT         "/*"([^*]|\*+[^*/])*\*+"/"
  34 LINECOMMENT     "//".*\n
  35
  36 %{
  37 #include "dtc.h"
  38 #include "srcpos.h"
  39 #include "dtc-parser.tab.h"
  40
  41 YYLTYPE yylloc;
  42 extern bool treesource_error;
  43
  44 /* CAUTION: this will stop working if we ever use yyless() or yyunput() */
  45 #define YY_USER_ACTION \
  46         { \
  47                 srcpos_update(&yylloc, yytext, yyleng); \
  48         }
  49
  50 /*#define LEXDEBUG      1*/
  51
  52 #ifdef LEXDEBUG
  53 #define DPRINT(fmt, ...)        fprintf(stderr, fmt, ##__VA_ARGS__)
  54 #else
  55 #define DPRINT(fmt, ...)        do { } while (0)
  56 #endif
  57
  58 static int dts_version = 1;
  59
  60 #define BEGIN_DEFAULT()         DPRINT("<V1>\n"); \
  61                                 BEGIN(V1); \
  62
  63 static void push_input_file(const char *filename);
  64 static bool pop_input_file(void);
  65 static void PRINTF(1, 2) lexical_error(const char *fmt, ...);
  66
  67 %}
  68
  69 %%
  70 <*>"/include/"{WS}*{STRING} {
  71                         char *name = strchr(yytext, '\"') + 1;
  72                         yytext[yyleng-1] = '\0';
  73                         push_input_file(name);
  74                 }
  75
  76 <*>^"#"(line)?[ \t]+[0-9]+[ \t]+{STRING}([ \t]+[0-9]+)? {
  77                         char *line, *fnstart, *fnend;
  78                         struct data fn;
  79                         /* skip text before line # */
  80                         line = yytext;
  81                         while (!isdigit((unsigned char)*line))
  82                                 line++;
  83
  84                         /* regexp ensures that first and list "
  85                          * in the whole yytext are those at
  86                          * beginning and end of the filename string */
  87                         fnstart = memchr(yytext, '"', yyleng);
  88                         for (fnend = yytext + yyleng - 1;
  89                              *fnend != '"'; fnend--)
  90                                 ;
  91                         assert(fnstart && fnend && (fnend > fnstart));
  92
  93                         fn = data_copy_escape_string(fnstart + 1,
  94                                                      fnend - fnstart - 1);
  95
  96                         /* Don't allow nuls in filenames */
  97                         if (memchr(fn.val, '\0', fn.len - 1))
  98                                 lexical_error("nul in line number directive");
  99
 100                         /* -1 since #line is the number of the next line */
 101                         srcpos_set_line(xstrdup(fn.val), atoi(line) - 1);
 102                         data_free(fn);
 103                 }
 104
 105 <*><<EOF>>              {
 106                         if (!pop_input_file()) {
 107                                 yyterminate();
 108                         }
 109                 }
 110
 111 <*>{STRING}     {
 112                         DPRINT("String: %s\n", yytext);
 113                         yylval.data = data_copy_escape_string(yytext+1,
 114                                         yyleng-2);
 115                         return DT_STRING;
 116                 }
 117
 118 <*>"/dts-v1/"   {
 119                         DPRINT("Keyword: /dts-v1/\n");
 120                         dts_version = 1;
 121                         BEGIN_DEFAULT();
 122                         return DT_V1;
 123                 }
 124
 125 <*>"/plugin/"   {
 126                         DPRINT("Keyword: /plugin/\n");
 127                         return DT_PLUGIN;
 128                 }
 129
 130 <*>"/memreserve/"       {
 131                         DPRINT("Keyword: /memreserve/\n");
 132                         BEGIN_DEFAULT();
 133                         return DT_MEMRESERVE;
 134                 }
 135
 136 <*>"/bits/"     {
 137                         DPRINT("Keyword: /bits/\n");
 138                         BEGIN_DEFAULT();
 139                         return DT_BITS;
 140                 }
 141
 142 <*>"/delete-property/"  {
 143                         DPRINT("Keyword: /delete-property/\n");
 144                         DPRINT("<PROPNODENAME>\n");
 145                         BEGIN(PROPNODENAME);
 146                         return DT_DEL_PROP;
 147                 }
 148
 149 <*>"/delete-node/"      {
 150                         DPRINT("Keyword: /delete-node/\n");
 151                         DPRINT("<PROPNODENAME>\n");
 152                         BEGIN(PROPNODENAME);
 153                         return DT_DEL_NODE;
 154                 }
 155
 156 <*>"/omit-if-no-ref/"   {
 157                         DPRINT("Keyword: /omit-if-no-ref/\n");
 158                         DPRINT("<PROPNODENAME>\n");
 159                         BEGIN(PROPNODENAME);
 160                         return DT_OMIT_NO_REF;
 161                 }
 162
 163 <*>{LABEL}:     {
 164                         DPRINT("Label: %s\n", yytext);
 165                         yylval.labelref = xstrdup(yytext);
 166                         yylval.labelref[yyleng-1] = '\0';
 167                         return DT_LABEL;
 168                 }
 169
 170 <V1>([0-9]+|0[xX][0-9a-fA-F]+)(U|L|UL|LL|ULL)? {
 171                         char *e;
 172                         DPRINT("Integer Literal: '%s'\n", yytext);
 173
 174                         errno = 0;
 175                         yylval.integer = strtoull(yytext, &e, 0);
 176
 177                         if (*e && e[strspn(e, "UL")]) {
 178                                 lexical_error("Bad integer literal '%s'",
 179                                               yytext);
 180                         }
 181
 182                         if (errno == ERANGE)
 183                                 lexical_error("Integer literal '%s' out of range",
 184                                               yytext);
 185                         else
 186                                 /* ERANGE is the only strtoull error triggerable
 187                                  *  by strings matching the pattern */
 188                                 assert(errno == 0);
 189                         return DT_LITERAL;
 190                 }
 191
 192 <*>{CHAR_LITERAL}       {
 193                         struct data d;
 194                         DPRINT("Character literal: %s\n", yytext);
 195
 196                         d = data_copy_escape_string(yytext+1, yyleng-2);
 197                         if (d.len == 1) {
 198                                 lexical_error("Empty character literal");
 199                                 yylval.integer = 0;
 200                         } else {
 201                                 yylval.integer = (unsigned char)d.val[0];
 202
 203                                 if (d.len > 2)
 204                                         lexical_error("Character literal has %d"
 205                                                       " characters instead of 1",
 206                                                       d.len - 1);
 207                         }
 208
 209                         data_free(d);
 210                         return DT_CHAR_LITERAL;
 211                 }
 212
 213 <*>\&{LABEL}    {       /* label reference */
 214                         DPRINT("Ref: %s\n", yytext+1);
 215                         yylval.labelref = xstrdup(yytext+1);
 216                         return DT_REF;
 217                 }
 218
 219 <*>"&{/"{PATHCHAR}*\}   {       /* new-style path reference */
 220                         yytext[yyleng-1] = '\0';
 221                         DPRINT("Ref: %s\n", yytext+2);
 222                         yylval.labelref = xstrdup(yytext+2);
 223                         return DT_REF;
 224                 }
 225
 226 <BYTESTRING>[0-9a-fA-F]{2} {
 227                         yylval.byte = strtol(yytext, NULL, 16);
 228                         DPRINT("Byte: %02x\n", (int)yylval.byte);
 229                         return DT_BYTE;
 230                 }
 231
 232 <BYTESTRING>"]" {
 233                         DPRINT("/BYTESTRING\n");
 234                         BEGIN_DEFAULT();
 235                         return ']';
 236                 }
 237
 238 <PROPNODENAME>\\?{PROPNODECHAR}+ {
 239                         DPRINT("PropNodeName: %s\n", yytext);
 240                         yylval.propnodename = xstrdup((yytext[0] == '\\') ?
 241                                                         yytext + 1 : yytext);
 242                         BEGIN_DEFAULT();
 243                         return DT_PROPNODENAME;
 244                 }
 245
 246 "/incbin/"      {
 247                         DPRINT("Binary Include\n");
 248                         return DT_INCBIN;
 249                 }
 250
 251 <*>{WS}+        /* eat whitespace */
 252 <*>{COMMENT}+   /* eat C-style comments */
 253 <*>{LINECOMMENT}+ /* eat C++-style comments */
 254
 255 <*>"<<"         { return DT_LSHIFT; };
 256 <*>">>"         { return DT_RSHIFT; };
 257 <*>"<="         { return DT_LE; };
 258 <*>">="         { return DT_GE; };
 259 <*>"=="         { return DT_EQ; };
 260 <*>"!="         { return DT_NE; };
 261 <*>"&&"         { return DT_AND; };
 262 <*>"||"         { return DT_OR; };
 263
 264 <*>.            {
 265                         DPRINT("Char: %c (\\x%02x)\n", yytext[0],
 266                                 (unsigned)yytext[0]);
 267                         if (yytext[0] == '[') {
 268                                 DPRINT("<BYTESTRING>\n");
 269                                 BEGIN(BYTESTRING);
 270                         }
 271                         if ((yytext[0] == '{')
 272                             || (yytext[0] == ';')) {
 273                                 DPRINT("<PROPNODENAME>\n");
 274                                 BEGIN(PROPNODENAME);
 275                         }
 276                         return yytext[0];
 277                 }
 278
 279 %%
 280
 281 static void push_input_file(const char *filename)
 282 {
 283         assert(filename);
 284
 285         srcfile_push(filename);
 286
 287         yyin = current_srcfile->f;
 288
 289         yypush_buffer_state(yy_create_buffer(yyin, YY_BUF_SIZE));
 290 }
 291
 292
 293 static bool pop_input_file(void)
 294 {
 295         if (srcfile_pop() == 0)
 296                 return false;
 297
 298         yypop_buffer_state();
 299         yyin = current_srcfile->f;
 300
 301         return true;
 302 }
 303
 304 static void lexical_error(const char *fmt, ...)
 305 {
 306         va_list ap;
 307
 308         va_start(ap, fmt);
 309         srcpos_verror(&yylloc, "Lexical error", fmt, ap);
 310         va_end(ap);
 311
 312         treesource_error = true;
 313 }