arch/alpha/lib/strchr.S

   1 /*
   2  * arch/alpha/lib/strchr.S
   3  * Contributed by Richard Henderson (rth@tamu.edu)
   4  *
   5  * Return the address of a given character within a null-terminated
   6  * string, or null if it is not found.
   7  */
   8
   9 #include <asm/regdef.h>
  10
  11         .set noreorder
  12         .set noat
  13
  14         .align 3
  15         .globl strchr
  16         .ent strchr
  17 strchr:
  18         .frame sp, 0, ra
  19         .prologue 0
  20
  21         zapnot  a1, 1, a1       # e0    : zero extend the search character
  22         ldq_u   t0, 0(a0)       # .. e1 : load first quadword
  23         sll     a1, 8, t5       # e0    : replicate the search character
  24         andnot  a0, 7, v0       # .. e1 : align our loop pointer
  25         or      t5, a1, a1      # e0    :
  26         lda     t4, -1          # .. e1 : build garbage mask
  27         sll     a1, 16, t5      # e0    :
  28         cmpbge  zero, t0, t2    # .. e1 : bits set iff byte == zero
  29         mskqh   t4, a0, t4      # e0    :
  30         or      t5, a1, a1      # .. e1 :
  31         sll     a1, 32, t5      # e0    :
  32         cmpbge  zero, t4, t4    # .. e1 : bits set iff byte is garbage
  33         or      t5, a1, a1      # e0    :
  34         xor     t0, a1, t1      # .. e1 : make bytes == c zero
  35         cmpbge  zero, t1, t3    # e0    : bits set iff byte == c
  36         or      t2, t3, t0      # e1    : bits set iff char match or zero match
  37         andnot  t0, t4, t0      # e0    : clear garbage bits
  38         bne     t0, $found      # .. e1 (zdb)
  39
  40 $loop:  ldq     t0, 8(v0)       # e0    :
  41         addq    v0, 8, v0       # .. e1 :
  42         nop                     # e0    :
  43         xor     t0, a1, t1      # .. e1 (ev5 data stall)
  44         cmpbge  zero, t0, t2    # e0    : bits set iff byte == 0
  45         cmpbge  zero, t1, t3    # .. e1 : bits set iff byte == c
  46         or      t2, t3, t0      # e0    :
  47         beq     t0, $loop       # .. e1 (zdb)
  48
  49 $found: negq    t0, t1          # e0    : clear all but least set bit
  50         and     t0, t1, t0      # e1 (stall)
  51
  52         and     t0, t3, t1      # e0    : bit set iff byte was the char
  53         beq     t1, $retnull    # .. e1 (zdb)
  54
  55         and     t0, 0xf0, t2    # e0    : binary search for that set bit
  56         and     t0, 0xcc, t3    # .. e1 :
  57         and     t0, 0xaa, t4    # e0    :
  58         cmovne  t2, 4, t2       # .. e1 :
  59         cmovne  t3, 2, t3       # e0    :
  60         cmovne  t4, 1, t4       # .. e1 :
  61         addq    t2, t3, t2      # e0    :
  62         addq    v0, t4, v0      # .. e1 :
  63         addq    v0, t2, v0      # e0    :
  64         ret                     # .. e1 :
  65
  66 $retnull:
  67         mov     zero, v0        # e0    :
  68         ret                     # .. e1 :
  69
  70         .end strchr