| blob | 2b34e6de3e8a2ab90b48c14eeac11354bae2d685 |
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA(PAGE_SIZE)
27 * RW_DATA(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 *
32 * BSS_SECTION(0, 0, 0)
33 * _end = .;
34 *
35 * STABS_DEBUG
36 * DWARF_DEBUG
37 *
38 * DISCARDS // must be the last
39 * }
40 *
41 * [__init_begin, __init_end] is the init section that may be freed after init
42 * // __init_begin and __init_end should be page aligned, so that we can
43 * // free the whole .init memory
44 * [_stext, _etext] is the text section
45 * [_sdata, _edata] is the data section
46 *
47 * Some of the included output section have their own set of constants.
48 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
49 * [__nosave_begin, __nosave_end] for the nosave data
50 */
52 #ifndef LOAD_OFFSET
53 #define LOAD_OFFSET 0
54 #endif
56 /*
57 * Only some architectures want to have the .notes segment visible in
58 * a separate PT_NOTE ELF Program Header. When this happens, it needs
59 * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
60 * Program Headers. In this case, though, the PT_LOAD needs to be made
61 * the default again so that all the following sections don't also end
62 * up in the PT_NOTE Program Header.
63 */
64 #ifdef EMITS_PT_NOTE
65 #define NOTES_HEADERS :text :note
66 #define NOTES_HEADERS_RESTORE __restore_ph : { *(.__restore_ph) } :text
67 #else
68 #define NOTES_HEADERS
69 #define NOTES_HEADERS_RESTORE
70 #endif
72 /*
73 * Some architectures have non-executable read-only exception tables.
74 * They can be added to the RO_DATA segment by specifying their desired
75 * alignment.
76 */
77 #ifdef RO_EXCEPTION_TABLE_ALIGN
78 #define RO_EXCEPTION_TABLE EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
79 #else
80 #define RO_EXCEPTION_TABLE
81 #endif
83 /* Align . to a 8 byte boundary equals to maximum function alignment. */
84 #define ALIGN_FUNCTION() . = ALIGN(8)
86 /*
87 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
88 * generates .data.identifier sections, which need to be pulled in with
89 * .data. We don't want to pull in .data..other sections, which Linux
90 * has defined. Same for text and bss.
91 *
92 * RODATA_MAIN is not used because existing code already defines .rodata.x
93 * sections to be brought in with rodata.
94 */
95 #ifdef CONFIG_LD_DEAD_CODE_DATA_ELIMINATION
96 #define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
97 #define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..LPBX*
98 #define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
99 #define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]*
100 #define BSS_MAIN .bss .bss.[0-9a-zA-Z_]*
101 #define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
102 #else
103 #define TEXT_MAIN .text
104 #define DATA_MAIN .data
105 #define SDATA_MAIN .sdata
106 #define RODATA_MAIN .rodata
107 #define BSS_MAIN .bss
108 #define SBSS_MAIN .sbss
109 #endif
111 /*
112 * GCC 4.5 and later have a 32 bytes section alignment for structures.
113 * Except GCC 4.9, that feels the need to align on 64 bytes.
114 */
115 #if __GNUC__ == 4 && __GNUC_MINOR__ == 9
116 #define STRUCT_ALIGNMENT 64
117 #else
118 #define STRUCT_ALIGNMENT 32
119 #endif
120 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
122 /*
123 * The order of the sched class addresses are important, as they are
124 * used to determine the order of the priority of each sched class in
125 * relation to each other.
126 */
127 #define SCHED_DATA \
128 STRUCT_ALIGN(); \
129 __begin_sched_classes = .; \
130 *(__idle_sched_class) \
131 *(__fair_sched_class) \
132 *(__rt_sched_class) \
133 *(__dl_sched_class) \
134 *(__stop_sched_class) \
135 __end_sched_classes = .;
137 /* The actual configuration determine if the init/exit sections
138 * are handled as text/data or they can be discarded (which
139 * often happens at runtime)
140 */
141 #ifdef CONFIG_HOTPLUG_CPU
142 #define CPU_KEEP(sec) *(.cpu##sec)
143 #define CPU_DISCARD(sec)
144 #else
145 #define CPU_KEEP(sec)
146 #define CPU_DISCARD(sec) *(.cpu##sec)
147 #endif
149 #if defined(CONFIG_MEMORY_HOTPLUG)
150 #define MEM_KEEP(sec) *(.mem##sec)
151 #define MEM_DISCARD(sec)
152 #else
153 #define MEM_KEEP(sec)
154 #define MEM_DISCARD(sec) *(.mem##sec)
155 #endif
157 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
158 /*
159 * The ftrace call sites are logged to a section whose name depends on the
160 * compiler option used. A given kernel image will only use one, AKA
161 * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
162 * dependencies for FTRACE_CALLSITE_SECTION's definition.
163 *
164 * Need to also make ftrace_stub_graph point to ftrace_stub
165 * so that the same stub location may have different protocols
166 * and not mess up with C verifiers.
167 */
168 #define MCOUNT_REC() . = ALIGN(8); \
169 __start_mcount_loc = .; \
170 KEEP(*(__mcount_loc)) \
171 KEEP(*(__patchable_function_entries)) \
172 __stop_mcount_loc = .; \
173 ftrace_stub_graph = ftrace_stub;
174 #else
175 # ifdef CONFIG_FUNCTION_TRACER
176 # define MCOUNT_REC() ftrace_stub_graph = ftrace_stub;
177 # else
178 # define MCOUNT_REC()
179 # endif
180 #endif
182 #ifdef CONFIG_TRACE_BRANCH_PROFILING
183 #define LIKELY_PROFILE() __start_annotated_branch_profile = .; \
184 KEEP(*(_ftrace_annotated_branch)) \
185 __stop_annotated_branch_profile = .;
186 #else
187 #define LIKELY_PROFILE()
188 #endif
190 #ifdef CONFIG_PROFILE_ALL_BRANCHES
191 #define BRANCH_PROFILE() __start_branch_profile = .; \
192 KEEP(*(_ftrace_branch)) \
193 __stop_branch_profile = .;
194 #else
195 #define BRANCH_PROFILE()
196 #endif
198 #ifdef CONFIG_KPROBES
199 #define KPROBE_BLACKLIST() . = ALIGN(8); \
200 __start_kprobe_blacklist = .; \
201 KEEP(*(_kprobe_blacklist)) \
202 __stop_kprobe_blacklist = .;
203 #else
204 #define KPROBE_BLACKLIST()
205 #endif
207 #ifdef CONFIG_FUNCTION_ERROR_INJECTION
208 #define ERROR_INJECT_WHITELIST() STRUCT_ALIGN(); \
209 __start_error_injection_whitelist = .; \
210 KEEP(*(_error_injection_whitelist)) \
211 __stop_error_injection_whitelist = .;
212 #else
213 #define ERROR_INJECT_WHITELIST()
214 #endif
216 #ifdef CONFIG_EVENT_TRACING
217 #define FTRACE_EVENTS() . = ALIGN(8); \
218 __start_ftrace_events = .; \
219 KEEP(*(_ftrace_events)) \
220 __stop_ftrace_events = .; \
221 __start_ftrace_eval_maps = .; \
222 KEEP(*(_ftrace_eval_map)) \
223 __stop_ftrace_eval_maps = .;
224 #else
225 #define FTRACE_EVENTS()
226 #endif
228 #ifdef CONFIG_TRACING
229 #define TRACE_PRINTKS() __start___trace_bprintk_fmt = .; \
231 __stop___trace_bprintk_fmt = .;
232 #define TRACEPOINT_STR() __start___tracepoint_str = .; \
234 __stop___tracepoint_str = .;
235 #else
236 #define TRACE_PRINTKS()
237 #define TRACEPOINT_STR()
238 #endif
240 #ifdef CONFIG_FTRACE_SYSCALLS
241 #define TRACE_SYSCALLS() . = ALIGN(8); \
242 __start_syscalls_metadata = .; \
243 KEEP(*(__syscalls_metadata)) \
244 __stop_syscalls_metadata = .;
245 #else
246 #define TRACE_SYSCALLS()
247 #endif
249 #ifdef CONFIG_BPF_EVENTS
250 #define BPF_RAW_TP() STRUCT_ALIGN(); \
251 __start__bpf_raw_tp = .; \
252 KEEP(*(__bpf_raw_tp_map)) \
253 __stop__bpf_raw_tp = .;
254 #else
255 #define BPF_RAW_TP()
256 #endif
258 #ifdef CONFIG_SERIAL_EARLYCON
259 #define EARLYCON_TABLE() . = ALIGN(8); \
260 __earlycon_table = .; \
261 KEEP(*(__earlycon_table)) \
262 __earlycon_table_end = .;
263 #else
264 #define EARLYCON_TABLE()
265 #endif
267 #ifdef CONFIG_SECURITY
268 #define LSM_TABLE() . = ALIGN(8); \
269 __start_lsm_info = .; \
270 KEEP(*(.lsm_info.init)) \
271 __end_lsm_info = .;
272 #define EARLY_LSM_TABLE() . = ALIGN(8); \
273 __start_early_lsm_info = .; \
274 KEEP(*(.early_lsm_info.init)) \
275 __end_early_lsm_info = .;
276 #else
277 #define LSM_TABLE()
278 #define EARLY_LSM_TABLE()
279 #endif
281 #define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
282 #define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
283 #define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
284 #define _OF_TABLE_0(name)
285 #define _OF_TABLE_1(name) \
286 . = ALIGN(8); \
287 __##name##_of_table = .; \
288 KEEP(*(__##name##_of_table)) \
289 KEEP(*(__##name##_of_table_end))
291 #define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
292 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
293 #define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
294 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
295 #define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
296 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
298 #ifdef CONFIG_ACPI
299 #define ACPI_PROBE_TABLE(name) \
300 . = ALIGN(8); \
301 __##name##_acpi_probe_table = .; \
302 KEEP(*(__##name##_acpi_probe_table)) \
303 __##name##_acpi_probe_table_end = .;
304 #else
305 #define ACPI_PROBE_TABLE(name)
306 #endif
308 #ifdef CONFIG_THERMAL
309 #define THERMAL_TABLE(name) \
310 . = ALIGN(8); \
311 __##name##_thermal_table = .; \
312 KEEP(*(__##name##_thermal_table)) \
313 __##name##_thermal_table_end = .;
314 #else
315 #define THERMAL_TABLE(name)
316 #endif
318 #define KERNEL_DTB() \
319 STRUCT_ALIGN(); \
320 __dtb_start = .; \
321 KEEP(*(.dtb.init.rodata)) \
322 __dtb_end = .;
324 /*
325 * .data section
326 */
327 #define DATA_DATA \
328 *(.xiptext) \
329 *(DATA_MAIN) \
330 *(.ref.data) \
332 MEM_KEEP(init.data*) \
333 MEM_KEEP(exit.data*) \
334 *(.data.unlikely) \
335 __start_once = .; \
336 *(.data.once) \
337 __end_once = .; \
338 STRUCT_ALIGN(); \
339 *(__tracepoints) \
341 . = ALIGN(8); \
342 __start___dyndbg = .; \
343 KEEP(*(__dyndbg)) \
344 __stop___dyndbg = .; \
345 LIKELY_PROFILE() \
346 BRANCH_PROFILE() \
347 TRACE_PRINTKS() \
348 BPF_RAW_TP() \
349 TRACEPOINT_STR()
351 /*
352 * Data section helpers
353 */
354 #define NOSAVE_DATA \
355 . = ALIGN(PAGE_SIZE); \
356 __nosave_begin = .; \
357 *(.data..nosave) \
358 . = ALIGN(PAGE_SIZE); \
359 __nosave_end = .;
361 #define PAGE_ALIGNED_DATA(page_align) \
362 . = ALIGN(page_align); \
363 *(.data..page_aligned) \
364 . = ALIGN(page_align);
366 #define READ_MOSTLY_DATA(align) \
367 . = ALIGN(align); \
368 *(.data..read_mostly) \
369 . = ALIGN(align);
371 #define CACHELINE_ALIGNED_DATA(align) \
372 . = ALIGN(align); \
373 *(.data..cacheline_aligned)
375 #define INIT_TASK_DATA(align) \
376 . = ALIGN(align); \
377 __start_init_task = .; \
378 init_thread_union = .; \
379 init_stack = .; \
380 KEEP(*(.data..init_task)) \
381 KEEP(*(.data..init_thread_info)) \
382 . = __start_init_task + THREAD_SIZE; \
383 __end_init_task = .;
385 #define JUMP_TABLE_DATA \
386 . = ALIGN(8); \
387 __start___jump_table = .; \
388 KEEP(*(__jump_table)) \
389 __stop___jump_table = .;
391 /*
392 * Allow architectures to handle ro_after_init data on their
393 * own by defining an empty RO_AFTER_INIT_DATA.
394 */
395 #ifndef RO_AFTER_INIT_DATA
396 #define RO_AFTER_INIT_DATA \
397 . = ALIGN(8); \
398 __start_ro_after_init = .; \
399 *(.data..ro_after_init) \
400 JUMP_TABLE_DATA \
401 __end_ro_after_init = .;
402 #endif
404 /*
405 * Read only Data
406 */
407 #define RO_DATA(align) \
408 . = ALIGN((align)); \
409 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
410 __start_rodata = .; \
411 *(.rodata) *(.rodata.*) \
412 SCHED_DATA \
414 . = ALIGN(8); \
415 __start___tracepoints_ptrs = .; \
417 __stop___tracepoints_ptrs = .; \
419 } \
420 \
421 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
422 *(.rodata1) \
423 } \
424 \
426 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
427 __start_pci_fixups_early = .; \
428 KEEP(*(.pci_fixup_early)) \
429 __end_pci_fixups_early = .; \
430 __start_pci_fixups_header = .; \
431 KEEP(*(.pci_fixup_header)) \
432 __end_pci_fixups_header = .; \
433 __start_pci_fixups_final = .; \
434 KEEP(*(.pci_fixup_final)) \
435 __end_pci_fixups_final = .; \
436 __start_pci_fixups_enable = .; \
437 KEEP(*(.pci_fixup_enable)) \
438 __end_pci_fixups_enable = .; \
439 __start_pci_fixups_resume = .; \
440 KEEP(*(.pci_fixup_resume)) \
441 __end_pci_fixups_resume = .; \
442 __start_pci_fixups_resume_early = .; \
443 KEEP(*(.pci_fixup_resume_early)) \
444 __end_pci_fixups_resume_early = .; \
445 __start_pci_fixups_suspend = .; \
446 KEEP(*(.pci_fixup_suspend)) \
447 __end_pci_fixups_suspend = .; \
448 __start_pci_fixups_suspend_late = .; \
449 KEEP(*(.pci_fixup_suspend_late)) \
450 __end_pci_fixups_suspend_late = .; \
451 } \
452 \
454 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
455 __start_builtin_fw = .; \
456 KEEP(*(.builtin_fw)) \
457 __end_builtin_fw = .; \
458 } \
459 \
460 TRACEDATA \
461 \
463 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
464 __start___ksymtab = .; \
465 KEEP(*(SORT(___ksymtab+*))) \
466 __stop___ksymtab = .; \
467 } \
468 \
470 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
471 __start___ksymtab_gpl = .; \
472 KEEP(*(SORT(___ksymtab_gpl+*))) \
473 __stop___ksymtab_gpl = .; \
474 } \
475 \
477 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
478 __start___ksymtab_unused = .; \
479 KEEP(*(SORT(___ksymtab_unused+*))) \
480 __stop___ksymtab_unused = .; \
481 } \
482 \
484 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
485 __start___ksymtab_unused_gpl = .; \
486 KEEP(*(SORT(___ksymtab_unused_gpl+*))) \
487 __stop___ksymtab_unused_gpl = .; \
488 } \
489 \
491 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
492 __start___ksymtab_gpl_future = .; \
493 KEEP(*(SORT(___ksymtab_gpl_future+*))) \
494 __stop___ksymtab_gpl_future = .; \
495 } \
496 \
498 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
499 __start___kcrctab = .; \
500 KEEP(*(SORT(___kcrctab+*))) \
501 __stop___kcrctab = .; \
502 } \
503 \
505 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
506 __start___kcrctab_gpl = .; \
507 KEEP(*(SORT(___kcrctab_gpl+*))) \
508 __stop___kcrctab_gpl = .; \
509 } \
510 \
512 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
513 __start___kcrctab_unused = .; \
514 KEEP(*(SORT(___kcrctab_unused+*))) \
515 __stop___kcrctab_unused = .; \
516 } \
517 \
519 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
520 __start___kcrctab_unused_gpl = .; \
521 KEEP(*(SORT(___kcrctab_unused_gpl+*))) \
522 __stop___kcrctab_unused_gpl = .; \
523 } \
524 \
526 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
527 __start___kcrctab_gpl_future = .; \
528 KEEP(*(SORT(___kcrctab_gpl_future+*))) \
529 __stop___kcrctab_gpl_future = .; \
530 } \
531 \
533 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
534 *(__ksymtab_strings) \
535 } \
536 \
538 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
539 *(.ref.rodata) \
540 MEM_KEEP(init.rodata) \
541 MEM_KEEP(exit.rodata) \
542 } \
543 \
545 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
546 __start___param = .; \
547 KEEP(*(__param)) \
548 __stop___param = .; \
549 } \
550 \
552 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
553 __start___modver = .; \
554 KEEP(*(__modver)) \
555 __stop___modver = .; \
556 } \
557 \
558 RO_EXCEPTION_TABLE \
559 NOTES \
560 BTF \
561 \
562 . = ALIGN((align)); \
563 __end_rodata = .;
565 /*
566 * Non-instrumentable text section
567 */
568 #define NOINSTR_TEXT \
569 ALIGN_FUNCTION(); \
570 __noinstr_text_start = .; \
571 *(.noinstr.text) \
572 __noinstr_text_end = .;
574 /*
575 * .text section. Map to function alignment to avoid address changes
576 * during second ld run in second ld pass when generating System.map
577 *
578 * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
579 * code elimination is enabled, so these sections should be converted
580 * to use ".." first.
581 */
582 #define TEXT_TEXT \
583 ALIGN_FUNCTION(); \
584 *(.text.hot .text.hot.*) \
585 *(TEXT_MAIN .text.fixup) \
586 *(.text.unlikely .text.unlikely.*) \
587 *(.text.unknown .text.unknown.*) \
588 NOINSTR_TEXT \
589 *(.text..refcount) \
590 *(.ref.text) \
591 MEM_KEEP(init.text*) \
592 MEM_KEEP(exit.text*) \
595 /* sched.text is aling to function alignment to secure we have same
596 * address even at second ld pass when generating System.map */
597 #define SCHED_TEXT \
598 ALIGN_FUNCTION(); \
599 __sched_text_start = .; \
600 *(.sched.text) \
601 __sched_text_end = .;
603 /* spinlock.text is aling to function alignment to secure we have same
604 * address even at second ld pass when generating System.map */
605 #define LOCK_TEXT \
606 ALIGN_FUNCTION(); \
607 __lock_text_start = .; \
608 *(.spinlock.text) \
609 __lock_text_end = .;
611 #define CPUIDLE_TEXT \
612 ALIGN_FUNCTION(); \
613 __cpuidle_text_start = .; \
614 *(.cpuidle.text) \
615 __cpuidle_text_end = .;
617 #define KPROBES_TEXT \
618 ALIGN_FUNCTION(); \
619 __kprobes_text_start = .; \
620 *(.kprobes.text) \
621 __kprobes_text_end = .;
623 #define ENTRY_TEXT \
624 ALIGN_FUNCTION(); \
625 __entry_text_start = .; \
626 *(.entry.text) \
627 __entry_text_end = .;
629 #define IRQENTRY_TEXT \
630 ALIGN_FUNCTION(); \
631 __irqentry_text_start = .; \
632 *(.irqentry.text) \
633 __irqentry_text_end = .;
635 #define SOFTIRQENTRY_TEXT \
636 ALIGN_FUNCTION(); \
637 __softirqentry_text_start = .; \
638 *(.softirqentry.text) \
639 __softirqentry_text_end = .;
641 /* Section used for early init (in .S files) */
642 #define HEAD_TEXT KEEP(*(.head.text))
644 #define HEAD_TEXT_SECTION \
645 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
646 HEAD_TEXT \
647 }
649 /*
650 * Exception table
651 */
652 #define EXCEPTION_TABLE(align) \
653 . = ALIGN(align); \
654 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
655 __start___ex_table = .; \
656 KEEP(*(__ex_table)) \
657 __stop___ex_table = .; \
658 }
660 /*
661 * .BTF
662 */
663 #ifdef CONFIG_DEBUG_INFO_BTF
664 #define BTF \
665 .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) { \
666 __start_BTF = .; \
667 KEEP(*(.BTF)) \
668 __stop_BTF = .; \
669 } \
670 . = ALIGN(4); \
671 .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) { \
672 *(.BTF_ids) \
673 }
674 #else
675 #define BTF
676 #endif
678 /*
679 * Init task
680 */
681 #define INIT_TASK_DATA_SECTION(align) \
682 . = ALIGN(align); \
683 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
684 INIT_TASK_DATA(align) \
685 }
687 #ifdef CONFIG_CONSTRUCTORS
688 #define KERNEL_CTORS() . = ALIGN(8); \
689 __ctors_start = .; \
690 KEEP(*(.ctors)) \
691 KEEP(*(SORT(.init_array.*))) \
692 KEEP(*(.init_array)) \
693 __ctors_end = .;
694 #else
695 #define KERNEL_CTORS()
696 #endif
698 /* init and exit section handling */
699 #define INIT_DATA \
700 KEEP(*(SORT(___kentry+*))) \
701 *(.init.data init.data.*) \
702 MEM_DISCARD(init.data*) \
703 KERNEL_CTORS() \
704 MCOUNT_REC() \
705 *(.init.rodata .init.rodata.*) \
706 FTRACE_EVENTS() \
707 TRACE_SYSCALLS() \
708 KPROBE_BLACKLIST() \
709 ERROR_INJECT_WHITELIST() \
710 MEM_DISCARD(init.rodata) \
711 CLK_OF_TABLES() \
712 RESERVEDMEM_OF_TABLES() \
713 TIMER_OF_TABLES() \
714 CPU_METHOD_OF_TABLES() \
715 CPUIDLE_METHOD_OF_TABLES() \
716 KERNEL_DTB() \
717 IRQCHIP_OF_MATCH_TABLE() \
718 ACPI_PROBE_TABLE(irqchip) \
719 ACPI_PROBE_TABLE(timer) \
720 THERMAL_TABLE(governor) \
721 EARLYCON_TABLE() \
722 LSM_TABLE() \
723 EARLY_LSM_TABLE()
725 #define INIT_TEXT \
726 *(.init.text .init.text.*) \
727 *(.text.startup) \
728 MEM_DISCARD(init.text*)
730 #define EXIT_DATA \
731 *(.exit.data .exit.data.*) \
732 *(.fini_array .fini_array.*) \
733 *(.dtors .dtors.*) \
734 MEM_DISCARD(exit.data*) \
735 MEM_DISCARD(exit.rodata*)
737 #define EXIT_TEXT \
738 *(.exit.text) \
739 *(.text.exit) \
740 MEM_DISCARD(exit.text)
742 #define EXIT_CALL \
743 *(.exitcall.exit)
745 /*
746 * bss (Block Started by Symbol) - uninitialized data
747 * zeroed during startup
748 */
749 #define SBSS(sbss_align) \
750 . = ALIGN(sbss_align); \
751 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
752 *(.dynsbss) \
753 *(SBSS_MAIN) \
754 *(.scommon) \
755 }
757 /*
758 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
759 * sections to the front of bss.
760 */
761 #ifndef BSS_FIRST_SECTIONS
762 #define BSS_FIRST_SECTIONS
763 #endif
765 #define BSS(bss_align) \
766 . = ALIGN(bss_align); \
767 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
768 BSS_FIRST_SECTIONS \
769 . = ALIGN(PAGE_SIZE); \
770 *(.bss..page_aligned) \
771 . = ALIGN(PAGE_SIZE); \
772 *(.dynbss) \
773 *(BSS_MAIN) \
774 *(COMMON) \
775 }
777 /*
778 * DWARF debug sections.
779 * Symbols in the DWARF debugging sections are relative to
780 * the beginning of the section so we begin them at 0.
781 */
782 #define DWARF_DEBUG \
784 .debug 0 : { *(.debug) } \
785 .line 0 : { *(.line) } \
787 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
788 .debug_sfnames 0 : { *(.debug_sfnames) } \
790 .debug_aranges 0 : { *(.debug_aranges) } \
791 .debug_pubnames 0 : { *(.debug_pubnames) } \
793 .debug_info 0 : { *(.debug_info \
794 .gnu.linkonce.wi.*) } \
795 .debug_abbrev 0 : { *(.debug_abbrev) } \
796 .debug_line 0 : { *(.debug_line) } \
797 .debug_frame 0 : { *(.debug_frame) } \
798 .debug_str 0 : { *(.debug_str) } \
799 .debug_loc 0 : { *(.debug_loc) } \
800 .debug_macinfo 0 : { *(.debug_macinfo) } \
801 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
803 .debug_ranges 0 : { *(.debug_ranges) } \
805 .debug_weaknames 0 : { *(.debug_weaknames) } \
806 .debug_funcnames 0 : { *(.debug_funcnames) } \
807 .debug_typenames 0 : { *(.debug_typenames) } \
808 .debug_varnames 0 : { *(.debug_varnames) } \
810 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
811 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
813 .debug_types 0 : { *(.debug_types) } \
815 .debug_macro 0 : { *(.debug_macro) } \
816 .debug_addr 0 : { *(.debug_addr) }
818 /* Stabs debugging sections. */
819 #define STABS_DEBUG \
820 .stab 0 : { *(.stab) } \
821 .stabstr 0 : { *(.stabstr) } \
822 .stab.excl 0 : { *(.stab.excl) } \
823 .stab.exclstr 0 : { *(.stab.exclstr) } \
824 .stab.index 0 : { *(.stab.index) } \
825 .stab.indexstr 0 : { *(.stab.indexstr) } \
826 .comment 0 : { *(.comment) }
828 #ifdef CONFIG_GENERIC_BUG
829 #define BUG_TABLE \
830 . = ALIGN(8); \
831 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
832 __start___bug_table = .; \
833 KEEP(*(__bug_table)) \
834 __stop___bug_table = .; \
835 }
836 #else
837 #define BUG_TABLE
838 #endif
840 #ifdef CONFIG_UNWINDER_ORC
841 #define ORC_UNWIND_TABLE \
842 . = ALIGN(4); \
843 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
844 __start_orc_unwind_ip = .; \
845 KEEP(*(.orc_unwind_ip)) \
846 __stop_orc_unwind_ip = .; \
847 } \
848 . = ALIGN(2); \
849 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
850 __start_orc_unwind = .; \
851 KEEP(*(.orc_unwind)) \
852 __stop_orc_unwind = .; \
853 } \
854 . = ALIGN(4); \
855 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
856 orc_lookup = .; \
857 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) / \
858 LOOKUP_BLOCK_SIZE) + 1) * 4; \
859 orc_lookup_end = .; \
860 }
861 #else
862 #define ORC_UNWIND_TABLE
863 #endif
865 #ifdef CONFIG_PM_TRACE
866 #define TRACEDATA \
867 . = ALIGN(4); \
868 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
869 __tracedata_start = .; \
870 KEEP(*(.tracedata)) \
871 __tracedata_end = .; \
872 }
873 #else
874 #define TRACEDATA
875 #endif
877 #define NOTES \
878 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
879 __start_notes = .; \
880 KEEP(*(.note.*)) \
881 __stop_notes = .; \
882 } NOTES_HEADERS \
883 NOTES_HEADERS_RESTORE
885 #define INIT_SETUP(initsetup_align) \
886 . = ALIGN(initsetup_align); \
887 __setup_start = .; \
888 KEEP(*(.init.setup)) \
889 __setup_end = .;
891 #define INIT_CALLS_LEVEL(level) \
892 __initcall##level##_start = .; \
893 KEEP(*(.initcall##level##.init)) \
894 KEEP(*(.initcall##level##s.init)) \
896 #define INIT_CALLS \
897 __initcall_start = .; \
898 KEEP(*(.initcallearly.init)) \
899 INIT_CALLS_LEVEL(0) \
900 INIT_CALLS_LEVEL(1) \
901 INIT_CALLS_LEVEL(2) \
902 INIT_CALLS_LEVEL(3) \
903 INIT_CALLS_LEVEL(4) \
904 INIT_CALLS_LEVEL(5) \
905 INIT_CALLS_LEVEL(rootfs) \
906 INIT_CALLS_LEVEL(6) \
907 INIT_CALLS_LEVEL(7) \
908 __initcall_end = .;
910 #define CON_INITCALL \
911 __con_initcall_start = .; \
912 KEEP(*(.con_initcall.init)) \
913 __con_initcall_end = .;
915 #ifdef CONFIG_BLK_DEV_INITRD
916 #define INIT_RAM_FS \
917 . = ALIGN(4); \
918 __initramfs_start = .; \
919 KEEP(*(.init.ramfs)) \
920 . = ALIGN(8); \
921 KEEP(*(.init.ramfs.info))
922 #else
923 #define INIT_RAM_FS
924 #endif
926 /*
927 * Memory encryption operates on a page basis. Since we need to clear
928 * the memory encryption mask for this section, it needs to be aligned
929 * on a page boundary and be a page-size multiple in length.
930 *
931 * Note: We use a separate section so that only this section gets
932 * decrypted to avoid exposing more than we wish.
933 */
934 #ifdef CONFIG_AMD_MEM_ENCRYPT
935 #define PERCPU_DECRYPTED_SECTION \
936 . = ALIGN(PAGE_SIZE); \
937 *(.data..percpu..decrypted) \
938 . = ALIGN(PAGE_SIZE);
939 #else
940 #define PERCPU_DECRYPTED_SECTION
941 #endif
944 /*
945 * Default discarded sections.
946 *
947 * Some archs want to discard exit text/data at runtime rather than
948 * link time due to cross-section references such as alt instructions,
949 * bug table, eh_frame, etc. DISCARDS must be the last of output
950 * section definitions so that such archs put those in earlier section
951 * definitions.
952 */
953 #ifdef RUNTIME_DISCARD_EXIT
954 #define EXIT_DISCARDS
955 #else
956 #define EXIT_DISCARDS \
957 EXIT_TEXT \
958 EXIT_DATA
959 #endif
961 #define DISCARDS \
962 /DISCARD/ : { \
963 EXIT_DISCARDS \
964 EXIT_CALL \
965 *(.discard) \
966 *(.discard.*) \
967 *(.modinfo) \
968 }
970 /**
971 * PERCPU_INPUT - the percpu input sections
972 * @cacheline: cacheline size
973 *
974 * The core percpu section names and core symbols which do not rely
975 * directly upon load addresses.
976 *
977 * @cacheline is used to align subsections to avoid false cacheline
978 * sharing between subsections for different purposes.
979 */
980 #define PERCPU_INPUT(cacheline) \
981 __per_cpu_start = .; \
982 *(.data..percpu..first) \
983 . = ALIGN(PAGE_SIZE); \
984 *(.data..percpu..page_aligned) \
985 . = ALIGN(cacheline); \
986 *(.data..percpu..read_mostly) \
987 . = ALIGN(cacheline); \
988 *(.data..percpu) \
989 *(.data..percpu..shared_aligned) \
990 PERCPU_DECRYPTED_SECTION \
991 __per_cpu_end = .;
993 /**
994 * PERCPU_VADDR - define output section for percpu area
995 * @cacheline: cacheline size
996 * @vaddr: explicit base address (optional)
997 * @phdr: destination PHDR (optional)
998 *
999 * Macro which expands to output section for percpu area.
1000 *
1001 * @cacheline is used to align subsections to avoid false cacheline
1002 * sharing between subsections for different purposes.
1003 *
1004 * If @vaddr is not blank, it specifies explicit base address and all
1005 * percpu symbols will be offset from the given address. If blank,
1006 * @vaddr always equals @laddr + LOAD_OFFSET.
1007 *
1008 * @phdr defines the output PHDR to use if not blank. Be warned that
1009 * output PHDR is sticky. If @phdr is specified, the next output
1010 * section in the linker script will go there too. @phdr should have
1011 * a leading colon.
1012 *
1013 * Note that this macros defines __per_cpu_load as an absolute symbol.
1014 * If there is no need to put the percpu section at a predetermined
1015 * address, use PERCPU_SECTION.
1016 */
1017 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
1018 __per_cpu_load = .; \
1019 .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) { \
1020 PERCPU_INPUT(cacheline) \
1021 } phdr \
1022 . = __per_cpu_load + SIZEOF(.data..percpu);
1024 /**
1025 * PERCPU_SECTION - define output section for percpu area, simple version
1026 * @cacheline: cacheline size
1027 *
1028 * Align to PAGE_SIZE and outputs output section for percpu area. This
1029 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
1030 * __per_cpu_start will be identical.
1031 *
1032 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
1033 * except that __per_cpu_load is defined as a relative symbol against
1034 * .data..percpu which is required for relocatable x86_32 configuration.
1035 */
1036 #define PERCPU_SECTION(cacheline) \
1037 . = ALIGN(PAGE_SIZE); \
1038 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
1039 __per_cpu_load = .; \
1040 PERCPU_INPUT(cacheline) \
1041 }
1044 /*
1045 * Definition of the high level *_SECTION macros
1046 * They will fit only a subset of the architectures
1047 */
1050 /*
1051 * Writeable data.
1052 * All sections are combined in a single .data section.
1053 * The sections following CONSTRUCTORS are arranged so their
1054 * typical alignment matches.
1055 * A cacheline is typical/always less than a PAGE_SIZE so
1056 * the sections that has this restriction (or similar)
1057 * is located before the ones requiring PAGE_SIZE alignment.
1058 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1059 * matches the requirement of PAGE_ALIGNED_DATA.
1060 *
1061 * use 0 as page_align if page_aligned data is not used */
1062 #define RW_DATA(cacheline, pagealigned, inittask) \
1063 . = ALIGN(PAGE_SIZE); \
1064 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
1065 INIT_TASK_DATA(inittask) \
1066 NOSAVE_DATA \
1067 PAGE_ALIGNED_DATA(pagealigned) \
1068 CACHELINE_ALIGNED_DATA(cacheline) \
1069 READ_MOSTLY_DATA(cacheline) \
1070 DATA_DATA \
1071 CONSTRUCTORS \
1072 } \
1073 BUG_TABLE \
1075 #define INIT_TEXT_SECTION(inittext_align) \
1076 . = ALIGN(inittext_align); \
1077 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
1078 _sinittext = .; \
1079 INIT_TEXT \
1080 _einittext = .; \
1081 }
1083 #define INIT_DATA_SECTION(initsetup_align) \
1084 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
1085 INIT_DATA \
1086 INIT_SETUP(initsetup_align) \
1087 INIT_CALLS \
1088 CON_INITCALL \
1089 INIT_RAM_FS \
1090 }
1092 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
1093 . = ALIGN(sbss_align); \
1094 __bss_start = .; \
1095 SBSS(sbss_align) \
1096 BSS(bss_align) \
1097 . = ALIGN(stop_align); \
1098 __bss_stop = .;