arch/s390/kernel/vdso32/clock_gettime.S

   1 /*
   2  * Userland implementation of clock_gettime() for 32 bits processes in a
   3  * s390 kernel for use in the vDSO
   4  *
   5  *  Copyright IBM Corp. 2008
   6  *  Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com)
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License (version 2 only)
  10  * as published by the Free Software Foundation.
  11  */
  12 #include <asm/vdso.h>
  13 #include <asm/asm-offsets.h>
  14 #include <asm/unistd.h>
  15
  16         .text
  17         .align 4
  18         .globl __kernel_clock_gettime
  19         .type  __kernel_clock_gettime,@function
  20 __kernel_clock_gettime:
  21         .cfi_startproc
  22         ahi     %r15,-16
  23         basr    %r5,0
  24 0:      al      %r5,21f-0b(%r5)                 /* get &_vdso_data */
  25         chi     %r2,__CLOCK_REALTIME_COARSE
  26         je      10f
  27         chi     %r2,__CLOCK_REALTIME
  28         je      11f
  29         chi     %r2,__CLOCK_MONOTONIC_COARSE
  30         je      9f
  31         chi     %r2,__CLOCK_MONOTONIC
  32         jne     19f
  33
  34         /* CLOCK_MONOTONIC */
  35 1:      l       %r4,__VDSO_UPD_COUNT+4(%r5)     /* load update counter */
  36         tml     %r4,0x0001                      /* pending update ? loop */
  37         jnz     1b
  38         stcke   0(%r15)                         /* Store TOD clock */
  39         lm      %r0,%r1,1(%r15)
  40         s       %r0,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
  41         sl      %r1,__VDSO_XTIME_STAMP+4(%r5)
  42         brc     3,2f
  43         ahi     %r0,-1
  44 2:      ms      %r0,__VDSO_TK_MULT(%r5)         /*  * tk->mult */
  45         lr      %r2,%r0
  46         l       %r0,__VDSO_TK_MULT(%r5)
  47         ltr     %r1,%r1
  48         mr      %r0,%r0
  49         jnm     3f
  50         a       %r0,__VDSO_TK_MULT(%r5)
  51 3:      alr     %r0,%r2
  52         al      %r0,__VDSO_WTOM_NSEC(%r5)
  53         al      %r1,__VDSO_WTOM_NSEC+4(%r5)
  54         brc     12,5f
  55         ahi     %r0,1
  56 5:      l       %r2,__VDSO_TK_SHIFT(%r5)        /* Timekeeper shift */
  57         srdl    %r0,0(%r2)                      /*  >> tk->shift */
  58         l       %r2,__VDSO_WTOM_SEC+4(%r5)
  59         cl      %r4,__VDSO_UPD_COUNT+4(%r5)     /* check update counter */
  60         jne     1b
  61         basr    %r5,0
  62 6:      ltr     %r0,%r0
  63         jnz     7f
  64         cl      %r1,20f-6b(%r5)
  65         jl      8f
  66 7:      ahi     %r2,1
  67         sl      %r1,20f-6b(%r5)
  68         brc     3,6b
  69         ahi     %r0,-1
  70         j       6b
  71 8:      st      %r2,0(%r3)                      /* store tp->tv_sec */
  72         st      %r1,4(%r3)                      /* store tp->tv_nsec */
  73         lhi     %r2,0
  74         ahi     %r15,16
  75         br      %r14
  76
  77         /* CLOCK_MONOTONIC_COARSE */
  78 9:      l       %r4,__VDSO_UPD_COUNT+4(%r5)     /* load update counter */
  79         tml     %r4,0x0001                      /* pending update ? loop */
  80         jnz     9b
  81         l       %r2,__VDSO_WTOM_CRS_SEC+4(%r5)
  82         l       %r1,__VDSO_WTOM_CRS_NSEC+4(%r5)
  83         cl      %r4,__VDSO_UPD_COUNT+4(%r5)     /* check update counter */
  84         jne     9b
  85         j       8b
  86
  87         /* CLOCK_REALTIME_COARSE */
  88 10:     l       %r4,__VDSO_UPD_COUNT+4(%r5)     /* load update counter */
  89         tml     %r4,0x0001                      /* pending update ? loop */
  90         jnz     10b
  91         l       %r2,__VDSO_XTIME_CRS_SEC+4(%r5)
  92         l       %r1,__VDSO_XTIME_CRS_NSEC+4(%r5)
  93         cl      %r4,__VDSO_UPD_COUNT+4(%r5)     /* check update counter */
  94         jne     10b
  95         j       17f
  96
  97         /* CLOCK_REALTIME */
  98 11:     l       %r4,__VDSO_UPD_COUNT+4(%r5)     /* load update counter */
  99         tml     %r4,0x0001                      /* pending update ? loop */
 100         jnz     11b
 101         stcke   0(%r15)                         /* Store TOD clock */
 102         lm      %r0,%r1,__VDSO_TS_END(%r5)      /* TOD steering end time */
 103         s       %r0,1(%r15)                     /* no - ts_steering_end */
 104         sl      %r1,5(%r15)
 105         brc     3,22f
 106         ahi     %r0,-1
 107 22:     ltr     %r0,%r0                         /* past end of steering? */
 108         jm      24f
 109         srdl    %r0,15                          /* 1 per 2^16 */
 110         tm      __VDSO_TS_DIR+3(%r5),0x01       /* steering direction? */
 111         jz      23f
 112         lcr     %r0,%r0                         /* negative TOD offset */
 113         lcr     %r1,%r1
 114         je      23f
 115         ahi     %r0,-1
 116 23:     a       %r0,1(%r15)                     /* add TOD timestamp */
 117         al      %r1,5(%r15)
 118         brc     12,25f
 119         ahi     %r0,1
 120         j       25f
 121 24:     lm      %r0,%r1,1(%r15)                 /* load TOD timestamp */
 122 25:     s       %r0,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
 123         sl      %r1,__VDSO_XTIME_STAMP+4(%r5)
 124         brc     3,12f
 125         ahi     %r0,-1
 126 12:     ms      %r0,__VDSO_TK_MULT(%r5)         /*  * tk->mult */
 127         lr      %r2,%r0
 128         l       %r0,__VDSO_TK_MULT(%r5)
 129         ltr     %r1,%r1
 130         mr      %r0,%r0
 131         jnm     13f
 132         a       %r0,__VDSO_TK_MULT(%r5)
 133 13:     alr     %r0,%r2
 134         al      %r0,__VDSO_XTIME_NSEC(%r5)      /*  + tk->xtime_nsec */
 135         al      %r1,__VDSO_XTIME_NSEC+4(%r5)
 136         brc     12,14f
 137         ahi     %r0,1
 138 14:     l       %r2,__VDSO_TK_SHIFT(%r5)        /* Timekeeper shift */
 139         srdl    %r0,0(%r2)                      /*  >> tk->shift */
 140         l       %r2,__VDSO_XTIME_SEC+4(%r5)
 141         cl      %r4,__VDSO_UPD_COUNT+4(%r5)     /* check update counter */
 142         jne     11b
 143         basr    %r5,0
 144 15:     ltr     %r0,%r0
 145         jnz     16f
 146         cl      %r1,20f-15b(%r5)
 147         jl      17f
 148 16:     ahi     %r2,1
 149         sl      %r1,20f-15b(%r5)
 150         brc     3,15b
 151         ahi     %r0,-1
 152         j       15b
 153 17:     st      %r2,0(%r3)                      /* store tp->tv_sec */
 154         st      %r1,4(%r3)                      /* store tp->tv_nsec */
 155         lhi     %r2,0
 156         ahi     %r15,16
 157         br      %r14
 158
 159         /* Fallback to system call */
 160 19:     lhi     %r1,__NR_clock_gettime
 161         svc     0
 162         ahi     %r15,16
 163         br      %r14
 164
 165 20:     .long   1000000000
 166 21:     .long   _vdso_data - 0b
 167         .cfi_endproc
 168         .size   __kernel_clock_gettime,.-__kernel_clock_gettime