arch/arc/kernel/entry.S

   1 /*
   2  * Common Low Level Interrupts/Traps/Exceptions(non-TLB) Handling for ARC
   3  * (included from entry-<isa>.S
   4  *
   5  * Copyright (C) 2014-15 Synopsys, Inc. (www.synopsys.com)
   6  * Copyright (C) 2004, 2007-2010, 2011-2012 Synopsys, Inc. (www.synopsys.com)
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  */
  12
  13 /*------------------------------------------------------------------
  14  *    Function                            ABI
  15  *------------------------------------------------------------------
  16  *
  17  *  Arguments                           r0 - r7
  18  *  Caller Saved Registers              r0 - r12
  19  *  Callee Saved Registers              r13- r25
  20  *  Global Pointer (gp)                 r26
  21  *  Frame Pointer (fp)                  r27
  22  *  Stack Pointer (sp)                  r28
  23  *  Branch link register (blink)        r31
  24  *------------------------------------------------------------------
  25  */
  26
  27 ;################### Special Sys Call Wrappers ##########################
  28
  29 ENTRY(sys_clone_wrapper)
  30         SAVE_CALLEE_SAVED_USER
  31         bl  @sys_clone
  32         DISCARD_CALLEE_SAVED_USER
  33
  34         GET_CURR_THR_INFO_FLAGS   r10
  35         btst r10, TIF_SYSCALL_TRACE
  36         bnz  tracesys_exit
  37
  38         b ret_from_system_call
  39 END(sys_clone_wrapper)
  40
  41 ENTRY(ret_from_fork)
  42         ; when the forked child comes here from the __switch_to function
  43         ; r0 has the last task pointer.
  44         ; put last task in scheduler queue
  45         bl   @schedule_tail
  46
  47         ld   r9, [sp, PT_status32]
  48         brne r9, 0, 1f
  49
  50         jl.d [r14]              ; kernel thread entry point
  51         mov  r0, r13            ; (see PF_KTHREAD block in copy_thread)
  52
  53 1:
  54         ; Return to user space
  55         ; 1. Any forked task (Reach here via BRne above)
  56         ; 2. First ever init task (Reach here via return from JL above)
  57         ;    This is the historic "kernel_execve" use-case, to return to init
  58         ;    user mode, in a round about way since that is always done from
  59         ;    a kernel thread which is executed via JL above but always returns
  60         ;    out whenever kernel_execve (now inline do_fork()) is involved
  61         b    ret_from_exception
  62 END(ret_from_fork)
  63
  64 #ifdef CONFIG_ARC_DW2_UNWIND
  65 ; Workaround for bug 94179 (STAR ):
  66 ; Despite -fasynchronous-unwind-tables, linker is not making dwarf2 unwinder
  67 ; section (.debug_frame) as loadable. So we force it here.
  68 ; This also fixes STAR 9000487933 where the prev-workaround (objcopy --setflag)
  69 ; would not work after a clean build due to kernel build system dependencies.
  70 .section .debug_frame, "wa",@progbits
  71
  72 ; Reset to .text as this file is included in entry-<isa>.S
  73 .section .text, "ax",@progbits
  74 #endif
  75
  76 ;################### Non TLB Exception Handling #############################
  77
  78 ; ---------------------------------------------
  79 ; Instruction Error Exception Handler
  80 ; ---------------------------------------------
  81
  82 ENTRY(instr_service)
  83
  84         EXCEPTION_PROLOGUE
  85
  86         lr  r0, [efa]
  87         mov r1, sp
  88
  89         FAKE_RET_FROM_EXCPN
  90
  91         bl  do_insterror_or_kprobe
  92         b   ret_from_exception
  93 END(instr_service)
  94
  95 ; ---------------------------------------------
  96 ; Memory Error Exception Handler
  97 ; ---------------------------------------------
  98
  99 ENTRY(mem_service)
 100
 101         EXCEPTION_PROLOGUE
 102
 103         lr  r0, [efa]
 104         mov r1, sp
 105
 106         FAKE_RET_FROM_EXCPN
 107
 108         bl  do_memory_error
 109         b   ret_from_exception
 110 END(mem_service)
 111
 112 ; ---------------------------------------------
 113 ; Machine Check Exception Handler
 114 ; ---------------------------------------------
 115
 116 ENTRY(EV_MachineCheck)
 117
 118         EXCEPTION_PROLOGUE
 119
 120         lr  r2, [ecr]
 121         lr  r0, [efa]
 122         mov r1, sp
 123
 124         lsr     r3, r2, 8
 125         bmsk    r3, r3, 7
 126         brne    r3, ECR_C_MCHK_DUP_TLB, 1f
 127
 128         bl      do_tlb_overlap_fault
 129         b       ret_from_exception
 130
 131 1:
 132         ; DEAD END: can't do much, display Regs and HALT
 133         SAVE_CALLEE_SAVED_USER
 134
 135         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r10
 136         st  sp, [r10, THREAD_CALLEE_REG]
 137
 138         j  do_machine_check_fault
 139
 140 END(EV_MachineCheck)
 141
 142 ; ---------------------------------------------
 143 ; Privilege Violation Exception Handler
 144 ; ---------------------------------------------
 145 ENTRY(EV_PrivilegeV)
 146
 147         EXCEPTION_PROLOGUE
 148
 149         lr  r0, [efa]
 150         mov r1, sp
 151
 152         FAKE_RET_FROM_EXCPN
 153
 154         bl  do_privilege_fault
 155         b   ret_from_exception
 156 END(EV_PrivilegeV)
 157
 158 ; ---------------------------------------------
 159 ; Extension Instruction Exception Handler
 160 ; ---------------------------------------------
 161 ENTRY(EV_Extension)
 162
 163         EXCEPTION_PROLOGUE
 164
 165         lr  r0, [efa]
 166         mov r1, sp
 167
 168         FAKE_RET_FROM_EXCPN
 169
 170         bl  do_extension_fault
 171         b   ret_from_exception
 172 END(EV_Extension)
 173
 174 ;################ Trap Handling (Syscall, Breakpoint) ##################
 175
 176 ; ---------------------------------------------
 177 ; syscall Tracing
 178 ; ---------------------------------------------
 179 tracesys:
 180         ; save EFA in case tracer wants the PC of traced task
 181         ; using ERET won't work since next-PC has already committed
 182         lr  r12, [efa]
 183         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r11
 184         st  r12, [r11, THREAD_FAULT_ADDR]       ; thread.fault_address
 185
 186         ; PRE Sys Call Ptrace hook
 187         mov r0, sp                      ; pt_regs needed
 188         bl  @syscall_trace_entry
 189
 190         ; Tracing code now returns the syscall num (orig or modif)
 191         mov r8, r0
 192
 193         ; Do the Sys Call as we normally would.
 194         ; Validate the Sys Call number
 195         cmp     r8,  NR_syscalls
 196         mov.hi  r0, -ENOSYS
 197         bhi     tracesys_exit
 198
 199         ; Restore the sys-call args. Mere invocation of the hook abv could have
 200         ; clobbered them (since they are in scratch regs). The tracer could also
 201         ; have deliberately changed the syscall args: r0-r7
 202         ld  r0, [sp, PT_r0]
 203         ld  r1, [sp, PT_r1]
 204         ld  r2, [sp, PT_r2]
 205         ld  r3, [sp, PT_r3]
 206         ld  r4, [sp, PT_r4]
 207         ld  r5, [sp, PT_r5]
 208         ld  r6, [sp, PT_r6]
 209         ld  r7, [sp, PT_r7]
 210         ld.as   r9, [sys_call_table, r8]
 211         jl      [r9]        ; Entry into Sys Call Handler
 212
 213 tracesys_exit:
 214         st  r0, [sp, PT_r0]     ; sys call return value in pt_regs
 215
 216         ;POST Sys Call Ptrace Hook
 217         bl  @syscall_trace_exit
 218         b   ret_from_exception ; NOT ret_from_system_call at is saves r0 which
 219         ; we'd done before calling post hook above
 220
 221 ; ---------------------------------------------
 222 ; Breakpoint TRAP
 223 ; ---------------------------------------------
 224 trap_with_param:
 225
 226         ; stop_pc info by gdb needs this info
 227         lr  r0, [efa]
 228         mov r1, sp
 229
 230         ; Now that we have read EFA, it is safe to do "fake" rtie
 231         ;   and get out of CPU exception mode
 232         FAKE_RET_FROM_EXCPN
 233
 234         ; Save callee regs in case gdb wants to have a look
 235         ; SP will grow up by size of CALLEE Reg-File
 236         ; NOTE: clobbers r12
 237         SAVE_CALLEE_SAVED_USER
 238
 239         ; save location of saved Callee Regs @ thread_struct->pc
 240         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r10
 241         st  sp, [r10, THREAD_CALLEE_REG]
 242
 243         ; Call the trap handler
 244         bl  do_non_swi_trap
 245
 246         ; unwind stack to discard Callee saved Regs
 247         DISCARD_CALLEE_SAVED_USER
 248
 249         b   ret_from_exception
 250
 251 ; ---------------------------------------------
 252 ; syscall TRAP
 253 ; ABI: (r0-r7) upto 8 args, (r8) syscall number
 254 ; ---------------------------------------------
 255
 256 ENTRY(EV_Trap)
 257
 258         EXCEPTION_PROLOGUE
 259
 260         ;============ TRAP 1   :breakpoints
 261         ; Check ECR for trap with arg (PROLOGUE ensures r9 has ECR)
 262         bmsk.f 0, r9, 7
 263         bnz    trap_with_param
 264
 265         ;============ TRAP  (no param): syscall top level
 266
 267         ; First return from Exception to pure K mode (Exception/IRQs renabled)
 268         FAKE_RET_FROM_EXCPN
 269
 270         ; If syscall tracing ongoing, invoke pre-post-hooks
 271         GET_CURR_THR_INFO_FLAGS   r10
 272         btst r10, TIF_SYSCALL_TRACE
 273         bnz tracesys  ; this never comes back
 274
 275         ;============ Normal syscall case
 276
 277         ; syscall num shd not exceed the total system calls avail
 278         cmp     r8,  NR_syscalls
 279         mov.hi  r0, -ENOSYS
 280         bhi     ret_from_system_call
 281
 282         ; Offset into the syscall_table and call handler
 283         ld.as   r9,[sys_call_table, r8]
 284         jl      [r9]        ; Entry into Sys Call Handler
 285
 286         ; fall through to ret_from_system_call
 287 END(EV_Trap)
 288
 289 ENTRY(ret_from_system_call)
 290
 291         st  r0, [sp, PT_r0]     ; sys call return value in pt_regs
 292
 293         ; fall through yet again to ret_from_exception
 294
 295 ;############# Return from Intr/Excp/Trap (Linux Specifics) ##############
 296 ;
 297 ; If ret to user mode do we need to handle signals, schedule() et al.
 298
 299 ENTRY(ret_from_exception)
 300
 301         ; Pre-{IRQ,Trap,Exception} K/U mode from pt_regs->status32
 302         ld  r8, [sp, PT_status32]   ; returning to User/Kernel Mode
 303
 304         bbit0  r8, STATUS_U_BIT, resume_kernel_mode
 305
 306         ; Before returning to User mode check-for-and-complete any pending work
 307         ; such as rescheduling/signal-delivery etc.
 308 resume_user_mode_begin:
 309
 310         ; Disable IRQs to ensures that chk for pending work itself is atomic
 311         ; (and we don't end up missing a NEED_RESCHED/SIGPENDING due to an
 312         ; interim IRQ).
 313         IRQ_DISABLE     r10
 314
 315         ; Fast Path return to user mode if no pending work
 316         GET_CURR_THR_INFO_FLAGS   r9
 317         and.f  0,  r9, _TIF_WORK_MASK
 318         bz     .Lrestore_regs
 319
 320         ; --- (Slow Path #1) task preemption ---
 321         bbit0  r9, TIF_NEED_RESCHED, .Lchk_pend_signals
 322         mov    blink, resume_user_mode_begin  ; tail-call to U mode ret chks
 323         b      @schedule        ; BTST+Bnz causes relo error in link
 324
 325 .Lchk_pend_signals:
 326         IRQ_ENABLE      r10
 327
 328         ; --- (Slow Path #2) pending signal  ---
 329         mov r0, sp      ; pt_regs for arg to do_signal()/do_notify_resume()
 330
 331         GET_CURR_THR_INFO_FLAGS   r9
 332         bbit0  r9, TIF_SIGPENDING, .Lchk_notify_resume
 333
 334         ; Normal Trap/IRQ entry only saves Scratch (caller-saved) regs
 335         ; in pt_reg since the "C" ABI (kernel code) will automatically
 336         ; save/restore callee-saved regs.
 337         ;
 338         ; However, here we need to explicitly save callee regs because
 339         ; (i)  If this signal causes coredump - full regfile needed
 340         ; (ii) If signal is SIGTRAP/SIGSTOP, task is being traced thus
 341         ;      tracer might call PEEKUSR(CALLEE reg)
 342         ;
 343         ; NOTE: SP will grow up by size of CALLEE Reg-File
 344         SAVE_CALLEE_SAVED_USER          ; clobbers r12
 345
 346         ; save location of saved Callee Regs @ thread_struct->callee
 347         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r10
 348         st  sp, [r10, THREAD_CALLEE_REG]
 349
 350         bl  @do_signal
 351
 352         ; Ideally we want to discard the Callee reg above, however if this was
 353         ; a tracing signal, tracer could have done a POKEUSR(CALLEE reg)
 354         RESTORE_CALLEE_SAVED_USER
 355
 356         b      resume_user_mode_begin   ; loop back to start of U mode ret
 357
 358         ; --- (Slow Path #3) notify_resume ---
 359 .Lchk_notify_resume:
 360         btst   r9, TIF_NOTIFY_RESUME
 361         blnz   @do_notify_resume
 362         b      resume_user_mode_begin   ; unconditionally back to U mode ret chks
 363                                         ; for single exit point from this block
 364
 365 resume_kernel_mode:
 366
 367         ; Disable Interrupts from this point on
 368         ; CONFIG_PREEMPT: This is a must for preempt_schedule_irq()
 369         ; !CONFIG_PREEMPT: To ensure restore_regs is intr safe
 370         IRQ_DISABLE     r9
 371
 372 #ifdef CONFIG_PREEMPT
 373
 374         ; Can't preempt if preemption disabled
 375         GET_CURR_THR_INFO_FROM_SP   r10
 376         ld  r8, [r10, THREAD_INFO_PREEMPT_COUNT]
 377         brne  r8, 0, .Lrestore_regs
 378
 379         ; check if this task's NEED_RESCHED flag set
 380         ld  r9, [r10, THREAD_INFO_FLAGS]
 381         bbit0  r9, TIF_NEED_RESCHED, .Lrestore_regs
 382
 383         ; Invoke PREEMPTION
 384         bl      preempt_schedule_irq
 385
 386         ; preempt_schedule_irq() always returns with IRQ disabled
 387 #endif
 388
 389         b       .Lrestore_regs
 390
 391 ##### DONT ADD CODE HERE - .Lrestore_regs actually follows in entry-<isa>.S
 392