| blob | c251be7451079ac9150033b5987f6259902328b0 |
1 /*
2 * linux/arch/x86_64/entry.S
3 *
4 * Copyright (C) 1991, 1992 Linus Torvalds
5 * Copyright (C) 2000, 2001, 2002 Andi Kleen SuSE Labs
6 * Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
7 */
9 /*
10 * entry.S contains the system-call and fault low-level handling routines.
11 *
12 * NOTE: This code handles signal-recognition, which happens every time
13 * after an interrupt and after each system call.
14 *
15 * Normal syscalls and interrupts don't save a full stack frame, this is
16 * only done for syscall tracing, signals or fork/exec et.al.
17 *
18 * A note on terminology:
19 * - top of stack: Architecture defined interrupt frame from SS to RIP
20 * at the top of the kernel process stack.
21 * - partial stack frame: partially saved registers upto R11.
22 * - full stack frame: Like partial stack frame, but all register saved.
23 *
24 * Some macro usage:
25 * - CFI macros are used to generate dwarf2 unwind information for better
26 * backtraces. They don't change any code.
27 * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
28 * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
29 * There are unfortunately lots of special cases where some registers
30 * not touched. The macro is a big mess that should be cleaned up.
31 * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
32 * Gives a full stack frame.
33 * - ENTRY/END Define functions in the symbol table.
34 * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
35 * frame that is otherwise undefined after a SYSCALL
36 * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
37 * - errorentry/paranoidentry/zeroentry - Define exception entry points.
38 */
40 #include <linux/linkage.h>
41 #include <asm/segment.h>
42 #include <asm/cache.h>
43 #include <asm/errno.h>
44 #include <asm/dwarf2.h>
45 #include <asm/calling.h>
46 #include <asm/asm-offsets.h>
47 #include <asm/msr.h>
48 #include <asm/unistd.h>
49 #include <asm/thread_info.h>
50 #include <asm/hw_irq.h>
51 #include <asm/page_types.h>
52 #include <asm/irqflags.h>
53 #include <asm/paravirt.h>
54 #include <asm/ftrace.h>
55 #include <asm/percpu.h>
57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
58 #include <linux/elf-em.h>
59 #define AUDIT_ARCH_X86_64 (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
60 #define __AUDIT_ARCH_64BIT 0x80000000
61 #define __AUDIT_ARCH_LE 0x40000000
63 .code64
64 #ifdef CONFIG_FUNCTION_TRACER
65 #ifdef CONFIG_DYNAMIC_FTRACE
66 ENTRY(mcount)
67 retq
68 END(mcount)
70 ENTRY(ftrace_caller)
71 cmpl $0, function_trace_stop
72 jne ftrace_stub
74 MCOUNT_SAVE_FRAME
76 movq 0x38(%rsp), %rdi
77 movq 8(%rbp), %rsi
78 subq $MCOUNT_INSN_SIZE, %rdi
80 GLOBAL(ftrace_call)
81 call ftrace_stub
83 MCOUNT_RESTORE_FRAME
85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
86 GLOBAL(ftrace_graph_call)
87 jmp ftrace_stub
88 #endif
90 GLOBAL(ftrace_stub)
91 retq
92 END(ftrace_caller)
94 #else /* ! CONFIG_DYNAMIC_FTRACE */
95 ENTRY(mcount)
96 cmpl $0, function_trace_stop
97 jne ftrace_stub
99 cmpq $ftrace_stub, ftrace_trace_function
100 jnz trace
102 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
103 cmpq $ftrace_stub, ftrace_graph_return
104 jnz ftrace_graph_caller
106 cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
107 jnz ftrace_graph_caller
108 #endif
110 GLOBAL(ftrace_stub)
111 retq
113 trace:
114 MCOUNT_SAVE_FRAME
116 movq 0x38(%rsp), %rdi
117 movq 8(%rbp), %rsi
118 subq $MCOUNT_INSN_SIZE, %rdi
120 call *ftrace_trace_function
122 MCOUNT_RESTORE_FRAME
124 jmp ftrace_stub
125 END(mcount)
126 #endif /* CONFIG_DYNAMIC_FTRACE */
127 #endif /* CONFIG_FUNCTION_TRACER */
129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
130 ENTRY(ftrace_graph_caller)
131 cmpl $0, function_trace_stop
132 jne ftrace_stub
134 MCOUNT_SAVE_FRAME
136 leaq 8(%rbp), %rdi
137 movq 0x38(%rsp), %rsi
138 movq (%rbp), %rdx
139 subq $MCOUNT_INSN_SIZE, %rsi
141 call prepare_ftrace_return
143 MCOUNT_RESTORE_FRAME
145 retq
146 END(ftrace_graph_caller)
148 GLOBAL(return_to_handler)
149 subq $80, %rsp
151 /* Save the return values */
152 movq %rax, (%rsp)
153 movq %rdx, 8(%rsp)
154 movq %rbp, %rdi
156 call ftrace_return_to_handler
158 movq %rax, 72(%rsp)
159 movq 8(%rsp), %rdx
160 movq (%rsp), %rax
161 addq $72, %rsp
162 retq
163 #endif
166 #ifndef CONFIG_PREEMPT
167 #define retint_kernel retint_restore_args
168 #endif
170 #ifdef CONFIG_PARAVIRT
171 ENTRY(native_usergs_sysret64)
172 swapgs
173 sysretq
174 ENDPROC(native_usergs_sysret64)
175 #endif /* CONFIG_PARAVIRT */
178 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
179 #ifdef CONFIG_TRACE_IRQFLAGS
180 bt $9,EFLAGS-\offset(%rsp) /* interrupts off? */
181 jnc 1f
182 TRACE_IRQS_ON
183 1:
184 #endif
185 .endm
187 /*
188 * C code is not supposed to know about undefined top of stack. Every time
189 * a C function with an pt_regs argument is called from the SYSCALL based
190 * fast path FIXUP_TOP_OF_STACK is needed.
191 * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
192 * manipulation.
193 */
195 /* %rsp:at FRAMEEND */
196 .macro FIXUP_TOP_OF_STACK tmp offset=0
197 movq PER_CPU_VAR(old_rsp),\tmp
198 movq \tmp,RSP+\offset(%rsp)
199 movq $__USER_DS,SS+\offset(%rsp)
200 movq $__USER_CS,CS+\offset(%rsp)
201 movq $-1,RCX+\offset(%rsp)
202 movq R11+\offset(%rsp),\tmp /* get eflags */
203 movq \tmp,EFLAGS+\offset(%rsp)
204 .endm
206 .macro RESTORE_TOP_OF_STACK tmp offset=0
207 movq RSP+\offset(%rsp),\tmp
208 movq \tmp,PER_CPU_VAR(old_rsp)
209 movq EFLAGS+\offset(%rsp),\tmp
210 movq \tmp,R11+\offset(%rsp)
211 .endm
213 .macro FAKE_STACK_FRAME child_rip
214 /* push in order ss, rsp, eflags, cs, rip */
215 xorl %eax, %eax
216 pushq $__KERNEL_DS /* ss */
217 CFI_ADJUST_CFA_OFFSET 8
218 /*CFI_REL_OFFSET ss,0*/
219 pushq %rax /* rsp */
220 CFI_ADJUST_CFA_OFFSET 8
221 CFI_REL_OFFSET rsp,0
222 pushq $X86_EFLAGS_IF /* eflags - interrupts on */
223 CFI_ADJUST_CFA_OFFSET 8
224 /*CFI_REL_OFFSET rflags,0*/
225 pushq $__KERNEL_CS /* cs */
226 CFI_ADJUST_CFA_OFFSET 8
227 /*CFI_REL_OFFSET cs,0*/
228 pushq \child_rip /* rip */
229 CFI_ADJUST_CFA_OFFSET 8
230 CFI_REL_OFFSET rip,0
231 pushq %rax /* orig rax */
232 CFI_ADJUST_CFA_OFFSET 8
233 .endm
235 .macro UNFAKE_STACK_FRAME
236 addq $8*6, %rsp
237 CFI_ADJUST_CFA_OFFSET -(6*8)
238 .endm
240 /*
241 * initial frame state for interrupts (and exceptions without error code)
242 */
243 .macro EMPTY_FRAME start=1 offset=0
244 .if \start
245 CFI_STARTPROC simple
246 CFI_SIGNAL_FRAME
247 CFI_DEF_CFA rsp,8+\offset
248 .else
249 CFI_DEF_CFA_OFFSET 8+\offset
250 .endif
251 .endm
253 /*
254 * initial frame state for interrupts (and exceptions without error code)
255 */
256 .macro INTR_FRAME start=1 offset=0
257 EMPTY_FRAME \start, SS+8+\offset-RIP
258 /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
259 CFI_REL_OFFSET rsp, RSP+\offset-RIP
260 /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
261 /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
262 CFI_REL_OFFSET rip, RIP+\offset-RIP
263 .endm
265 /*
266 * initial frame state for exceptions with error code (and interrupts
267 * with vector already pushed)
268 */
269 .macro XCPT_FRAME start=1 offset=0
270 INTR_FRAME \start, RIP+\offset-ORIG_RAX
271 /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
272 .endm
274 /*
275 * frame that enables calling into C.
276 */
277 .macro PARTIAL_FRAME start=1 offset=0
278 XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
279 CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
280 CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
281 CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
282 CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
283 CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
284 CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
285 CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
286 CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
287 CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
288 .endm
290 /*
291 * frame that enables passing a complete pt_regs to a C function.
292 */
293 .macro DEFAULT_FRAME start=1 offset=0
294 PARTIAL_FRAME \start, R11+\offset-R15
295 CFI_REL_OFFSET rbx, RBX+\offset
296 CFI_REL_OFFSET rbp, RBP+\offset
297 CFI_REL_OFFSET r12, R12+\offset
298 CFI_REL_OFFSET r13, R13+\offset
299 CFI_REL_OFFSET r14, R14+\offset
300 CFI_REL_OFFSET r15, R15+\offset
301 .endm
303 /* save partial stack frame */
304 ENTRY(save_args)
305 XCPT_FRAME
306 cld
307 movq_cfi rdi, RDI+16-ARGOFFSET
308 movq_cfi rsi, RSI+16-ARGOFFSET
309 movq_cfi rdx, RDX+16-ARGOFFSET
310 movq_cfi rcx, RCX+16-ARGOFFSET
311 movq_cfi rax, RAX+16-ARGOFFSET
312 movq_cfi r8, R8+16-ARGOFFSET
313 movq_cfi r9, R9+16-ARGOFFSET
314 movq_cfi r10, R10+16-ARGOFFSET
315 movq_cfi r11, R11+16-ARGOFFSET
317 leaq -ARGOFFSET+16(%rsp),%rdi /* arg1 for handler */
318 movq_cfi rbp, 8 /* push %rbp */
319 leaq 8(%rsp), %rbp /* mov %rsp, %ebp */
320 testl $3, CS(%rdi)
321 je 1f
322 SWAPGS
323 /*
324 * irq_count is used to check if a CPU is already on an interrupt stack
325 * or not. While this is essentially redundant with preempt_count it is
326 * a little cheaper to use a separate counter in the PDA (short of
327 * moving irq_enter into assembly, which would be too much work)
328 */
329 1: incl PER_CPU_VAR(irq_count)
330 jne 2f
331 popq_cfi %rax /* move return address... */
332 mov PER_CPU_VAR(irq_stack_ptr),%rsp
333 EMPTY_FRAME 0
334 pushq_cfi %rbp /* backlink for unwinder */
335 pushq_cfi %rax /* ... to the new stack */
336 /*
337 * We entered an interrupt context - irqs are off:
338 */
339 2: TRACE_IRQS_OFF
340 ret
341 CFI_ENDPROC
342 END(save_args)
344 ENTRY(save_rest)
345 PARTIAL_FRAME 1 REST_SKIP+8
346 movq 5*8+16(%rsp), %r11 /* save return address */
347 movq_cfi rbx, RBX+16
348 movq_cfi rbp, RBP+16
349 movq_cfi r12, R12+16
350 movq_cfi r13, R13+16
351 movq_cfi r14, R14+16
352 movq_cfi r15, R15+16
353 movq %r11, 8(%rsp) /* return address */
354 FIXUP_TOP_OF_STACK %r11, 16
355 ret
356 CFI_ENDPROC
357 END(save_rest)
359 /* save complete stack frame */
360 .pushsection .kprobes.text, "ax"
361 ENTRY(save_paranoid)
362 XCPT_FRAME 1 RDI+8
363 cld
364 movq_cfi rdi, RDI+8
365 movq_cfi rsi, RSI+8
366 movq_cfi rdx, RDX+8
367 movq_cfi rcx, RCX+8
368 movq_cfi rax, RAX+8
369 movq_cfi r8, R8+8
370 movq_cfi r9, R9+8
371 movq_cfi r10, R10+8
372 movq_cfi r11, R11+8
373 movq_cfi rbx, RBX+8
374 movq_cfi rbp, RBP+8
375 movq_cfi r12, R12+8
376 movq_cfi r13, R13+8
377 movq_cfi r14, R14+8
378 movq_cfi r15, R15+8
379 movl $1,%ebx
380 movl $MSR_GS_BASE,%ecx
381 rdmsr
382 testl %edx,%edx
383 js 1f /* negative -> in kernel */
384 SWAPGS
385 xorl %ebx,%ebx
386 1: ret
387 CFI_ENDPROC
388 END(save_paranoid)
389 .popsection
391 /*
392 * A newly forked process directly context switches into this address.
393 *
394 * rdi: prev task we switched from
395 */
396 ENTRY(ret_from_fork)
397 DEFAULT_FRAME
399 LOCK ; btr $TIF_FORK,TI_flags(%r8)
401 push kernel_eflags(%rip)
402 CFI_ADJUST_CFA_OFFSET 8
403 popf # reset kernel eflags
404 CFI_ADJUST_CFA_OFFSET -8
406 call schedule_tail # rdi: 'prev' task parameter
408 GET_THREAD_INFO(%rcx)
410 RESTORE_REST
412 testl $3, CS-ARGOFFSET(%rsp) # from kernel_thread?
413 je int_ret_from_sys_call
415 testl $_TIF_IA32, TI_flags(%rcx) # 32-bit compat task needs IRET
416 jnz int_ret_from_sys_call
418 RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
419 jmp ret_from_sys_call # go to the SYSRET fastpath
421 CFI_ENDPROC
422 END(ret_from_fork)
424 /*
425 * System call entry. Upto 6 arguments in registers are supported.
426 *
427 * SYSCALL does not save anything on the stack and does not change the
428 * stack pointer.
429 */
431 /*
432 * Register setup:
433 * rax system call number
434 * rdi arg0
435 * rcx return address for syscall/sysret, C arg3
436 * rsi arg1
437 * rdx arg2
438 * r10 arg3 (--> moved to rcx for C)
439 * r8 arg4
440 * r9 arg5
441 * r11 eflags for syscall/sysret, temporary for C
442 * r12-r15,rbp,rbx saved by C code, not touched.
443 *
444 * Interrupts are off on entry.
445 * Only called from user space.
446 *
447 * XXX if we had a free scratch register we could save the RSP into the stack frame
448 * and report it properly in ps. Unfortunately we haven't.
449 *
450 * When user can change the frames always force IRET. That is because
451 * it deals with uncanonical addresses better. SYSRET has trouble
452 * with them due to bugs in both AMD and Intel CPUs.
453 */
455 ENTRY(system_call)
456 CFI_STARTPROC simple
457 CFI_SIGNAL_FRAME
458 CFI_DEF_CFA rsp,KERNEL_STACK_OFFSET
459 CFI_REGISTER rip,rcx
460 /*CFI_REGISTER rflags,r11*/
461 SWAPGS_UNSAFE_STACK
462 /*
463 * A hypervisor implementation might want to use a label
464 * after the swapgs, so that it can do the swapgs
465 * for the guest and jump here on syscall.
466 */
467 ENTRY(system_call_after_swapgs)
469 movq %rsp,PER_CPU_VAR(old_rsp)
470 movq PER_CPU_VAR(kernel_stack),%rsp
471 /*
472 * No need to follow this irqs off/on section - it's straight
473 * and short:
474 */
475 ENABLE_INTERRUPTS(CLBR_NONE)
476 SAVE_ARGS 8,1
477 movq %rax,ORIG_RAX-ARGOFFSET(%rsp)
478 movq %rcx,RIP-ARGOFFSET(%rsp)
479 CFI_REL_OFFSET rip,RIP-ARGOFFSET
480 GET_THREAD_INFO(%rcx)
481 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
482 jnz tracesys
483 system_call_fastpath:
484 cmpq $__NR_syscall_max,%rax
485 ja badsys
486 movq %r10,%rcx
487 call *sys_call_table(,%rax,8) # XXX: rip relative
488 movq %rax,RAX-ARGOFFSET(%rsp)
489 /*
490 * Syscall return path ending with SYSRET (fast path)
491 * Has incomplete stack frame and undefined top of stack.
492 */
493 ret_from_sys_call:
494 movl $_TIF_ALLWORK_MASK,%edi
495 /* edi: flagmask */
496 sysret_check:
497 LOCKDEP_SYS_EXIT
498 GET_THREAD_INFO(%rcx)
499 DISABLE_INTERRUPTS(CLBR_NONE)
500 TRACE_IRQS_OFF
501 movl TI_flags(%rcx),%edx
502 andl %edi,%edx
503 jnz sysret_careful
504 CFI_REMEMBER_STATE
505 /*
506 * sysretq will re-enable interrupts:
507 */
508 TRACE_IRQS_ON
509 movq RIP-ARGOFFSET(%rsp),%rcx
510 CFI_REGISTER rip,rcx
511 RESTORE_ARGS 0,-ARG_SKIP,1
512 /*CFI_REGISTER rflags,r11*/
513 movq PER_CPU_VAR(old_rsp), %rsp
514 USERGS_SYSRET64
516 CFI_RESTORE_STATE
517 /* Handle reschedules */
518 /* edx: work, edi: workmask */
519 sysret_careful:
520 bt $TIF_NEED_RESCHED,%edx
521 jnc sysret_signal
522 TRACE_IRQS_ON
523 ENABLE_INTERRUPTS(CLBR_NONE)
524 pushq %rdi
525 CFI_ADJUST_CFA_OFFSET 8
526 call schedule
527 popq %rdi
528 CFI_ADJUST_CFA_OFFSET -8
529 jmp sysret_check
531 /* Handle a signal */
532 sysret_signal:
533 TRACE_IRQS_ON
534 ENABLE_INTERRUPTS(CLBR_NONE)
535 #ifdef CONFIG_AUDITSYSCALL
536 bt $TIF_SYSCALL_AUDIT,%edx
537 jc sysret_audit
538 #endif
539 /* edx: work flags (arg3) */
540 leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
541 xorl %esi,%esi # oldset -> arg2
542 SAVE_REST
543 FIXUP_TOP_OF_STACK %r11
544 call do_notify_resume
545 RESTORE_TOP_OF_STACK %r11
546 RESTORE_REST
547 movl $_TIF_WORK_MASK,%edi
548 /* Use IRET because user could have changed frame. This
549 works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
550 DISABLE_INTERRUPTS(CLBR_NONE)
551 TRACE_IRQS_OFF
552 jmp int_with_check
554 badsys:
555 movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
556 jmp ret_from_sys_call
558 #ifdef CONFIG_AUDITSYSCALL
559 /*
560 * Fast path for syscall audit without full syscall trace.
561 * We just call audit_syscall_entry() directly, and then
562 * jump back to the normal fast path.
563 */
564 auditsys:
565 movq %r10,%r9 /* 6th arg: 4th syscall arg */
566 movq %rdx,%r8 /* 5th arg: 3rd syscall arg */
567 movq %rsi,%rcx /* 4th arg: 2nd syscall arg */
568 movq %rdi,%rdx /* 3rd arg: 1st syscall arg */
569 movq %rax,%rsi /* 2nd arg: syscall number */
570 movl $AUDIT_ARCH_X86_64,%edi /* 1st arg: audit arch */
571 call audit_syscall_entry
572 LOAD_ARGS 0 /* reload call-clobbered registers */
573 jmp system_call_fastpath
575 /*
576 * Return fast path for syscall audit. Call audit_syscall_exit()
577 * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
578 * masked off.
579 */
580 sysret_audit:
581 movq %rax,%rsi /* second arg, syscall return value */
582 cmpq $0,%rax /* is it < 0? */
583 setl %al /* 1 if so, 0 if not */
584 movzbl %al,%edi /* zero-extend that into %edi */
585 inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
586 call audit_syscall_exit
587 movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
588 jmp sysret_check
589 #endif /* CONFIG_AUDITSYSCALL */
591 /* Do syscall tracing */
592 tracesys:
593 #ifdef CONFIG_AUDITSYSCALL
594 testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
595 jz auditsys
596 #endif
597 SAVE_REST
598 movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
599 FIXUP_TOP_OF_STACK %rdi
600 movq %rsp,%rdi
601 call syscall_trace_enter
602 /*
603 * Reload arg registers from stack in case ptrace changed them.
604 * We don't reload %rax because syscall_trace_enter() returned
605 * the value it wants us to use in the table lookup.
606 */
607 LOAD_ARGS ARGOFFSET, 1
608 RESTORE_REST
609 cmpq $__NR_syscall_max,%rax
610 ja int_ret_from_sys_call /* RAX(%rsp) set to -ENOSYS above */
611 movq %r10,%rcx /* fixup for C */
612 call *sys_call_table(,%rax,8)
613 movq %rax,RAX-ARGOFFSET(%rsp)
614 /* Use IRET because user could have changed frame */
616 /*
617 * Syscall return path ending with IRET.
618 * Has correct top of stack, but partial stack frame.
619 */
620 GLOBAL(int_ret_from_sys_call)
621 DISABLE_INTERRUPTS(CLBR_NONE)
622 TRACE_IRQS_OFF
623 testl $3,CS-ARGOFFSET(%rsp)
624 je retint_restore_args
625 movl $_TIF_ALLWORK_MASK,%edi
626 /* edi: mask to check */
627 GLOBAL(int_with_check)
628 LOCKDEP_SYS_EXIT_IRQ
629 GET_THREAD_INFO(%rcx)
630 movl TI_flags(%rcx),%edx
631 andl %edi,%edx
632 jnz int_careful
633 andl $~TS_COMPAT,TI_status(%rcx)
634 jmp retint_swapgs
636 /* Either reschedule or signal or syscall exit tracking needed. */
637 /* First do a reschedule test. */
638 /* edx: work, edi: workmask */
639 int_careful:
640 bt $TIF_NEED_RESCHED,%edx
641 jnc int_very_careful
642 TRACE_IRQS_ON
643 ENABLE_INTERRUPTS(CLBR_NONE)
644 pushq %rdi
645 CFI_ADJUST_CFA_OFFSET 8
646 call schedule
647 popq %rdi
648 CFI_ADJUST_CFA_OFFSET -8
649 DISABLE_INTERRUPTS(CLBR_NONE)
650 TRACE_IRQS_OFF
651 jmp int_with_check
653 /* handle signals and tracing -- both require a full stack frame */
654 int_very_careful:
655 TRACE_IRQS_ON
656 ENABLE_INTERRUPTS(CLBR_NONE)
657 SAVE_REST
658 /* Check for syscall exit trace */
659 testl $_TIF_WORK_SYSCALL_EXIT,%edx
660 jz int_signal
661 pushq %rdi
662 CFI_ADJUST_CFA_OFFSET 8
663 leaq 8(%rsp),%rdi # &ptregs -> arg1
664 call syscall_trace_leave
665 popq %rdi
666 CFI_ADJUST_CFA_OFFSET -8
667 andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
668 jmp int_restore_rest
670 int_signal:
671 testl $_TIF_DO_NOTIFY_MASK,%edx
672 jz 1f
673 movq %rsp,%rdi # &ptregs -> arg1
674 xorl %esi,%esi # oldset -> arg2
675 call do_notify_resume
676 1: movl $_TIF_WORK_MASK,%edi
677 int_restore_rest:
678 RESTORE_REST
679 DISABLE_INTERRUPTS(CLBR_NONE)
680 TRACE_IRQS_OFF
681 jmp int_with_check
682 CFI_ENDPROC
683 END(system_call)
685 /*
686 * Certain special system calls that need to save a complete full stack frame.
687 */
688 .macro PTREGSCALL label,func,arg
689 ENTRY(\label)
690 PARTIAL_FRAME 1 8 /* offset 8: return address */
691 subq $REST_SKIP, %rsp
692 CFI_ADJUST_CFA_OFFSET REST_SKIP
693 call save_rest
694 DEFAULT_FRAME 0 8 /* offset 8: return address */
695 leaq 8(%rsp), \arg /* pt_regs pointer */
696 call \func
697 jmp ptregscall_common
698 CFI_ENDPROC
699 END(\label)
700 .endm
702 PTREGSCALL stub_clone, sys_clone, %r8
703 PTREGSCALL stub_fork, sys_fork, %rdi
704 PTREGSCALL stub_vfork, sys_vfork, %rdi
705 PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
706 PTREGSCALL stub_iopl, sys_iopl, %rsi
708 ENTRY(ptregscall_common)
709 DEFAULT_FRAME 1 8 /* offset 8: return address */
710 RESTORE_TOP_OF_STACK %r11, 8
711 movq_cfi_restore R15+8, r15
712 movq_cfi_restore R14+8, r14
713 movq_cfi_restore R13+8, r13
714 movq_cfi_restore R12+8, r12
715 movq_cfi_restore RBP+8, rbp
716 movq_cfi_restore RBX+8, rbx
717 ret $REST_SKIP /* pop extended registers */
718 CFI_ENDPROC
719 END(ptregscall_common)
721 ENTRY(stub_execve)
722 CFI_STARTPROC
723 popq %r11
724 CFI_ADJUST_CFA_OFFSET -8
725 CFI_REGISTER rip, r11
726 SAVE_REST
727 FIXUP_TOP_OF_STACK %r11
728 movq %rsp, %rcx
729 call sys_execve
730 RESTORE_TOP_OF_STACK %r11
731 movq %rax,RAX(%rsp)
732 RESTORE_REST
733 jmp int_ret_from_sys_call
734 CFI_ENDPROC
735 END(stub_execve)
737 /*
738 * sigreturn is special because it needs to restore all registers on return.
739 * This cannot be done with SYSRET, so use the IRET return path instead.
740 */
741 ENTRY(stub_rt_sigreturn)
742 CFI_STARTPROC
743 addq $8, %rsp
744 CFI_ADJUST_CFA_OFFSET -8
745 SAVE_REST
746 movq %rsp,%rdi
747 FIXUP_TOP_OF_STACK %r11
748 call sys_rt_sigreturn
749 movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
750 RESTORE_REST
751 jmp int_ret_from_sys_call
752 CFI_ENDPROC
753 END(stub_rt_sigreturn)
755 /*
756 * Build the entry stubs and pointer table with some assembler magic.
757 * We pack 7 stubs into a single 32-byte chunk, which will fit in a
758 * single cache line on all modern x86 implementations.
759 */
760 .section .init.rodata,"a"
761 ENTRY(interrupt)
762 .text
763 .p2align 5
764 .p2align CONFIG_X86_L1_CACHE_SHIFT
765 ENTRY(irq_entries_start)
766 INTR_FRAME
767 vector=FIRST_EXTERNAL_VECTOR
768 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
769 .balign 32
770 .rept 7
771 .if vector < NR_VECTORS
772 .if vector <> FIRST_EXTERNAL_VECTOR
773 CFI_ADJUST_CFA_OFFSET -8
774 .endif
775 1: pushq $(~vector+0x80) /* Note: always in signed byte range */
776 CFI_ADJUST_CFA_OFFSET 8
777 .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
778 jmp 2f
779 .endif
780 .previous
781 .quad 1b
782 .text
783 vector=vector+1
784 .endif
785 .endr
786 2: jmp common_interrupt
787 .endr
788 CFI_ENDPROC
789 END(irq_entries_start)
791 .previous
792 END(interrupt)
793 .previous
795 /*
796 * Interrupt entry/exit.
797 *
798 * Interrupt entry points save only callee clobbered registers in fast path.
799 *
800 * Entry runs with interrupts off.
801 */
803 /* 0(%rsp): ~(interrupt number) */
804 .macro interrupt func
805 subq $10*8, %rsp
806 CFI_ADJUST_CFA_OFFSET 10*8
807 call save_args
808 PARTIAL_FRAME 0
809 call \func
810 .endm
812 /*
813 * The interrupt stubs push (~vector+0x80) onto the stack and
814 * then jump to common_interrupt.
815 */
816 .p2align CONFIG_X86_L1_CACHE_SHIFT
817 common_interrupt:
818 XCPT_FRAME
819 addq $-0x80,(%rsp) /* Adjust vector to [-256,-1] range */
820 interrupt do_IRQ
821 /* 0(%rsp): old_rsp-ARGOFFSET */
822 ret_from_intr:
823 DISABLE_INTERRUPTS(CLBR_NONE)
824 TRACE_IRQS_OFF
825 decl PER_CPU_VAR(irq_count)
826 leaveq
827 CFI_DEF_CFA_REGISTER rsp
828 CFI_ADJUST_CFA_OFFSET -8
829 exit_intr:
830 GET_THREAD_INFO(%rcx)
831 testl $3,CS-ARGOFFSET(%rsp)
832 je retint_kernel
834 /* Interrupt came from user space */
835 /*
836 * Has a correct top of stack, but a partial stack frame
837 * %rcx: thread info. Interrupts off.
838 */
839 retint_with_reschedule:
840 movl $_TIF_WORK_MASK,%edi
841 retint_check:
842 LOCKDEP_SYS_EXIT_IRQ
843 movl TI_flags(%rcx),%edx
844 andl %edi,%edx
845 CFI_REMEMBER_STATE
846 jnz retint_careful
848 retint_swapgs: /* return to user-space */
849 /*
850 * The iretq could re-enable interrupts:
851 */
852 DISABLE_INTERRUPTS(CLBR_ANY)
853 TRACE_IRQS_IRETQ
854 SWAPGS
855 jmp restore_args
857 retint_restore_args: /* return to kernel space */
858 DISABLE_INTERRUPTS(CLBR_ANY)
859 /*
860 * The iretq could re-enable interrupts:
861 */
862 TRACE_IRQS_IRETQ
863 restore_args:
864 RESTORE_ARGS 0,8,0
866 irq_return:
867 INTERRUPT_RETURN
869 .section __ex_table, "a"
870 .quad irq_return, bad_iret
871 .previous
873 #ifdef CONFIG_PARAVIRT
874 ENTRY(native_iret)
875 iretq
877 .section __ex_table,"a"
878 .quad native_iret, bad_iret
879 .previous
880 #endif
882 .section .fixup,"ax"
883 bad_iret:
884 /*
885 * The iret traps when the %cs or %ss being restored is bogus.
886 * We've lost the original trap vector and error code.
887 * #GPF is the most likely one to get for an invalid selector.
888 * So pretend we completed the iret and took the #GPF in user mode.
889 *
890 * We are now running with the kernel GS after exception recovery.
891 * But error_entry expects us to have user GS to match the user %cs,
892 * so swap back.
893 */
894 pushq $0
896 SWAPGS
897 jmp general_protection
899 .previous
901 /* edi: workmask, edx: work */
902 retint_careful:
903 CFI_RESTORE_STATE
904 bt $TIF_NEED_RESCHED,%edx
905 jnc retint_signal
906 TRACE_IRQS_ON
907 ENABLE_INTERRUPTS(CLBR_NONE)
908 pushq %rdi
909 CFI_ADJUST_CFA_OFFSET 8
910 call schedule
911 popq %rdi
912 CFI_ADJUST_CFA_OFFSET -8
913 GET_THREAD_INFO(%rcx)
914 DISABLE_INTERRUPTS(CLBR_NONE)
915 TRACE_IRQS_OFF
916 jmp retint_check
918 retint_signal:
919 testl $_TIF_DO_NOTIFY_MASK,%edx
920 jz retint_swapgs
921 TRACE_IRQS_ON
922 ENABLE_INTERRUPTS(CLBR_NONE)
923 SAVE_REST
924 movq $-1,ORIG_RAX(%rsp)
925 xorl %esi,%esi # oldset
926 movq %rsp,%rdi # &pt_regs
927 call do_notify_resume
928 RESTORE_REST
929 DISABLE_INTERRUPTS(CLBR_NONE)
930 TRACE_IRQS_OFF
931 GET_THREAD_INFO(%rcx)
932 jmp retint_with_reschedule
934 #ifdef CONFIG_PREEMPT
935 /* Returning to kernel space. Check if we need preemption */
936 /* rcx: threadinfo. interrupts off. */
937 ENTRY(retint_kernel)
938 cmpl $0,TI_preempt_count(%rcx)
939 jnz retint_restore_args
940 bt $TIF_NEED_RESCHED,TI_flags(%rcx)
941 jnc retint_restore_args
942 bt $9,EFLAGS-ARGOFFSET(%rsp) /* interrupts off? */
943 jnc retint_restore_args
944 call preempt_schedule_irq
945 jmp exit_intr
946 #endif
948 CFI_ENDPROC
949 END(common_interrupt)
951 /*
952 * APIC interrupts.
953 */
954 .macro apicinterrupt num sym do_sym
955 ENTRY(\sym)
956 INTR_FRAME
957 pushq $~(\num)
958 CFI_ADJUST_CFA_OFFSET 8
959 interrupt \do_sym
960 jmp ret_from_intr
961 CFI_ENDPROC
962 END(\sym)
963 .endm
965 #ifdef CONFIG_SMP
966 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
967 irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
968 apicinterrupt REBOOT_VECTOR \
969 reboot_interrupt smp_reboot_interrupt
970 #endif
972 #ifdef CONFIG_X86_UV
973 apicinterrupt UV_BAU_MESSAGE \
974 uv_bau_message_intr1 uv_bau_message_interrupt
975 #endif
976 apicinterrupt LOCAL_TIMER_VECTOR \
977 apic_timer_interrupt smp_apic_timer_interrupt
978 apicinterrupt GENERIC_INTERRUPT_VECTOR \
979 generic_interrupt smp_generic_interrupt
981 #ifdef CONFIG_SMP
982 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
983 invalidate_interrupt0 smp_invalidate_interrupt
984 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
985 invalidate_interrupt1 smp_invalidate_interrupt
986 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
987 invalidate_interrupt2 smp_invalidate_interrupt
988 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
989 invalidate_interrupt3 smp_invalidate_interrupt
990 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
991 invalidate_interrupt4 smp_invalidate_interrupt
992 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
993 invalidate_interrupt5 smp_invalidate_interrupt
994 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
995 invalidate_interrupt6 smp_invalidate_interrupt
996 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
997 invalidate_interrupt7 smp_invalidate_interrupt
998 #endif
1000 apicinterrupt THRESHOLD_APIC_VECTOR \
1001 threshold_interrupt smp_threshold_interrupt
1002 apicinterrupt THERMAL_APIC_VECTOR \
1003 thermal_interrupt smp_thermal_interrupt
1005 #ifdef CONFIG_X86_MCE
1006 apicinterrupt MCE_SELF_VECTOR \
1007 mce_self_interrupt smp_mce_self_interrupt
1008 #endif
1010 #ifdef CONFIG_SMP
1011 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1012 call_function_single_interrupt smp_call_function_single_interrupt
1013 apicinterrupt CALL_FUNCTION_VECTOR \
1014 call_function_interrupt smp_call_function_interrupt
1015 apicinterrupt RESCHEDULE_VECTOR \
1016 reschedule_interrupt smp_reschedule_interrupt
1017 #endif
1019 apicinterrupt ERROR_APIC_VECTOR \
1020 error_interrupt smp_error_interrupt
1021 apicinterrupt SPURIOUS_APIC_VECTOR \
1022 spurious_interrupt smp_spurious_interrupt
1024 #ifdef CONFIG_PERF_COUNTERS
1025 apicinterrupt LOCAL_PENDING_VECTOR \
1026 perf_pending_interrupt smp_perf_pending_interrupt
1027 #endif
1029 /*
1030 * Exception entry points.
1031 */
1032 .macro zeroentry sym do_sym
1033 ENTRY(\sym)
1034 INTR_FRAME
1035 PARAVIRT_ADJUST_EXCEPTION_FRAME
1036 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1037 subq $15*8,%rsp
1038 CFI_ADJUST_CFA_OFFSET 15*8
1039 call error_entry
1040 DEFAULT_FRAME 0
1041 movq %rsp,%rdi /* pt_regs pointer */
1042 xorl %esi,%esi /* no error code */
1043 call \do_sym
1044 jmp error_exit /* %ebx: no swapgs flag */
1045 CFI_ENDPROC
1046 END(\sym)
1047 .endm
1049 .macro paranoidzeroentry sym do_sym
1050 ENTRY(\sym)
1051 INTR_FRAME
1052 PARAVIRT_ADJUST_EXCEPTION_FRAME
1053 pushq $-1 /* ORIG_RAX: no syscall to restart */
1054 CFI_ADJUST_CFA_OFFSET 8
1055 subq $15*8, %rsp
1056 call save_paranoid
1057 TRACE_IRQS_OFF
1058 movq %rsp,%rdi /* pt_regs pointer */
1059 xorl %esi,%esi /* no error code */
1060 call \do_sym
1061 jmp paranoid_exit /* %ebx: no swapgs flag */
1062 CFI_ENDPROC
1063 END(\sym)
1064 .endm
1066 .macro paranoidzeroentry_ist sym do_sym ist
1067 ENTRY(\sym)
1068 INTR_FRAME
1069 PARAVIRT_ADJUST_EXCEPTION_FRAME
1070 pushq $-1 /* ORIG_RAX: no syscall to restart */
1071 CFI_ADJUST_CFA_OFFSET 8
1072 subq $15*8, %rsp
1073 call save_paranoid
1074 TRACE_IRQS_OFF
1075 movq %rsp,%rdi /* pt_regs pointer */
1076 xorl %esi,%esi /* no error code */
1077 PER_CPU(init_tss, %rbp)
1078 subq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1079 call \do_sym
1080 addq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1081 jmp paranoid_exit /* %ebx: no swapgs flag */
1082 CFI_ENDPROC
1083 END(\sym)
1084 .endm
1086 .macro errorentry sym do_sym
1087 ENTRY(\sym)
1088 XCPT_FRAME
1089 PARAVIRT_ADJUST_EXCEPTION_FRAME
1090 subq $15*8,%rsp
1091 CFI_ADJUST_CFA_OFFSET 15*8
1092 call error_entry
1093 DEFAULT_FRAME 0
1094 movq %rsp,%rdi /* pt_regs pointer */
1095 movq ORIG_RAX(%rsp),%rsi /* get error code */
1096 movq $-1,ORIG_RAX(%rsp) /* no syscall to restart */
1097 call \do_sym
1098 jmp error_exit /* %ebx: no swapgs flag */
1099 CFI_ENDPROC
1100 END(\sym)
1101 .endm
1103 /* error code is on the stack already */
1104 .macro paranoiderrorentry sym do_sym
1105 ENTRY(\sym)
1106 XCPT_FRAME
1107 PARAVIRT_ADJUST_EXCEPTION_FRAME
1108 subq $15*8,%rsp
1109 CFI_ADJUST_CFA_OFFSET 15*8
1110 call save_paranoid
1111 DEFAULT_FRAME 0
1112 TRACE_IRQS_OFF
1113 movq %rsp,%rdi /* pt_regs pointer */
1114 movq ORIG_RAX(%rsp),%rsi /* get error code */
1115 movq $-1,ORIG_RAX(%rsp) /* no syscall to restart */
1116 call \do_sym
1117 jmp paranoid_exit /* %ebx: no swapgs flag */
1118 CFI_ENDPROC
1119 END(\sym)
1120 .endm
1122 zeroentry divide_error do_divide_error
1123 zeroentry overflow do_overflow
1124 zeroentry bounds do_bounds
1125 zeroentry invalid_op do_invalid_op
1126 zeroentry device_not_available do_device_not_available
1127 paranoiderrorentry double_fault do_double_fault
1128 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1129 errorentry invalid_TSS do_invalid_TSS
1130 errorentry segment_not_present do_segment_not_present
1131 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1132 zeroentry coprocessor_error do_coprocessor_error
1133 errorentry alignment_check do_alignment_check
1134 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1136 /* Reload gs selector with exception handling */
1137 /* edi: new selector */
1138 ENTRY(native_load_gs_index)
1139 CFI_STARTPROC
1140 pushf
1141 CFI_ADJUST_CFA_OFFSET 8
1142 DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1143 SWAPGS
1144 gs_change:
1145 movl %edi,%gs
1146 2: mfence /* workaround */
1147 SWAPGS
1148 popf
1149 CFI_ADJUST_CFA_OFFSET -8
1150 ret
1151 CFI_ENDPROC
1152 END(native_load_gs_index)
1154 .section __ex_table,"a"
1155 .align 8
1156 .quad gs_change,bad_gs
1157 .previous
1158 .section .fixup,"ax"
1159 /* running with kernelgs */
1160 bad_gs:
1161 SWAPGS /* switch back to user gs */
1162 xorl %eax,%eax
1163 movl %eax,%gs
1164 jmp 2b
1165 .previous
1167 /*
1168 * Create a kernel thread.
1169 *
1170 * C extern interface:
1171 * extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1172 *
1173 * asm input arguments:
1174 * rdi: fn, rsi: arg, rdx: flags
1175 */
1176 ENTRY(kernel_thread)
1177 CFI_STARTPROC
1178 FAKE_STACK_FRAME $child_rip
1179 SAVE_ALL
1181 # rdi: flags, rsi: usp, rdx: will be &pt_regs
1182 movq %rdx,%rdi
1183 orq kernel_thread_flags(%rip),%rdi
1184 movq $-1, %rsi
1185 movq %rsp, %rdx
1187 xorl %r8d,%r8d
1188 xorl %r9d,%r9d
1190 # clone now
1191 call do_fork
1192 movq %rax,RAX(%rsp)
1193 xorl %edi,%edi
1195 /*
1196 * It isn't worth to check for reschedule here,
1197 * so internally to the x86_64 port you can rely on kernel_thread()
1198 * not to reschedule the child before returning, this avoids the need
1199 * of hacks for example to fork off the per-CPU idle tasks.
1200 * [Hopefully no generic code relies on the reschedule -AK]
1201 */
1202 RESTORE_ALL
1203 UNFAKE_STACK_FRAME
1204 ret
1205 CFI_ENDPROC
1206 END(kernel_thread)
1208 ENTRY(child_rip)
1209 pushq $0 # fake return address
1210 CFI_STARTPROC
1211 /*
1212 * Here we are in the child and the registers are set as they were
1213 * at kernel_thread() invocation in the parent.
1214 */
1215 movq %rdi, %rax
1216 movq %rsi, %rdi
1217 call *%rax
1218 # exit
1219 mov %eax, %edi
1220 call do_exit
1221 ud2 # padding for call trace
1222 CFI_ENDPROC
1223 END(child_rip)
1225 /*
1226 * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1227 *
1228 * C extern interface:
1229 * extern long execve(char *name, char **argv, char **envp)
1230 *
1231 * asm input arguments:
1232 * rdi: name, rsi: argv, rdx: envp
1233 *
1234 * We want to fallback into:
1235 * extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1236 *
1237 * do_sys_execve asm fallback arguments:
1238 * rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1239 */
1240 ENTRY(kernel_execve)
1241 CFI_STARTPROC
1242 FAKE_STACK_FRAME $0
1243 SAVE_ALL
1244 movq %rsp,%rcx
1245 call sys_execve
1246 movq %rax, RAX(%rsp)
1247 RESTORE_REST
1248 testq %rax,%rax
1249 je int_ret_from_sys_call
1250 RESTORE_ARGS
1251 UNFAKE_STACK_FRAME
1252 ret
1253 CFI_ENDPROC
1254 END(kernel_execve)
1256 /* Call softirq on interrupt stack. Interrupts are off. */
1257 ENTRY(call_softirq)
1258 CFI_STARTPROC
1259 push %rbp
1260 CFI_ADJUST_CFA_OFFSET 8
1261 CFI_REL_OFFSET rbp,0
1262 mov %rsp,%rbp
1263 CFI_DEF_CFA_REGISTER rbp
1264 incl PER_CPU_VAR(irq_count)
1265 cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1266 push %rbp # backlink for old unwinder
1267 call __do_softirq
1268 leaveq
1269 CFI_DEF_CFA_REGISTER rsp
1270 CFI_ADJUST_CFA_OFFSET -8
1271 decl PER_CPU_VAR(irq_count)
1272 ret
1273 CFI_ENDPROC
1274 END(call_softirq)
1276 #ifdef CONFIG_XEN
1277 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1279 /*
1280 * A note on the "critical region" in our callback handler.
1281 * We want to avoid stacking callback handlers due to events occurring
1282 * during handling of the last event. To do this, we keep events disabled
1283 * until we've done all processing. HOWEVER, we must enable events before
1284 * popping the stack frame (can't be done atomically) and so it would still
1285 * be possible to get enough handler activations to overflow the stack.
1286 * Although unlikely, bugs of that kind are hard to track down, so we'd
1287 * like to avoid the possibility.
1288 * So, on entry to the handler we detect whether we interrupted an
1289 * existing activation in its critical region -- if so, we pop the current
1290 * activation and restart the handler using the previous one.
1291 */
1292 ENTRY(xen_do_hypervisor_callback) # do_hypervisor_callback(struct *pt_regs)
1293 CFI_STARTPROC
1294 /*
1295 * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1296 * see the correct pointer to the pt_regs
1297 */
1298 movq %rdi, %rsp # we don't return, adjust the stack frame
1299 CFI_ENDPROC
1300 DEFAULT_FRAME
1301 11: incl PER_CPU_VAR(irq_count)
1302 movq %rsp,%rbp
1303 CFI_DEF_CFA_REGISTER rbp
1304 cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1305 pushq %rbp # backlink for old unwinder
1306 call xen_evtchn_do_upcall
1307 popq %rsp
1308 CFI_DEF_CFA_REGISTER rsp
1309 decl PER_CPU_VAR(irq_count)
1310 jmp error_exit
1311 CFI_ENDPROC
1312 END(do_hypervisor_callback)
1314 /*
1315 * Hypervisor uses this for application faults while it executes.
1316 * We get here for two reasons:
1317 * 1. Fault while reloading DS, ES, FS or GS
1318 * 2. Fault while executing IRET
1319 * Category 1 we do not need to fix up as Xen has already reloaded all segment
1320 * registers that could be reloaded and zeroed the others.
1321 * Category 2 we fix up by killing the current process. We cannot use the
1322 * normal Linux return path in this case because if we use the IRET hypercall
1323 * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1324 * We distinguish between categories by comparing each saved segment register
1325 * with its current contents: any discrepancy means we in category 1.
1326 */
1327 ENTRY(xen_failsafe_callback)
1328 INTR_FRAME 1 (6*8)
1329 /*CFI_REL_OFFSET gs,GS*/
1330 /*CFI_REL_OFFSET fs,FS*/
1331 /*CFI_REL_OFFSET es,ES*/
1332 /*CFI_REL_OFFSET ds,DS*/
1333 CFI_REL_OFFSET r11,8
1334 CFI_REL_OFFSET rcx,0
1335 movw %ds,%cx
1336 cmpw %cx,0x10(%rsp)
1337 CFI_REMEMBER_STATE
1338 jne 1f
1339 movw %es,%cx
1340 cmpw %cx,0x18(%rsp)
1341 jne 1f
1342 movw %fs,%cx
1343 cmpw %cx,0x20(%rsp)
1344 jne 1f
1345 movw %gs,%cx
1346 cmpw %cx,0x28(%rsp)
1347 jne 1f
1348 /* All segments match their saved values => Category 2 (Bad IRET). */
1349 movq (%rsp),%rcx
1350 CFI_RESTORE rcx
1351 movq 8(%rsp),%r11
1352 CFI_RESTORE r11
1353 addq $0x30,%rsp
1354 CFI_ADJUST_CFA_OFFSET -0x30
1355 pushq_cfi $0 /* RIP */
1356 pushq_cfi %r11
1357 pushq_cfi %rcx
1358 jmp general_protection
1359 CFI_RESTORE_STATE
1360 1: /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1361 movq (%rsp),%rcx
1362 CFI_RESTORE rcx
1363 movq 8(%rsp),%r11
1364 CFI_RESTORE r11
1365 addq $0x30,%rsp
1366 CFI_ADJUST_CFA_OFFSET -0x30
1367 pushq_cfi $0
1368 SAVE_ALL
1369 jmp error_exit
1370 CFI_ENDPROC
1371 END(xen_failsafe_callback)
1373 #endif /* CONFIG_XEN */
1375 /*
1376 * Some functions should be protected against kprobes
1377 */
1378 .pushsection .kprobes.text, "ax"
1380 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1381 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1382 paranoiderrorentry stack_segment do_stack_segment
1383 #ifdef CONFIG_XEN
1384 zeroentry xen_debug do_debug
1385 zeroentry xen_int3 do_int3
1386 errorentry xen_stack_segment do_stack_segment
1387 #endif
1388 errorentry general_protection do_general_protection
1389 errorentry page_fault do_page_fault
1390 #ifdef CONFIG_X86_MCE
1391 paranoidzeroentry machine_check *machine_check_vector(%rip)
1392 #endif
1394 /*
1395 * "Paranoid" exit path from exception stack.
1396 * Paranoid because this is used by NMIs and cannot take
1397 * any kernel state for granted.
1398 * We don't do kernel preemption checks here, because only
1399 * NMI should be common and it does not enable IRQs and
1400 * cannot get reschedule ticks.
1401 *
1402 * "trace" is 0 for the NMI handler only, because irq-tracing
1403 * is fundamentally NMI-unsafe. (we cannot change the soft and
1404 * hard flags at once, atomically)
1405 */
1407 /* ebx: no swapgs flag */
1408 ENTRY(paranoid_exit)
1409 INTR_FRAME
1410 DISABLE_INTERRUPTS(CLBR_NONE)
1411 TRACE_IRQS_OFF
1412 testl %ebx,%ebx /* swapgs needed? */
1413 jnz paranoid_restore
1414 testl $3,CS(%rsp)
1415 jnz paranoid_userspace
1416 paranoid_swapgs:
1417 TRACE_IRQS_IRETQ 0
1418 SWAPGS_UNSAFE_STACK
1419 RESTORE_ALL 8
1420 jmp irq_return
1421 paranoid_restore:
1422 TRACE_IRQS_IRETQ 0
1423 RESTORE_ALL 8
1424 jmp irq_return
1425 paranoid_userspace:
1426 GET_THREAD_INFO(%rcx)
1427 movl TI_flags(%rcx),%ebx
1428 andl $_TIF_WORK_MASK,%ebx
1429 jz paranoid_swapgs
1430 movq %rsp,%rdi /* &pt_regs */
1431 call sync_regs
1432 movq %rax,%rsp /* switch stack for scheduling */
1433 testl $_TIF_NEED_RESCHED,%ebx
1434 jnz paranoid_schedule
1435 movl %ebx,%edx /* arg3: thread flags */
1436 TRACE_IRQS_ON
1437 ENABLE_INTERRUPTS(CLBR_NONE)
1438 xorl %esi,%esi /* arg2: oldset */
1439 movq %rsp,%rdi /* arg1: &pt_regs */
1440 call do_notify_resume
1441 DISABLE_INTERRUPTS(CLBR_NONE)
1442 TRACE_IRQS_OFF
1443 jmp paranoid_userspace
1444 paranoid_schedule:
1445 TRACE_IRQS_ON
1446 ENABLE_INTERRUPTS(CLBR_ANY)
1447 call schedule
1448 DISABLE_INTERRUPTS(CLBR_ANY)
1449 TRACE_IRQS_OFF
1450 jmp paranoid_userspace
1451 CFI_ENDPROC
1452 END(paranoid_exit)
1454 /*
1455 * Exception entry point. This expects an error code/orig_rax on the stack.
1456 * returns in "no swapgs flag" in %ebx.
1457 */
1458 ENTRY(error_entry)
1459 XCPT_FRAME
1460 CFI_ADJUST_CFA_OFFSET 15*8
1461 /* oldrax contains error code */
1462 cld
1463 movq_cfi rdi, RDI+8
1464 movq_cfi rsi, RSI+8
1465 movq_cfi rdx, RDX+8
1466 movq_cfi rcx, RCX+8
1467 movq_cfi rax, RAX+8
1468 movq_cfi r8, R8+8
1469 movq_cfi r9, R9+8
1470 movq_cfi r10, R10+8
1471 movq_cfi r11, R11+8
1472 movq_cfi rbx, RBX+8
1473 movq_cfi rbp, RBP+8
1474 movq_cfi r12, R12+8
1475 movq_cfi r13, R13+8
1476 movq_cfi r14, R14+8
1477 movq_cfi r15, R15+8
1478 xorl %ebx,%ebx
1479 testl $3,CS+8(%rsp)
1480 je error_kernelspace
1481 error_swapgs:
1482 SWAPGS
1483 error_sti:
1484 TRACE_IRQS_OFF
1485 ret
1486 CFI_ENDPROC
1488 /*
1489 * There are two places in the kernel that can potentially fault with
1490 * usergs. Handle them here. The exception handlers after iret run with
1491 * kernel gs again, so don't set the user space flag. B stepping K8s
1492 * sometimes report an truncated RIP for IRET exceptions returning to
1493 * compat mode. Check for these here too.
1494 */
1495 error_kernelspace:
1496 incl %ebx
1497 leaq irq_return(%rip),%rcx
1498 cmpq %rcx,RIP+8(%rsp)
1499 je error_swapgs
1500 movl %ecx,%ecx /* zero extend */
1501 cmpq %rcx,RIP+8(%rsp)
1502 je error_swapgs
1503 cmpq $gs_change,RIP+8(%rsp)
1504 je error_swapgs
1505 jmp error_sti
1506 END(error_entry)
1509 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1510 ENTRY(error_exit)
1511 DEFAULT_FRAME
1512 movl %ebx,%eax
1513 RESTORE_REST
1514 DISABLE_INTERRUPTS(CLBR_NONE)
1515 TRACE_IRQS_OFF
1516 GET_THREAD_INFO(%rcx)
1517 testl %eax,%eax
1518 jne retint_kernel
1519 LOCKDEP_SYS_EXIT_IRQ
1520 movl TI_flags(%rcx),%edx
1521 movl $_TIF_WORK_MASK,%edi
1522 andl %edi,%edx
1523 jnz retint_careful
1524 jmp retint_swapgs
1525 CFI_ENDPROC
1526 END(error_exit)
1529 /* runs on exception stack */
1530 ENTRY(nmi)
1531 INTR_FRAME
1532 PARAVIRT_ADJUST_EXCEPTION_FRAME
1533 pushq_cfi $-1
1534 subq $15*8, %rsp
1535 CFI_ADJUST_CFA_OFFSET 15*8
1536 call save_paranoid
1537 DEFAULT_FRAME 0
1538 /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1539 movq %rsp,%rdi
1540 movq $-1,%rsi
1541 call do_nmi
1542 #ifdef CONFIG_TRACE_IRQFLAGS
1543 /* paranoidexit; without TRACE_IRQS_OFF */
1544 /* ebx: no swapgs flag */
1545 DISABLE_INTERRUPTS(CLBR_NONE)
1546 testl %ebx,%ebx /* swapgs needed? */
1547 jnz nmi_restore
1548 testl $3,CS(%rsp)
1549 jnz nmi_userspace
1550 nmi_swapgs:
1551 SWAPGS_UNSAFE_STACK
1552 nmi_restore:
1553 RESTORE_ALL 8
1554 jmp irq_return
1555 nmi_userspace:
1556 GET_THREAD_INFO(%rcx)
1557 movl TI_flags(%rcx),%ebx
1558 andl $_TIF_WORK_MASK,%ebx
1559 jz nmi_swapgs
1560 movq %rsp,%rdi /* &pt_regs */
1561 call sync_regs
1562 movq %rax,%rsp /* switch stack for scheduling */
1563 testl $_TIF_NEED_RESCHED,%ebx
1564 jnz nmi_schedule
1565 movl %ebx,%edx /* arg3: thread flags */
1566 ENABLE_INTERRUPTS(CLBR_NONE)
1567 xorl %esi,%esi /* arg2: oldset */
1568 movq %rsp,%rdi /* arg1: &pt_regs */
1569 call do_notify_resume
1570 DISABLE_INTERRUPTS(CLBR_NONE)
1571 jmp nmi_userspace
1572 nmi_schedule:
1573 ENABLE_INTERRUPTS(CLBR_ANY)
1574 call schedule
1575 DISABLE_INTERRUPTS(CLBR_ANY)
1576 jmp nmi_userspace
1577 CFI_ENDPROC
1578 #else
1579 jmp paranoid_exit
1580 CFI_ENDPROC
1581 #endif
1582 END(nmi)
1584 ENTRY(ignore_sysret)
1585 CFI_STARTPROC
1586 mov $-ENOSYS,%eax
1587 sysret
1588 CFI_ENDPROC
1589 END(ignore_sysret)
1591 /*
1592 * End of kprobes section
1593 */
1594 .popsection