| blob | 30747960bc54a29496eb134ebff26bfcb67e2fd7 |
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
57 #include <linux/export.h>
59 /* Align . to a 8 byte boundary equals to maximum function alignment. */
60 #define ALIGN_FUNCTION() . = ALIGN(8)
62 /*
63 * Align to a 32 byte boundary equal to the
64 * alignment gcc 4.5 uses for a struct
65 */
66 #define STRUCT_ALIGNMENT 32
67 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
69 /* The actual configuration determine if the init/exit sections
70 * are handled as text/data or they can be discarded (which
71 * often happens at runtime)
72 */
73 #ifdef CONFIG_HOTPLUG_CPU
74 #define CPU_KEEP(sec) *(.cpu##sec)
75 #define CPU_DISCARD(sec)
76 #else
77 #define CPU_KEEP(sec)
78 #define CPU_DISCARD(sec) *(.cpu##sec)
79 #endif
81 #if defined(CONFIG_MEMORY_HOTPLUG)
82 #define MEM_KEEP(sec) *(.mem##sec)
83 #define MEM_DISCARD(sec)
84 #else
85 #define MEM_KEEP(sec)
86 #define MEM_DISCARD(sec) *(.mem##sec)
87 #endif
89 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
90 #define MCOUNT_REC() . = ALIGN(8); \
91 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
92 *(__mcount_loc) \
93 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
94 #else
95 #define MCOUNT_REC()
96 #endif
98 #ifdef CONFIG_TRACE_BRANCH_PROFILING
99 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
100 *(_ftrace_annotated_branch) \
101 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
102 #else
103 #define LIKELY_PROFILE()
104 #endif
106 #ifdef CONFIG_PROFILE_ALL_BRANCHES
107 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
108 *(_ftrace_branch) \
109 VMLINUX_SYMBOL(__stop_branch_profile) = .;
110 #else
111 #define BRANCH_PROFILE()
112 #endif
114 #ifdef CONFIG_KPROBES
115 #define KPROBE_BLACKLIST() . = ALIGN(8); \
116 VMLINUX_SYMBOL(__start_kprobe_blacklist) = .; \
117 *(_kprobe_blacklist) \
118 VMLINUX_SYMBOL(__stop_kprobe_blacklist) = .;
119 #else
120 #define KPROBE_BLACKLIST()
121 #endif
123 #ifdef CONFIG_EVENT_TRACING
124 #define FTRACE_EVENTS() . = ALIGN(8); \
125 VMLINUX_SYMBOL(__start_ftrace_events) = .; \
126 *(_ftrace_events) \
127 VMLINUX_SYMBOL(__stop_ftrace_events) = .; \
128 VMLINUX_SYMBOL(__start_ftrace_enum_maps) = .; \
129 *(_ftrace_enum_map) \
130 VMLINUX_SYMBOL(__stop_ftrace_enum_maps) = .;
131 #else
132 #define FTRACE_EVENTS()
133 #endif
135 #ifdef CONFIG_TRACING
136 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
138 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
139 #define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .; \
141 VMLINUX_SYMBOL(__stop___tracepoint_str) = .;
142 #else
143 #define TRACE_PRINTKS()
144 #define TRACEPOINT_STR()
145 #endif
147 #ifdef CONFIG_FTRACE_SYSCALLS
148 #define TRACE_SYSCALLS() . = ALIGN(8); \
149 VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
150 *(__syscalls_metadata) \
151 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
152 #else
153 #define TRACE_SYSCALLS()
154 #endif
156 #ifdef CONFIG_SERIAL_EARLYCON
157 #define EARLYCON_TABLE() STRUCT_ALIGN(); \
158 VMLINUX_SYMBOL(__earlycon_table) = .; \
159 *(__earlycon_table) \
160 VMLINUX_SYMBOL(__earlycon_table_end) = .;
161 #else
162 #define EARLYCON_TABLE()
163 #endif
165 #define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
166 #define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
167 #define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
168 #define _OF_TABLE_0(name)
169 #define _OF_TABLE_1(name) \
170 . = ALIGN(8); \
171 VMLINUX_SYMBOL(__##name##_of_table) = .; \
172 *(__##name##_of_table) \
173 *(__##name##_of_table_end)
175 #define CLKSRC_OF_TABLES() OF_TABLE(CONFIG_CLKSRC_OF, clksrc)
176 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
177 #define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
178 #define IOMMU_OF_TABLES() OF_TABLE(CONFIG_OF_IOMMU, iommu)
179 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
180 #define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
181 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
183 #ifdef CONFIG_ACPI
184 #define ACPI_PROBE_TABLE(name) \
185 . = ALIGN(8); \
186 VMLINUX_SYMBOL(__##name##_acpi_probe_table) = .; \
187 *(__##name##_acpi_probe_table) \
188 VMLINUX_SYMBOL(__##name##_acpi_probe_table_end) = .;
189 #else
190 #define ACPI_PROBE_TABLE(name)
191 #endif
193 #define KERNEL_DTB() \
194 STRUCT_ALIGN(); \
195 VMLINUX_SYMBOL(__dtb_start) = .; \
196 *(.dtb.init.rodata) \
197 VMLINUX_SYMBOL(__dtb_end) = .;
199 /*
200 * .data section
201 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections generates
202 * .data.identifier which needs to be pulled in with .data, but don't want to
203 * pull in .data..stuff which has its own requirements. Same for bss.
204 */
205 #define DATA_DATA \
206 *(.data .data.[0-9a-zA-Z_]*) \
207 *(.ref.data) \
209 MEM_KEEP(init.data) \
210 MEM_KEEP(exit.data) \
211 *(.data.unlikely) \
212 STRUCT_ALIGN(); \
213 *(__tracepoints) \
215 . = ALIGN(8); \
216 VMLINUX_SYMBOL(__start___jump_table) = .; \
217 *(__jump_table) \
218 VMLINUX_SYMBOL(__stop___jump_table) = .; \
219 . = ALIGN(8); \
220 VMLINUX_SYMBOL(__start___verbose) = .; \
221 *(__verbose) \
222 VMLINUX_SYMBOL(__stop___verbose) = .; \
223 LIKELY_PROFILE() \
224 BRANCH_PROFILE() \
225 TRACE_PRINTKS() \
226 TRACEPOINT_STR()
228 /*
229 * Data section helpers
230 */
231 #define NOSAVE_DATA \
232 . = ALIGN(PAGE_SIZE); \
233 VMLINUX_SYMBOL(__nosave_begin) = .; \
234 *(.data..nosave) \
235 . = ALIGN(PAGE_SIZE); \
236 VMLINUX_SYMBOL(__nosave_end) = .;
238 #define PAGE_ALIGNED_DATA(page_align) \
239 . = ALIGN(page_align); \
240 *(.data..page_aligned)
242 #define READ_MOSTLY_DATA(align) \
243 . = ALIGN(align); \
244 *(.data..read_mostly) \
245 . = ALIGN(align);
247 #define CACHELINE_ALIGNED_DATA(align) \
248 . = ALIGN(align); \
249 *(.data..cacheline_aligned)
251 #define INIT_TASK_DATA(align) \
252 . = ALIGN(align); \
253 VMLINUX_SYMBOL(__start_init_task) = .; \
254 *(.data..init_task) \
255 VMLINUX_SYMBOL(__end_init_task) = .;
257 /*
258 * Allow architectures to handle ro_after_init data on their
259 * own by defining an empty RO_AFTER_INIT_DATA.
260 */
261 #ifndef RO_AFTER_INIT_DATA
262 #define RO_AFTER_INIT_DATA *(.data..ro_after_init)
263 #endif
265 /*
266 * Read only Data
267 */
268 #define RO_DATA_SECTION(align) \
269 . = ALIGN((align)); \
270 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
271 VMLINUX_SYMBOL(__start_rodata) = .; \
272 *(.rodata) *(.rodata.*) \
275 . = ALIGN(8); \
276 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \
278 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \
280 } \
281 \
282 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
283 *(.rodata1) \
284 } \
285 \
286 BUG_TABLE \
287 \
289 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
290 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
291 *(.pci_fixup_early) \
292 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
293 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
294 *(.pci_fixup_header) \
295 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
296 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
297 *(.pci_fixup_final) \
298 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
299 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
300 *(.pci_fixup_enable) \
301 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
302 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
303 *(.pci_fixup_resume) \
304 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
305 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
306 *(.pci_fixup_resume_early) \
307 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
308 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
309 *(.pci_fixup_suspend) \
310 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
311 VMLINUX_SYMBOL(__start_pci_fixups_suspend_late) = .; \
312 *(.pci_fixup_suspend_late) \
313 VMLINUX_SYMBOL(__end_pci_fixups_suspend_late) = .; \
314 } \
315 \
317 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
318 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
319 *(.builtin_fw) \
320 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
321 } \
322 \
323 TRACEDATA \
324 \
326 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
327 VMLINUX_SYMBOL(__start___ksymtab) = .; \
328 KEEP(*(SORT(___ksymtab+*))) \
329 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
330 } \
331 \
333 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
334 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
335 KEEP(*(SORT(___ksymtab_gpl+*))) \
336 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
337 } \
338 \
340 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
341 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
342 KEEP(*(SORT(___ksymtab_unused+*))) \
343 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
344 } \
345 \
347 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
348 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
349 KEEP(*(SORT(___ksymtab_unused_gpl+*))) \
350 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
351 } \
352 \
354 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
355 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
356 KEEP(*(SORT(___ksymtab_gpl_future+*))) \
357 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
358 } \
359 \
361 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
362 VMLINUX_SYMBOL(__start___kcrctab) = .; \
363 KEEP(*(SORT(___kcrctab+*))) \
364 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
365 } \
366 \
368 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
369 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
370 KEEP(*(SORT(___kcrctab_gpl+*))) \
371 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
372 } \
373 \
375 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
376 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
377 KEEP(*(SORT(___kcrctab_unused+*))) \
378 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
379 } \
380 \
382 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
383 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
384 KEEP(*(SORT(___kcrctab_unused_gpl+*))) \
385 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
386 } \
387 \
389 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
390 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
391 KEEP(*(SORT(___kcrctab_gpl_future+*))) \
392 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
393 } \
394 \
396 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
397 KEEP(*(__ksymtab_strings)) \
398 } \
399 \
401 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
402 *(.ref.rodata) \
403 MEM_KEEP(init.rodata) \
404 MEM_KEEP(exit.rodata) \
405 } \
406 \
408 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
409 VMLINUX_SYMBOL(__start___param) = .; \
410 *(__param) \
411 VMLINUX_SYMBOL(__stop___param) = .; \
412 } \
413 \
415 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
416 VMLINUX_SYMBOL(__start___modver) = .; \
417 *(__modver) \
418 VMLINUX_SYMBOL(__stop___modver) = .; \
419 . = ALIGN((align)); \
420 VMLINUX_SYMBOL(__end_rodata) = .; \
421 } \
422 . = ALIGN((align));
424 /* RODATA & RO_DATA provided for backward compatibility.
425 * All archs are supposed to use RO_DATA() */
426 #define RODATA RO_DATA_SECTION(4096)
427 #define RO_DATA(align) RO_DATA_SECTION(align)
429 #define SECURITY_INIT \
430 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
431 VMLINUX_SYMBOL(__security_initcall_start) = .; \
432 KEEP(*(.security_initcall.init)) \
433 VMLINUX_SYMBOL(__security_initcall_end) = .; \
434 }
436 /* .text section. Map to function alignment to avoid address changes
437 * during second ld run in second ld pass when generating System.map
438 * LD_DEAD_CODE_DATA_ELIMINATION option enables -ffunction-sections generates
439 * .text.identifier which needs to be pulled in with .text , but some
440 * architectures define .text.foo which is not intended to be pulled in here.
441 * Those enabling LD_DEAD_CODE_DATA_ELIMINATION must ensure they don't have
442 * conflicting section names, and must pull in .text.[0-9a-zA-Z_]* */
443 #define TEXT_TEXT \
444 ALIGN_FUNCTION(); \
445 *(.text.hot .text .text.fixup .text.unlikely) \
446 *(.ref.text) \
447 MEM_KEEP(init.text) \
448 MEM_KEEP(exit.text) \
451 /* sched.text is aling to function alignment to secure we have same
452 * address even at second ld pass when generating System.map */
453 #define SCHED_TEXT \
454 ALIGN_FUNCTION(); \
455 VMLINUX_SYMBOL(__sched_text_start) = .; \
456 *(.sched.text) \
457 VMLINUX_SYMBOL(__sched_text_end) = .;
459 /* spinlock.text is aling to function alignment to secure we have same
460 * address even at second ld pass when generating System.map */
461 #define LOCK_TEXT \
462 ALIGN_FUNCTION(); \
463 VMLINUX_SYMBOL(__lock_text_start) = .; \
464 *(.spinlock.text) \
465 VMLINUX_SYMBOL(__lock_text_end) = .;
467 #define CPUIDLE_TEXT \
468 ALIGN_FUNCTION(); \
469 VMLINUX_SYMBOL(__cpuidle_text_start) = .; \
470 *(.cpuidle.text) \
471 VMLINUX_SYMBOL(__cpuidle_text_end) = .;
473 #define KPROBES_TEXT \
474 ALIGN_FUNCTION(); \
475 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
476 *(.kprobes.text) \
477 VMLINUX_SYMBOL(__kprobes_text_end) = .;
479 #define ENTRY_TEXT \
480 ALIGN_FUNCTION(); \
481 VMLINUX_SYMBOL(__entry_text_start) = .; \
482 *(.entry.text) \
483 VMLINUX_SYMBOL(__entry_text_end) = .;
485 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
486 #define IRQENTRY_TEXT \
487 ALIGN_FUNCTION(); \
488 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
489 *(.irqentry.text) \
490 VMLINUX_SYMBOL(__irqentry_text_end) = .;
491 #else
492 #define IRQENTRY_TEXT
493 #endif
495 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
496 #define SOFTIRQENTRY_TEXT \
497 ALIGN_FUNCTION(); \
498 VMLINUX_SYMBOL(__softirqentry_text_start) = .; \
499 *(.softirqentry.text) \
500 VMLINUX_SYMBOL(__softirqentry_text_end) = .;
501 #else
502 #define SOFTIRQENTRY_TEXT
503 #endif
505 /* Section used for early init (in .S files) */
506 #define HEAD_TEXT *(.head.text)
508 #define HEAD_TEXT_SECTION \
509 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
510 HEAD_TEXT \
511 }
513 /*
514 * Exception table
515 */
516 #define EXCEPTION_TABLE(align) \
517 . = ALIGN(align); \
518 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
519 VMLINUX_SYMBOL(__start___ex_table) = .; \
520 *(__ex_table) \
521 VMLINUX_SYMBOL(__stop___ex_table) = .; \
522 }
524 /*
525 * Init task
526 */
527 #define INIT_TASK_DATA_SECTION(align) \
528 . = ALIGN(align); \
529 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
530 INIT_TASK_DATA(align) \
531 }
533 #ifdef CONFIG_CONSTRUCTORS
534 #define KERNEL_CTORS() . = ALIGN(8); \
535 VMLINUX_SYMBOL(__ctors_start) = .; \
536 *(.ctors) \
537 *(SORT(.init_array.*)) \
538 *(.init_array) \
539 VMLINUX_SYMBOL(__ctors_end) = .;
540 #else
541 #define KERNEL_CTORS()
542 #endif
544 /* init and exit section handling */
545 #define INIT_DATA \
546 KEEP(*(SORT(___kentry+*))) \
547 *(.init.data) \
548 MEM_DISCARD(init.data) \
549 KERNEL_CTORS() \
550 MCOUNT_REC() \
551 *(.init.rodata) \
552 FTRACE_EVENTS() \
553 TRACE_SYSCALLS() \
554 KPROBE_BLACKLIST() \
555 MEM_DISCARD(init.rodata) \
556 CLK_OF_TABLES() \
557 RESERVEDMEM_OF_TABLES() \
558 CLKSRC_OF_TABLES() \
559 IOMMU_OF_TABLES() \
560 CPU_METHOD_OF_TABLES() \
561 CPUIDLE_METHOD_OF_TABLES() \
562 KERNEL_DTB() \
563 IRQCHIP_OF_MATCH_TABLE() \
564 ACPI_PROBE_TABLE(irqchip) \
565 ACPI_PROBE_TABLE(clksrc) \
566 EARLYCON_TABLE()
568 #define INIT_TEXT \
569 *(.init.text) \
570 *(.text.startup) \
571 MEM_DISCARD(init.text)
573 #define EXIT_DATA \
574 *(.exit.data) \
575 *(.fini_array) \
576 *(.dtors) \
577 MEM_DISCARD(exit.data) \
578 MEM_DISCARD(exit.rodata)
580 #define EXIT_TEXT \
581 *(.exit.text) \
582 *(.text.exit) \
583 MEM_DISCARD(exit.text)
585 #define EXIT_CALL \
586 *(.exitcall.exit)
588 /*
589 * bss (Block Started by Symbol) - uninitialized data
590 * zeroed during startup
591 */
592 #define SBSS(sbss_align) \
593 . = ALIGN(sbss_align); \
594 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
595 *(.sbss) \
596 *(.scommon) \
597 }
599 /*
600 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
601 * sections to the front of bss.
602 */
603 #ifndef BSS_FIRST_SECTIONS
604 #define BSS_FIRST_SECTIONS
605 #endif
607 #define BSS(bss_align) \
608 . = ALIGN(bss_align); \
609 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
610 BSS_FIRST_SECTIONS \
611 *(.bss..page_aligned) \
612 *(.dynbss) \
613 *(.bss .bss.[0-9a-zA-Z_]*) \
614 *(COMMON) \
615 }
617 /*
618 * DWARF debug sections.
619 * Symbols in the DWARF debugging sections are relative to
620 * the beginning of the section so we begin them at 0.
621 */
622 #define DWARF_DEBUG \
624 .debug 0 : { *(.debug) } \
625 .line 0 : { *(.line) } \
627 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
628 .debug_sfnames 0 : { *(.debug_sfnames) } \
630 .debug_aranges 0 : { *(.debug_aranges) } \
631 .debug_pubnames 0 : { *(.debug_pubnames) } \
633 .debug_info 0 : { *(.debug_info \
634 .gnu.linkonce.wi.*) } \
635 .debug_abbrev 0 : { *(.debug_abbrev) } \
636 .debug_line 0 : { *(.debug_line) } \
637 .debug_frame 0 : { *(.debug_frame) } \
638 .debug_str 0 : { *(.debug_str) } \
639 .debug_loc 0 : { *(.debug_loc) } \
640 .debug_macinfo 0 : { *(.debug_macinfo) } \
642 .debug_weaknames 0 : { *(.debug_weaknames) } \
643 .debug_funcnames 0 : { *(.debug_funcnames) } \
644 .debug_typenames 0 : { *(.debug_typenames) } \
645 .debug_varnames 0 : { *(.debug_varnames) } \
647 /* Stabs debugging sections. */
648 #define STABS_DEBUG \
649 .stab 0 : { *(.stab) } \
650 .stabstr 0 : { *(.stabstr) } \
651 .stab.excl 0 : { *(.stab.excl) } \
652 .stab.exclstr 0 : { *(.stab.exclstr) } \
653 .stab.index 0 : { *(.stab.index) } \
654 .stab.indexstr 0 : { *(.stab.indexstr) } \
655 .comment 0 : { *(.comment) }
657 #ifdef CONFIG_GENERIC_BUG
658 #define BUG_TABLE \
659 . = ALIGN(8); \
660 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
661 VMLINUX_SYMBOL(__start___bug_table) = .; \
662 *(__bug_table) \
663 VMLINUX_SYMBOL(__stop___bug_table) = .; \
664 }
665 #else
666 #define BUG_TABLE
667 #endif
669 #ifdef CONFIG_PM_TRACE
670 #define TRACEDATA \
671 . = ALIGN(4); \
672 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
673 VMLINUX_SYMBOL(__tracedata_start) = .; \
674 *(.tracedata) \
675 VMLINUX_SYMBOL(__tracedata_end) = .; \
676 }
677 #else
678 #define TRACEDATA
679 #endif
681 #define NOTES \
682 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
683 VMLINUX_SYMBOL(__start_notes) = .; \
684 *(.note.*) \
685 VMLINUX_SYMBOL(__stop_notes) = .; \
686 }
688 #define INIT_SETUP(initsetup_align) \
689 . = ALIGN(initsetup_align); \
690 VMLINUX_SYMBOL(__setup_start) = .; \
691 *(.init.setup) \
692 VMLINUX_SYMBOL(__setup_end) = .;
694 #define INIT_CALLS_LEVEL(level) \
695 VMLINUX_SYMBOL(__initcall##level##_start) = .; \
696 KEEP(*(.initcall##level##.init)) \
697 KEEP(*(.initcall##level##s.init)) \
699 #define INIT_CALLS \
700 VMLINUX_SYMBOL(__initcall_start) = .; \
701 KEEP(*(.initcallearly.init)) \
702 INIT_CALLS_LEVEL(0) \
703 INIT_CALLS_LEVEL(1) \
704 INIT_CALLS_LEVEL(2) \
705 INIT_CALLS_LEVEL(3) \
706 INIT_CALLS_LEVEL(4) \
707 INIT_CALLS_LEVEL(5) \
708 INIT_CALLS_LEVEL(rootfs) \
709 INIT_CALLS_LEVEL(6) \
710 INIT_CALLS_LEVEL(7) \
711 VMLINUX_SYMBOL(__initcall_end) = .;
713 #define CON_INITCALL \
714 VMLINUX_SYMBOL(__con_initcall_start) = .; \
715 KEEP(*(.con_initcall.init)) \
716 VMLINUX_SYMBOL(__con_initcall_end) = .;
718 #define SECURITY_INITCALL \
719 VMLINUX_SYMBOL(__security_initcall_start) = .; \
720 KEEP(*(.security_initcall.init)) \
721 VMLINUX_SYMBOL(__security_initcall_end) = .;
723 #ifdef CONFIG_BLK_DEV_INITRD
724 #define INIT_RAM_FS \
725 . = ALIGN(4); \
726 VMLINUX_SYMBOL(__initramfs_start) = .; \
727 KEEP(*(.init.ramfs)) \
728 . = ALIGN(8); \
729 KEEP(*(.init.ramfs.info))
730 #else
731 #define INIT_RAM_FS
732 #endif
734 /*
735 * Default discarded sections.
736 *
737 * Some archs want to discard exit text/data at runtime rather than
738 * link time due to cross-section references such as alt instructions,
739 * bug table, eh_frame, etc. DISCARDS must be the last of output
740 * section definitions so that such archs put those in earlier section
741 * definitions.
742 */
743 #define DISCARDS \
744 /DISCARD/ : { \
745 EXIT_TEXT \
746 EXIT_DATA \
747 EXIT_CALL \
748 *(.discard) \
749 *(.discard.*) \
750 }
752 /**
753 * PERCPU_INPUT - the percpu input sections
754 * @cacheline: cacheline size
755 *
756 * The core percpu section names and core symbols which do not rely
757 * directly upon load addresses.
758 *
759 * @cacheline is used to align subsections to avoid false cacheline
760 * sharing between subsections for different purposes.
761 */
762 #define PERCPU_INPUT(cacheline) \
763 VMLINUX_SYMBOL(__per_cpu_start) = .; \
764 *(.data..percpu..first) \
765 . = ALIGN(PAGE_SIZE); \
766 *(.data..percpu..page_aligned) \
767 . = ALIGN(cacheline); \
768 *(.data..percpu..read_mostly) \
769 . = ALIGN(cacheline); \
770 *(.data..percpu) \
771 *(.data..percpu..shared_aligned) \
772 VMLINUX_SYMBOL(__per_cpu_end) = .;
774 /**
775 * PERCPU_VADDR - define output section for percpu area
776 * @cacheline: cacheline size
777 * @vaddr: explicit base address (optional)
778 * @phdr: destination PHDR (optional)
779 *
780 * Macro which expands to output section for percpu area.
781 *
782 * @cacheline is used to align subsections to avoid false cacheline
783 * sharing between subsections for different purposes.
784 *
785 * If @vaddr is not blank, it specifies explicit base address and all
786 * percpu symbols will be offset from the given address. If blank,
787 * @vaddr always equals @laddr + LOAD_OFFSET.
788 *
789 * @phdr defines the output PHDR to use if not blank. Be warned that
790 * output PHDR is sticky. If @phdr is specified, the next output
791 * section in the linker script will go there too. @phdr should have
792 * a leading colon.
793 *
794 * Note that this macros defines __per_cpu_load as an absolute symbol.
795 * If there is no need to put the percpu section at a predetermined
796 * address, use PERCPU_SECTION.
797 */
798 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
799 VMLINUX_SYMBOL(__per_cpu_load) = .; \
800 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
801 - LOAD_OFFSET) { \
802 PERCPU_INPUT(cacheline) \
803 } phdr \
804 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
806 /**
807 * PERCPU_SECTION - define output section for percpu area, simple version
808 * @cacheline: cacheline size
809 *
810 * Align to PAGE_SIZE and outputs output section for percpu area. This
811 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
812 * __per_cpu_start will be identical.
813 *
814 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
815 * except that __per_cpu_load is defined as a relative symbol against
816 * .data..percpu which is required for relocatable x86_32 configuration.
817 */
818 #define PERCPU_SECTION(cacheline) \
819 . = ALIGN(PAGE_SIZE); \
820 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
821 VMLINUX_SYMBOL(__per_cpu_load) = .; \
822 PERCPU_INPUT(cacheline) \
823 }
826 /*
827 * Definition of the high level *_SECTION macros
828 * They will fit only a subset of the architectures
829 */
832 /*
833 * Writeable data.
834 * All sections are combined in a single .data section.
835 * The sections following CONSTRUCTORS are arranged so their
836 * typical alignment matches.
837 * A cacheline is typical/always less than a PAGE_SIZE so
838 * the sections that has this restriction (or similar)
839 * is located before the ones requiring PAGE_SIZE alignment.
840 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
841 * matches the requirement of PAGE_ALIGNED_DATA.
842 *
843 * use 0 as page_align if page_aligned data is not used */
844 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
845 . = ALIGN(PAGE_SIZE); \
846 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
847 INIT_TASK_DATA(inittask) \
848 NOSAVE_DATA \
849 PAGE_ALIGNED_DATA(pagealigned) \
850 CACHELINE_ALIGNED_DATA(cacheline) \
851 READ_MOSTLY_DATA(cacheline) \
852 DATA_DATA \
853 CONSTRUCTORS \
854 }
856 #define INIT_TEXT_SECTION(inittext_align) \
857 . = ALIGN(inittext_align); \
858 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
859 VMLINUX_SYMBOL(_sinittext) = .; \
860 INIT_TEXT \
861 VMLINUX_SYMBOL(_einittext) = .; \
862 }
864 #define INIT_DATA_SECTION(initsetup_align) \
865 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
866 INIT_DATA \
867 INIT_SETUP(initsetup_align) \
868 INIT_CALLS \
869 CON_INITCALL \
870 SECURITY_INITCALL \
871 INIT_RAM_FS \
872 }
874 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
875 . = ALIGN(sbss_align); \
876 VMLINUX_SYMBOL(__bss_start) = .; \
877 SBSS(sbss_align) \
878 BSS(bss_align) \
879 . = ALIGN(stop_align); \
880 VMLINUX_SYMBOL(__bss_stop) = .;