arch/parisc/lib/fixup.S

   1 /*
   2  * Linux/PA-RISC Project (http://www.parisc-linux.org/)
   3  *
   4  *  Copyright (C) 2004  Randolph Chung <tausq@debian.org>
   5  *
   6  *    This program is free software; you can redistribute it and/or modify
   7  *    it under the terms of the GNU General Public License as published by
   8  *    the Free Software Foundation; either version 2, or (at your option)
   9  *    any later version.
  10  *
  11  *    This program is distributed in the hope that it will be useful,
  12  *    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  *    GNU General Public License for more details.
  15  *
  16  *    You should have received a copy of the GNU General Public License
  17  *    along with this program; if not, write to the Free Software
  18  *    Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  19  *
  20  * Fixup routines for kernel exception handling.
  21  */
  22 #include <asm/asm-offsets.h>
  23 #include <asm/assembly.h>
  24 #include <asm/errno.h>
  25 #include <linux/linkage.h>
  26
  27 #ifdef CONFIG_SMP
  28         .macro  get_fault_ip t1 t2
  29         loadgp
  30         addil LT%__per_cpu_offset,%r27
  31         LDREG RT%__per_cpu_offset(%r1),\t1
  32         /* t2 = smp_processor_id() */
  33         mfctl 30,\t2
  34         ldw TI_CPU(\t2),\t2
  35 #ifdef CONFIG_64BIT
  36         extrd,u \t2,63,32,\t2
  37 #endif
  38         /* t2 = &__per_cpu_offset[smp_processor_id()]; */
  39         LDREGX \t2(\t1),\t2
  40         addil LT%exception_data,%r27
  41         LDREG RT%exception_data(%r1),\t1
  42         /* t1 = this_cpu_ptr(&exception_data) */
  43         add,l \t1,\t2,\t1
  44         /* %r27 = t1->fault_gp - restore gp */
  45         LDREG EXCDATA_GP(\t1), %r27
  46         /* t1 = t1->fault_ip */
  47         LDREG EXCDATA_IP(\t1), \t1
  48         .endm
  49 #else
  50         .macro  get_fault_ip t1 t2
  51         loadgp
  52         /* t1 = this_cpu_ptr(&exception_data) */
  53         addil LT%exception_data,%r27
  54         LDREG RT%exception_data(%r1),\t2
  55         /* %r27 = t2->fault_gp - restore gp */
  56         LDREG EXCDATA_GP(\t2), %r27
  57         /* t1 = t2->fault_ip */
  58         LDREG EXCDATA_IP(\t2), \t1
  59         .endm
  60 #endif
  61
  62         .level LEVEL
  63
  64         .text
  65         .section .fixup, "ax"
  66
  67         /* get_user() fixups, store -EFAULT in r8, and 0 in r9 */
  68 ENTRY(fixup_get_user_skip_1)
  69         get_fault_ip %r1,%r8
  70         ldo 4(%r1), %r1
  71         ldi -EFAULT, %r8
  72         bv %r0(%r1)
  73         copy %r0, %r9
  74 ENDPROC(fixup_get_user_skip_1)
  75
  76 ENTRY(fixup_get_user_skip_2)
  77         get_fault_ip %r1,%r8
  78         ldo 8(%r1), %r1
  79         ldi -EFAULT, %r8
  80         bv %r0(%r1)
  81         copy %r0, %r9
  82 ENDPROC(fixup_get_user_skip_2)
  83
  84         /* put_user() fixups, store -EFAULT in r8 */
  85 ENTRY(fixup_put_user_skip_1)
  86         get_fault_ip %r1,%r8
  87         ldo 4(%r1), %r1
  88         bv %r0(%r1)
  89         ldi -EFAULT, %r8
  90 ENDPROC(fixup_put_user_skip_1)
  91
  92 ENTRY(fixup_put_user_skip_2)
  93         get_fault_ip %r1,%r8
  94         ldo 8(%r1), %r1
  95         bv %r0(%r1)
  96         ldi -EFAULT, %r8
  97 ENDPROC(fixup_put_user_skip_2)
  98