arch/sh/kernel/vsyscall/vsyscall.lds.S

   1 /*
   2  * Linker script for vsyscall DSO.  The vsyscall page is an ELF shared
   3  * object prelinked to its virtual address, and with only one read-only
   4  * segment (that fits in one page).  This script controls its layout.
   5  */
   6 #include <asm/asm-offsets.h>
   7
   8 #ifdef CONFIG_CPU_LITTLE_ENDIAN
   9 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  10 #else
  11 OUTPUT_FORMAT("elf32-shbig-linux", "elf32-shbig-linux", "elf32-shbig-linux")
  12 #endif
  13 OUTPUT_ARCH(sh)
  14
  15 /* The ELF entry point can be used to set the AT_SYSINFO value.  */
  16 ENTRY(__kernel_vsyscall);
  17
  18 SECTIONS
  19 {
  20         . = SIZEOF_HEADERS;
  21
  22         .hash           : { *(.hash) }                  :text
  23         .gnu.hash       : { *(.gnu.hash) }
  24         .dynsym         : { *(.dynsym) }
  25         .dynstr         : { *(.dynstr) }
  26         .gnu.version    : { *(.gnu.version) }
  27         .gnu.version_d  : { *(.gnu.version_d) }
  28         .gnu.version_r  : { *(.gnu.version_r) }
  29
  30         /*
  31          * This linker script is used both with -r and with -shared.
  32          * For the layouts to match, we need to skip more than enough
  33          * space for the dynamic symbol table et al.  If this amount
  34          * is insufficient, ld -shared will barf.  Just increase it here.
  35          */
  36         . = 0x400;
  37
  38         .text           : { *(.text) }                  :text   =0x90909090
  39         .note           : { *(.note.*) }                :text   :note
  40         .eh_frame_hdr   : { *(.eh_frame_hdr ) }         :text   :eh_frame_hdr
  41         .eh_frame       : {
  42                 KEEP (*(.eh_frame))
  43                 LONG (0)
  44         }                                               :text
  45         .dynamic        : { *(.dynamic) }               :text   :dynamic
  46         .useless        : {
  47               *(.got.plt) *(.got)
  48               *(.data .data.* .gnu.linkonce.d.*)
  49               *(.dynbss)
  50               *(.bss .bss.* .gnu.linkonce.b.*)
  51         }                                               :text
  52 }
  53
  54 /*
  55  * Very old versions of ld do not recognize this name token; use the constant.
  56  */
  57 #define PT_GNU_EH_FRAME 0x6474e550
  58
  59 /*
  60  * We must supply the ELF program headers explicitly to get just one
  61  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  62  */
  63 PHDRS
  64 {
  65         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  66         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
  67         note            PT_NOTE FLAGS(4);               /* PF_R */
  68         eh_frame_hdr    PT_GNU_EH_FRAME;
  69 }
  70
  71 /*
  72  * This controls what symbols we export from the DSO.
  73  */
  74 VERSION
  75 {
  76         LINUX_2.6 {
  77         global:
  78                 __kernel_vsyscall;
  79                 __kernel_sigreturn;
  80                 __kernel_rt_sigreturn;
  81
  82         local: *;
  83         };
  84 }