scripts/kconfig/zconf.l

   1 %option nostdinit noyywrap never-interactive full ecs
   2 %option 8bit nodefault perf-report perf-report
   3 %option noinput
   4 %x COMMAND HELP STRING PARAM
   5 %{
   6 /*
   7  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   8  * Released under the terms of the GNU GPL v2.0.
   9  */
  10
  11 #include <limits.h>
  12 #include <stdio.h>
  13 #include <stdlib.h>
  14 #include <string.h>
  15 #include <unistd.h>
  16
  17 #include "lkc.h"
  18
  19 #define START_STRSIZE   16
  20
  21 static struct {
  22         struct file *file;
  23         int lineno;
  24 } current_pos;
  25
  26 static char *text;
  27 static int text_size, text_asize;
  28
  29 struct buffer {
  30         struct buffer *parent;
  31         YY_BUFFER_STATE state;
  32 };
  33
  34 struct buffer *current_buf;
  35
  36 static int last_ts, first_ts;
  37
  38 static void zconf_endhelp(void);
  39 static void zconf_endfile(void);
  40
  41 static void new_string(void)
  42 {
  43         text = xmalloc(START_STRSIZE);
  44         text_asize = START_STRSIZE;
  45         text_size = 0;
  46         *text = 0;
  47 }
  48
  49 static void append_string(const char *str, int size)
  50 {
  51         int new_size = text_size + size + 1;
  52         if (new_size > text_asize) {
  53                 new_size += START_STRSIZE - 1;
  54                 new_size &= -START_STRSIZE;
  55                 text = realloc(text, new_size);
  56                 text_asize = new_size;
  57         }
  58         memcpy(text + text_size, str, size);
  59         text_size += size;
  60         text[text_size] = 0;
  61 }
  62
  63 static void alloc_string(const char *str, int size)
  64 {
  65         text = xmalloc(size + 1);
  66         memcpy(text, str, size);
  67         text[size] = 0;
  68 }
  69
  70 static void warn_ignored_character(char chr)
  71 {
  72         fprintf(stderr,
  73                 "%s:%d:warning: ignoring unsupported character '%c'\n",
  74                 current_file->name, yylineno, chr);
  75 }
  76 %}
  77
  78 n       [A-Za-z0-9_-]
  79
  80 %%
  81         int str = 0;
  82         int ts, i;
  83
  84 [ \t]*#.*\n     |
  85 [ \t]*\n        {
  86         current_file->lineno++;
  87         return T_EOL;
  88 }
  89 [ \t]*#.*
  90
  91
  92 [ \t]+  {
  93         BEGIN(COMMAND);
  94 }
  95
  96 .       {
  97         unput(yytext[0]);
  98         BEGIN(COMMAND);
  99 }
 100
 101
 102 <COMMAND>{
 103         {n}+    {
 104                 const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
 105                 BEGIN(PARAM);
 106                 current_pos.file = current_file;
 107                 current_pos.lineno = current_file->lineno;
 108                 if (id && id->flags & TF_COMMAND) {
 109                         zconflval.id = id;
 110                         return id->token;
 111                 }
 112                 alloc_string(yytext, yyleng);
 113                 zconflval.string = text;
 114                 return T_WORD;
 115         }
 116         .       warn_ignored_character(*yytext);
 117         \n      {
 118                 BEGIN(INITIAL);
 119                 current_file->lineno++;
 120                 return T_EOL;
 121         }
 122 }
 123
 124 <PARAM>{
 125         "&&"    return T_AND;
 126         "||"    return T_OR;
 127         "("     return T_OPEN_PAREN;
 128         ")"     return T_CLOSE_PAREN;
 129         "!"     return T_NOT;
 130         "="     return T_EQUAL;
 131         "!="    return T_UNEQUAL;
 132         "<="    return T_LESS_EQUAL;
 133         ">="    return T_GREATER_EQUAL;
 134         "<"     return T_LESS;
 135         ">"     return T_GREATER;
 136         \"|\'   {
 137                 str = yytext[0];
 138                 new_string();
 139                 BEGIN(STRING);
 140         }
 141         \n      BEGIN(INITIAL); current_file->lineno++; return T_EOL;
 142         ({n}|[/.])+     {
 143                 const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
 144                 if (id && id->flags & TF_PARAM) {
 145                         zconflval.id = id;
 146                         return id->token;
 147                 }
 148                 alloc_string(yytext, yyleng);
 149                 zconflval.string = text;
 150                 return T_WORD;
 151         }
 152         #.*     /* comment */
 153         \\\n    current_file->lineno++;
 154         [[:blank:]]+
 155         .       warn_ignored_character(*yytext);
 156         <<EOF>> {
 157                 BEGIN(INITIAL);
 158         }
 159 }
 160
 161 <STRING>{
 162         [^'"\\\n]+/\n   {
 163                 append_string(yytext, yyleng);
 164                 zconflval.string = text;
 165                 return T_WORD_QUOTE;
 166         }
 167         [^'"\\\n]+      {
 168                 append_string(yytext, yyleng);
 169         }
 170         \\.?/\n {
 171                 append_string(yytext + 1, yyleng - 1);
 172                 zconflval.string = text;
 173                 return T_WORD_QUOTE;
 174         }
 175         \\.?    {
 176                 append_string(yytext + 1, yyleng - 1);
 177         }
 178         \'|\"   {
 179                 if (str == yytext[0]) {
 180                         BEGIN(PARAM);
 181                         zconflval.string = text;
 182                         return T_WORD_QUOTE;
 183                 } else
 184                         append_string(yytext, 1);
 185         }
 186         \n      {
 187                 printf("%s:%d:warning: multi-line strings not supported\n", zconf_curname(), zconf_lineno());
 188                 current_file->lineno++;
 189                 BEGIN(INITIAL);
 190                 return T_EOL;
 191         }
 192         <<EOF>> {
 193                 BEGIN(INITIAL);
 194                 yylval.string = text;
 195                 return T_WORD_QUOTE;
 196         }
 197 }
 198
 199 <HELP>{
 200         [ \t]+  {
 201                 ts = 0;
 202                 for (i = 0; i < yyleng; i++) {
 203                         if (yytext[i] == '\t')
 204                                 ts = (ts & ~7) + 8;
 205                         else
 206                                 ts++;
 207                 }
 208                 last_ts = ts;
 209                 if (first_ts) {
 210                         if (ts < first_ts) {
 211                                 zconf_endhelp();
 212                                 return T_HELPTEXT;
 213                         }
 214                         ts -= first_ts;
 215                         while (ts > 8) {
 216                                 append_string("        ", 8);
 217                                 ts -= 8;
 218                         }
 219                         append_string("        ", ts);
 220                 }
 221         }
 222         [ \t]*\n/[^ \t\n] {
 223                 current_file->lineno++;
 224                 zconf_endhelp();
 225                 return T_HELPTEXT;
 226         }
 227         [ \t]*\n        {
 228                 current_file->lineno++;
 229                 append_string("\n", 1);
 230         }
 231         [^ \t\n].* {
 232                 while (yyleng) {
 233                         if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
 234                                 break;
 235                         yyleng--;
 236                 }
 237                 append_string(yytext, yyleng);
 238                 if (!first_ts)
 239                         first_ts = last_ts;
 240         }
 241         <<EOF>> {
 242                 zconf_endhelp();
 243                 return T_HELPTEXT;
 244         }
 245 }
 246
 247 <<EOF>> {
 248         if (current_file) {
 249                 zconf_endfile();
 250                 return T_EOL;
 251         }
 252         fclose(yyin);
 253         yyterminate();
 254 }
 255
 256 %%
 257 void zconf_starthelp(void)
 258 {
 259         new_string();
 260         last_ts = first_ts = 0;
 261         BEGIN(HELP);
 262 }
 263
 264 static void zconf_endhelp(void)
 265 {
 266         zconflval.string = text;
 267         BEGIN(INITIAL);
 268 }
 269
 270
 271 /*
 272  * Try to open specified file with following names:
 273  * ./name
 274  * $(srctree)/name
 275  * The latter is used when srctree is separate from objtree
 276  * when compiling the kernel.
 277  * Return NULL if file is not found.
 278  */
 279 FILE *zconf_fopen(const char *name)
 280 {
 281         char *env, fullname[PATH_MAX+1];
 282         FILE *f;
 283
 284         f = fopen(name, "r");
 285         if (!f && name != NULL && name[0] != '/') {
 286                 env = getenv(SRCTREE);
 287                 if (env) {
 288                         sprintf(fullname, "%s/%s", env, name);
 289                         f = fopen(fullname, "r");
 290                 }
 291         }
 292         return f;
 293 }
 294
 295 void zconf_initscan(const char *name)
 296 {
 297         yyin = zconf_fopen(name);
 298         if (!yyin) {
 299                 printf("can't find file %s\n", name);
 300                 exit(1);
 301         }
 302
 303         current_buf = xmalloc(sizeof(*current_buf));
 304         memset(current_buf, 0, sizeof(*current_buf));
 305
 306         current_file = file_lookup(name);
 307         current_file->lineno = 1;
 308 }
 309
 310 void zconf_nextfile(const char *name)
 311 {
 312         struct file *iter;
 313         struct file *file = file_lookup(name);
 314         struct buffer *buf = xmalloc(sizeof(*buf));
 315         memset(buf, 0, sizeof(*buf));
 316
 317         current_buf->state = YY_CURRENT_BUFFER;
 318         yyin = zconf_fopen(file->name);
 319         if (!yyin) {
 320                 printf("%s:%d: can't open file \"%s\"\n",
 321                     zconf_curname(), zconf_lineno(), file->name);
 322                 exit(1);
 323         }
 324         yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
 325         buf->parent = current_buf;
 326         current_buf = buf;
 327
 328         for (iter = current_file->parent; iter; iter = iter->parent ) {
 329                 if (!strcmp(current_file->name,iter->name) ) {
 330                         printf("%s:%d: recursive inclusion detected. "
 331                                "Inclusion path:\n  current file : '%s'\n",
 332                                zconf_curname(), zconf_lineno(),
 333                                zconf_curname());
 334                         iter = current_file->parent;
 335                         while (iter && \
 336                                strcmp(iter->name,current_file->name)) {
 337                                 printf("  included from: '%s:%d'\n",
 338                                        iter->name, iter->lineno-1);
 339                                 iter = iter->parent;
 340                         }
 341                         if (iter)
 342                                 printf("  included from: '%s:%d'\n",
 343                                        iter->name, iter->lineno+1);
 344                         exit(1);
 345                 }
 346         }
 347         file->lineno = 1;
 348         file->parent = current_file;
 349         current_file = file;
 350 }
 351
 352 static void zconf_endfile(void)
 353 {
 354         struct buffer *parent;
 355
 356         current_file = current_file->parent;
 357
 358         parent = current_buf->parent;
 359         if (parent) {
 360                 fclose(yyin);
 361                 yy_delete_buffer(YY_CURRENT_BUFFER);
 362                 yy_switch_to_buffer(parent->state);
 363         }
 364         free(current_buf);
 365         current_buf = parent;
 366 }
 367
 368 int zconf_lineno(void)
 369 {
 370         return current_pos.lineno;
 371 }
 372
 373 const char *zconf_curname(void)
 374 {
 375         return current_pos.file ? current_pos.file->name : "<none>";
 376 }