arch/arm64/kernel/entry-ftrace.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  * arch/arm64/kernel/entry-ftrace.S
   4  *
   5  * Copyright (C) 2013 Linaro Limited
   6  * Author: AKASHI Takahiro <takahiro.akashi@linaro.org>
   7  */
   8
   9 #include <linux/linkage.h>
  10 #include <asm/asm-offsets.h>
  11 #include <asm/assembler.h>
  12 #include <asm/ftrace.h>
  13 #include <asm/insn.h>
  14
  15 #ifdef CONFIG_DYNAMIC_FTRACE_WITH_REGS
  16 /*
  17  * Due to -fpatchable-function-entry=2, the compiler has placed two NOPs before
  18  * the regular function prologue. For an enabled callsite, ftrace_init_nop() and
  19  * ftrace_make_call() have patched those NOPs to:
  20  *
  21  *      MOV     X9, LR
  22  *      BL      <entry>
  23  *
  24  * ... where <entry> is either ftrace_caller or ftrace_regs_caller.
  25  *
  26  * Each instrumented function follows the AAPCS, so here x0-x8 and x18-x30 are
  27  * live (x18 holds the Shadow Call Stack pointer), and x9-x17 are safe to
  28  * clobber.
  29  *
  30  * We save the callsite's context into a pt_regs before invoking any ftrace
  31  * callbacks. So that we can get a sensible backtrace, we create a stack record
  32  * for the callsite and the ftrace entry assembly. This is not sufficient for
  33  * reliable stacktrace: until we create the callsite stack record, its caller
  34  * is missing from the LR and existing chain of frame records.
  35  */
  36         .macro  ftrace_regs_entry, allregs=0
  37         /* Make room for pt_regs, plus a callee frame */
  38         sub     sp, sp, #(S_FRAME_SIZE + 16)
  39
  40         /* Save function arguments (and x9 for simplicity) */
  41         stp     x0, x1, [sp, #S_X0]
  42         stp     x2, x3, [sp, #S_X2]
  43         stp     x4, x5, [sp, #S_X4]
  44         stp     x6, x7, [sp, #S_X6]
  45         stp     x8, x9, [sp, #S_X8]
  46
  47         /* Optionally save the callee-saved registers, always save the FP */
  48         .if \allregs == 1
  49         stp     x10, x11, [sp, #S_X10]
  50         stp     x12, x13, [sp, #S_X12]
  51         stp     x14, x15, [sp, #S_X14]
  52         stp     x16, x17, [sp, #S_X16]
  53         stp     x18, x19, [sp, #S_X18]
  54         stp     x20, x21, [sp, #S_X20]
  55         stp     x22, x23, [sp, #S_X22]
  56         stp     x24, x25, [sp, #S_X24]
  57         stp     x26, x27, [sp, #S_X26]
  58         stp     x28, x29, [sp, #S_X28]
  59         .else
  60         str     x29, [sp, #S_FP]
  61         .endif
  62
  63         /* Save the callsite's SP and LR */
  64         add     x10, sp, #(S_FRAME_SIZE + 16)
  65         stp     x9, x10, [sp, #S_LR]
  66
  67         /* Save the PC after the ftrace callsite */
  68         str     x30, [sp, #S_PC]
  69
  70         /* Create a frame record for the callsite above pt_regs */
  71         stp     x29, x9, [sp, #S_FRAME_SIZE]
  72         add     x29, sp, #S_FRAME_SIZE
  73
  74         /* Create our frame record within pt_regs. */
  75         stp     x29, x30, [sp, #S_STACKFRAME]
  76         add     x29, sp, #S_STACKFRAME
  77         .endm
  78
  79 SYM_CODE_START(ftrace_regs_caller)
  80         ftrace_regs_entry       1
  81         b       ftrace_common
  82 SYM_CODE_END(ftrace_regs_caller)
  83
  84 SYM_CODE_START(ftrace_caller)
  85         ftrace_regs_entry       0
  86         b       ftrace_common
  87 SYM_CODE_END(ftrace_caller)
  88
  89 SYM_CODE_START(ftrace_common)
  90         sub     x0, x30, #AARCH64_INSN_SIZE     // ip (callsite's BL insn)
  91         mov     x1, x9                          // parent_ip (callsite's LR)
  92         ldr_l   x2, function_trace_op           // op
  93         mov     x3, sp                          // regs
  94
  95 SYM_INNER_LABEL(ftrace_call, SYM_L_GLOBAL)
  96         bl      ftrace_stub
  97
  98 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  99 SYM_INNER_LABEL(ftrace_graph_call, SYM_L_GLOBAL) // ftrace_graph_caller();
 100         nop                             // If enabled, this will be replaced
 101                                         // "b ftrace_graph_caller"
 102 #endif
 103
 104 /*
 105  * At the callsite x0-x8 and x19-x30 were live. Any C code will have preserved
 106  * x19-x29 per the AAPCS, and we created frame records upon entry, so we need
 107  * to restore x0-x8, x29, and x30.
 108  */
 109 ftrace_common_return:
 110         /* Restore function arguments */
 111         ldp     x0, x1, [sp]
 112         ldp     x2, x3, [sp, #S_X2]
 113         ldp     x4, x5, [sp, #S_X4]
 114         ldp     x6, x7, [sp, #S_X6]
 115         ldr     x8, [sp, #S_X8]
 116
 117         /* Restore the callsite's FP, LR, PC */
 118         ldr     x29, [sp, #S_FP]
 119         ldr     x30, [sp, #S_LR]
 120         ldr     x9, [sp, #S_PC]
 121
 122         /* Restore the callsite's SP */
 123         add     sp, sp, #S_FRAME_SIZE + 16
 124
 125         ret     x9
 126 SYM_CODE_END(ftrace_common)
 127
 128 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 129 SYM_CODE_START(ftrace_graph_caller)
 130         ldr     x0, [sp, #S_PC]
 131         sub     x0, x0, #AARCH64_INSN_SIZE      // ip (callsite's BL insn)
 132         add     x1, sp, #S_LR                   // parent_ip (callsite's LR)
 133         ldr     x2, [sp, #S_FRAME_SIZE]         // parent fp (callsite's FP)
 134         bl      prepare_ftrace_return
 135         b       ftrace_common_return
 136 SYM_CODE_END(ftrace_graph_caller)
 137 #endif
 138
 139 #else /* CONFIG_DYNAMIC_FTRACE_WITH_REGS */
 140
 141 /*
 142  * Gcc with -pg will put the following code in the beginning of each function:
 143  *      mov x0, x30
 144  *      bl _mcount
 145  *      [function's body ...]
 146  * "bl _mcount" may be replaced to "bl ftrace_caller" or NOP if dynamic
 147  * ftrace is enabled.
 148  *
 149  * Please note that x0 as an argument will not be used here because we can
 150  * get lr(x30) of instrumented function at any time by winding up call stack
 151  * as long as the kernel is compiled without -fomit-frame-pointer.
 152  * (or CONFIG_FRAME_POINTER, this is forced on arm64)
 153  *
 154  * stack layout after mcount_enter in _mcount():
 155  *
 156  * current sp/fp =>  0:+-----+
 157  * in _mcount()        | x29 | -> instrumented function's fp
 158  *                     +-----+
 159  *                     | x30 | -> _mcount()'s lr (= instrumented function's pc)
 160  * old sp       => +16:+-----+
 161  * when instrumented   |     |
 162  * function calls      | ... |
 163  * _mcount()           |     |
 164  *                     |     |
 165  * instrumented => +xx:+-----+
 166  * function's fp       | x29 | -> parent's fp
 167  *                     +-----+
 168  *                     | x30 | -> instrumented function's lr (= parent's pc)
 169  *                     +-----+
 170  *                     | ... |
 171  */
 172
 173         .macro mcount_enter
 174         stp     x29, x30, [sp, #-16]!
 175         mov     x29, sp
 176         .endm
 177
 178         .macro mcount_exit
 179         ldp     x29, x30, [sp], #16
 180         ret
 181         .endm
 182
 183         .macro mcount_adjust_addr rd, rn
 184         sub     \rd, \rn, #AARCH64_INSN_SIZE
 185         .endm
 186
 187         /* for instrumented function's parent */
 188         .macro mcount_get_parent_fp reg
 189         ldr     \reg, [x29]
 190         ldr     \reg, [\reg]
 191         .endm
 192
 193         /* for instrumented function */
 194         .macro mcount_get_pc0 reg
 195         mcount_adjust_addr      \reg, x30
 196         .endm
 197
 198         .macro mcount_get_pc reg
 199         ldr     \reg, [x29, #8]
 200         mcount_adjust_addr      \reg, \reg
 201         .endm
 202
 203         .macro mcount_get_lr reg
 204         ldr     \reg, [x29]
 205         ldr     \reg, [\reg, #8]
 206         .endm
 207
 208         .macro mcount_get_lr_addr reg
 209         ldr     \reg, [x29]
 210         add     \reg, \reg, #8
 211         .endm
 212
 213 #ifndef CONFIG_DYNAMIC_FTRACE
 214 /*
 215  * void _mcount(unsigned long return_address)
 216  * @return_address: return address to instrumented function
 217  *
 218  * This function makes calls, if enabled, to:
 219  *     - tracer function to probe instrumented function's entry,
 220  *     - ftrace_graph_caller to set up an exit hook
 221  */
 222 SYM_FUNC_START(_mcount)
 223         mcount_enter
 224
 225         ldr_l   x2, ftrace_trace_function
 226         adr     x0, ftrace_stub
 227         cmp     x0, x2                  // if (ftrace_trace_function
 228         b.eq    skip_ftrace_call        //     != ftrace_stub) {
 229
 230         mcount_get_pc   x0              //       function's pc
 231         mcount_get_lr   x1              //       function's lr (= parent's pc)
 232         blr     x2                      //   (*ftrace_trace_function)(pc, lr);
 233
 234 skip_ftrace_call:                       // }
 235 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 236         ldr_l   x2, ftrace_graph_return
 237         cmp     x0, x2                  //   if ((ftrace_graph_return
 238         b.ne    ftrace_graph_caller     //        != ftrace_stub)
 239
 240         ldr_l   x2, ftrace_graph_entry  //     || (ftrace_graph_entry
 241         adr_l   x0, ftrace_graph_entry_stub //     != ftrace_graph_entry_stub))
 242         cmp     x0, x2
 243         b.ne    ftrace_graph_caller     //     ftrace_graph_caller();
 244 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
 245         mcount_exit
 246 SYM_FUNC_END(_mcount)
 247 EXPORT_SYMBOL(_mcount)
 248 NOKPROBE(_mcount)
 249
 250 #else /* CONFIG_DYNAMIC_FTRACE */
 251 /*
 252  * _mcount() is used to build the kernel with -pg option, but all the branch
 253  * instructions to _mcount() are replaced to NOP initially at kernel start up,
 254  * and later on, NOP to branch to ftrace_caller() when enabled or branch to
 255  * NOP when disabled per-function base.
 256  */
 257 SYM_FUNC_START(_mcount)
 258         ret
 259 SYM_FUNC_END(_mcount)
 260 EXPORT_SYMBOL(_mcount)
 261 NOKPROBE(_mcount)
 262
 263 /*
 264  * void ftrace_caller(unsigned long return_address)
 265  * @return_address: return address to instrumented function
 266  *
 267  * This function is a counterpart of _mcount() in 'static' ftrace, and
 268  * makes calls to:
 269  *     - tracer function to probe instrumented function's entry,
 270  *     - ftrace_graph_caller to set up an exit hook
 271  */
 272 SYM_FUNC_START(ftrace_caller)
 273         mcount_enter
 274
 275         mcount_get_pc0  x0              //     function's pc
 276         mcount_get_lr   x1              //     function's lr
 277
 278 SYM_INNER_LABEL(ftrace_call, SYM_L_GLOBAL)      // tracer(pc, lr);
 279         nop                             // This will be replaced with "bl xxx"
 280                                         // where xxx can be any kind of tracer.
 281
 282 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 283 SYM_INNER_LABEL(ftrace_graph_call, SYM_L_GLOBAL) // ftrace_graph_caller();
 284         nop                             // If enabled, this will be replaced
 285                                         // "b ftrace_graph_caller"
 286 #endif
 287
 288         mcount_exit
 289 SYM_FUNC_END(ftrace_caller)
 290 #endif /* CONFIG_DYNAMIC_FTRACE */
 291
 292 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 293 /*
 294  * void ftrace_graph_caller(void)
 295  *
 296  * Called from _mcount() or ftrace_caller() when function_graph tracer is
 297  * selected.
 298  * This function w/ prepare_ftrace_return() fakes link register's value on
 299  * the call stack in order to intercept instrumented function's return path
 300  * and run return_to_handler() later on its exit.
 301  */
 302 SYM_FUNC_START(ftrace_graph_caller)
 303         mcount_get_pc             x0    //     function's pc
 304         mcount_get_lr_addr        x1    //     pointer to function's saved lr
 305         mcount_get_parent_fp      x2    //     parent's fp
 306         bl      prepare_ftrace_return   // prepare_ftrace_return(pc, &lr, fp)
 307
 308         mcount_exit
 309 SYM_FUNC_END(ftrace_graph_caller)
 310 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
 311 #endif /* CONFIG_DYNAMIC_FTRACE_WITH_REGS */
 312
 313 SYM_FUNC_START(ftrace_stub)
 314         ret
 315 SYM_FUNC_END(ftrace_stub)
 316
 317 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 318 /*
 319  * void return_to_handler(void)
 320  *
 321  * Run ftrace_return_to_handler() before going back to parent.
 322  * @fp is checked against the value passed by ftrace_graph_caller().
 323  */
 324 SYM_CODE_START(return_to_handler)
 325         /* save return value regs */
 326         sub sp, sp, #64
 327         stp x0, x1, [sp]
 328         stp x2, x3, [sp, #16]
 329         stp x4, x5, [sp, #32]
 330         stp x6, x7, [sp, #48]
 331
 332         mov     x0, x29                 //     parent's fp
 333         bl      ftrace_return_to_handler// addr = ftrace_return_to_hander(fp);
 334         mov     x30, x0                 // restore the original return address
 335
 336         /* restore return value regs */
 337         ldp x0, x1, [sp]
 338         ldp x2, x3, [sp, #16]
 339         ldp x4, x5, [sp, #32]
 340         ldp x6, x7, [sp, #48]
 341         add sp, sp, #64
 342
 343         ret
 344 SYM_CODE_END(return_to_handler)
 345 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */