arch/powerpc/kernel/vdso32/vdso32.lds.S

   1 /*
   2  * This is the infamous ld script for the 32 bits vdso
   3  * library
   4  */
   5 #include <asm/vdso.h>
   6
   7 OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc", "elf32-powerpc")
   8 OUTPUT_ARCH(powerpc:common)
   9 ENTRY(_start)
  10
  11 SECTIONS
  12 {
  13         . = VDSO32_LBASE + SIZEOF_HEADERS;
  14
  15         .hash           : { *(.hash) }                  :text
  16         .gnu.hash       : { *(.gnu.hash) }
  17         .dynsym         : { *(.dynsym) }
  18         .dynstr         : { *(.dynstr) }
  19         .gnu.version    : { *(.gnu.version) }
  20         .gnu.version_d  : { *(.gnu.version_d) }
  21         .gnu.version_r  : { *(.gnu.version_r) }
  22
  23         .note           : { *(.note.*) }                :text   :note
  24
  25         . = ALIGN(16);
  26         .text           : {
  27                 *(.text .stub .text.* .gnu.linkonce.t.*)
  28         }
  29         PROVIDE(__etext = .);
  30         PROVIDE(_etext = .);
  31         PROVIDE(etext = .);
  32
  33         . = ALIGN(8);
  34         __ftr_fixup     : { *(__ftr_fixup) }
  35
  36 #ifdef CONFIG_PPC64
  37         . = ALIGN(8);
  38         __fw_ftr_fixup  : { *(__fw_ftr_fixup) }
  39 #endif
  40
  41         /*
  42          * Other stuff is appended to the text segment:
  43          */
  44         .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  45         .rodata1        : { *(.rodata1) }
  46
  47         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  48         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  49         .gcc_except_table : { *(.gcc_except_table) }
  50         .fixup          : { *(.fixup) }
  51
  52         .dynamic        : { *(.dynamic) }               :text   :dynamic
  53         .got            : { *(.got) }
  54         .plt            : { *(.plt) }
  55
  56         _end = .;
  57         __end = .;
  58         PROVIDE(end = .);
  59
  60         /*
  61          * Stabs debugging sections are here too.
  62          */
  63         .stab 0 : { *(.stab) }
  64         .stabstr 0 : { *(.stabstr) }
  65         .stab.excl 0 : { *(.stab.excl) }
  66         .stab.exclstr 0 : { *(.stab.exclstr) }
  67         .stab.index 0 : { *(.stab.index) }
  68         .stab.indexstr 0 : { *(.stab.indexstr) }
  69         .comment       0 : { *(.comment) }
  70
  71         /*
  72          * DWARF debug sections.
  73          * Symbols in the DWARF debugging sections are relative to the beginning
  74          * of the section so we begin them at 0.
  75          */
  76         /* DWARF 1 */
  77         .debug          0 : { *(.debug) }
  78         .line           0 : { *(.line) }
  79         /* GNU DWARF 1 extensions */
  80         .debug_srcinfo  0 : { *(.debug_srcinfo) }
  81         .debug_sfnames  0 : { *(.debug_sfnames) }
  82         /* DWARF 1.1 and DWARF 2 */
  83         .debug_aranges  0 : { *(.debug_aranges) }
  84         .debug_pubnames 0 : { *(.debug_pubnames) }
  85         /* DWARF 2 */
  86         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  87         .debug_abbrev   0 : { *(.debug_abbrev) }
  88         .debug_line     0 : { *(.debug_line) }
  89         .debug_frame    0 : { *(.debug_frame) }
  90         .debug_str      0 : { *(.debug_str) }
  91         .debug_loc      0 : { *(.debug_loc) }
  92         .debug_macinfo  0 : { *(.debug_macinfo) }
  93         /* SGI/MIPS DWARF 2 extensions */
  94         .debug_weaknames 0 : { *(.debug_weaknames) }
  95         .debug_funcnames 0 : { *(.debug_funcnames) }
  96         .debug_typenames 0 : { *(.debug_typenames) }
  97         .debug_varnames  0 : { *(.debug_varnames) }
  98
  99         /DISCARD/       : {
 100                 *(.note.GNU-stack)
 101                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
 102                 *(.bss .sbss .dynbss .dynsbss)
 103         }
 104 }
 105
 106 /*
 107  * Very old versions of ld do not recognize this name token; use the constant.
 108  */
 109 #define PT_GNU_EH_FRAME 0x6474e550
 110
 111 /*
 112  * We must supply the ELF program headers explicitly to get just one
 113  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 114  */
 115 PHDRS
 116 {
 117         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
 118         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
 119         note            PT_NOTE FLAGS(4);               /* PF_R */
 120         eh_frame_hdr    PT_GNU_EH_FRAME;
 121 }
 122
 123 /*
 124  * This controls what symbols we export from the DSO.
 125  */
 126 VERSION
 127 {
 128         VDSO_VERSION_STRING {
 129         global:
 130                 /*
 131                  * Has to be there for the kernel to find
 132                  */
 133                 __kernel_datapage_offset;
 134
 135                 __kernel_get_syscall_map;
 136                 __kernel_gettimeofday;
 137                 __kernel_clock_gettime;
 138                 __kernel_clock_getres;
 139                 __kernel_get_tbfreq;
 140                 __kernel_sync_dicache;
 141                 __kernel_sync_dicache_p5;
 142                 __kernel_sigtramp32;
 143                 __kernel_sigtramp_rt32;
 144
 145         local: *;
 146         };
 147 }