arch/powerpc/sysdev/6xx-suspend.S

   1 /*
   2  * Enter and leave sleep state on chips with 6xx-style HID0
   3  * power management bits, which don't leave sleep state via reset.
   4  *
   5  * Author: Scott Wood <scottwood@freescale.com>
   6  *
   7  * Copyright (c) 2006-2007 Freescale Semiconductor, Inc.
   8  *
   9  * This program is free software; you can redistribute it and/or modify it
  10  * under the terms of the GNU General Public License version 2 as published
  11  * by the Free Software Foundation.
  12  */
  13
  14 #include <asm/ppc_asm.h>
  15 #include <asm/reg.h>
  16 #include <asm/thread_info.h>
  17 #include <asm/asm-offsets.h>
  18
  19 _GLOBAL(mpc6xx_enter_standby)
  20         mflr    r4
  21
  22         mfspr   r5, SPRN_HID0
  23         rlwinm  r5, r5, 0, ~(HID0_DOZE | HID0_NAP)
  24         oris    r5, r5, HID0_SLEEP@h
  25         mtspr   SPRN_HID0, r5
  26         isync
  27
  28         lis     r5, ret_from_standby@h
  29         ori     r5, r5, ret_from_standby@l
  30         mtlr    r5
  31
  32         CURRENT_THREAD_INFO(r5, r1)
  33         lwz     r6, TI_LOCAL_FLAGS(r5)
  34         ori     r6, r6, _TLF_SLEEPING
  35         stw     r6, TI_LOCAL_FLAGS(r5)
  36
  37         mfmsr   r5
  38         ori     r5, r5, MSR_EE
  39         oris    r5, r5, MSR_POW@h
  40         sync
  41         mtmsr   r5
  42         isync
  43
  44 1:      b       1b
  45
  46 ret_from_standby:
  47         mfspr   r5, SPRN_HID0
  48         rlwinm  r5, r5, 0, ~HID0_SLEEP
  49         mtspr   SPRN_HID0, r5
  50
  51         mtlr    r4
  52         blr