arch/s390/kernel/mcount.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * Copyright IBM Corp. 2008, 2009
   4  *
   5  *   Author(s): Heiko Carstens <heiko.carstens@de.ibm.com>,
   6  *
   7  */
   8
   9 #include <linux/linkage.h>
  10 #include <asm/asm-offsets.h>
  11 #include <asm/ftrace.h>
  12 #include <asm/nospec-insn.h>
  13 #include <asm/ptrace.h>
  14 #include <asm/export.h>
  15
  16         GEN_BR_THUNK %r1
  17         GEN_BR_THUNK %r14
  18
  19         .section .kprobes.text, "ax"
  20
  21 ENTRY(ftrace_stub)
  22         BR_EX   %r14
  23 ENDPROC(ftrace_stub)
  24
  25 #define STACK_FRAME_SIZE  (STACK_FRAME_OVERHEAD + __PT_SIZE)
  26 #define STACK_PTREGS      (STACK_FRAME_OVERHEAD)
  27 #define STACK_PTREGS_GPRS (STACK_PTREGS + __PT_GPRS)
  28 #define STACK_PTREGS_PSW  (STACK_PTREGS + __PT_PSW)
  29 #ifdef __PACK_STACK
  30 /* allocate just enough for r14, r15 and backchain */
  31 #define TRACED_FUNC_FRAME_SIZE  24
  32 #else
  33 #define TRACED_FUNC_FRAME_SIZE  STACK_FRAME_OVERHEAD
  34 #endif
  35
  36 ENTRY(_mcount)
  37         BR_EX   %r14
  38 ENDPROC(_mcount)
  39 EXPORT_SYMBOL(_mcount)
  40
  41 ENTRY(ftrace_caller)
  42         .globl  ftrace_regs_caller
  43         .set    ftrace_regs_caller,ftrace_caller
  44         stg     %r14,(__SF_GPRS+8*8)(%r15)      # save traced function caller
  45         lghi    %r14,0                          # save condition code
  46         ipm     %r14                            # don't put any instructions
  47         sllg    %r14,%r14,16                    # clobbering CC before this point
  48         lgr     %r1,%r15
  49 #if !(defined(CC_USING_HOTPATCH) || defined(CC_USING_NOP_MCOUNT))
  50         aghi    %r0,MCOUNT_RETURN_FIXUP
  51 #endif
  52         # allocate stack frame for ftrace_caller to contain traced function
  53         aghi    %r15,-TRACED_FUNC_FRAME_SIZE
  54         stg     %r1,__SF_BACKCHAIN(%r15)
  55         stg     %r0,(__SF_GPRS+8*8)(%r15)
  56         stg     %r15,(__SF_GPRS+9*8)(%r15)
  57         # allocate pt_regs and stack frame for ftrace_trace_function
  58         aghi    %r15,-STACK_FRAME_SIZE
  59         stg     %r1,(STACK_PTREGS_GPRS+15*8)(%r15)
  60         stg     %r14,(STACK_PTREGS_PSW)(%r15)
  61         lg      %r14,(__SF_GPRS+8*8)(%r1)       # restore original return address
  62         stosm   (STACK_PTREGS_PSW)(%r15),0
  63         aghi    %r1,-TRACED_FUNC_FRAME_SIZE
  64         stg     %r1,__SF_BACKCHAIN(%r15)
  65         stg     %r0,(STACK_PTREGS_PSW+8)(%r15)
  66         stmg    %r2,%r14,(STACK_PTREGS_GPRS+2*8)(%r15)
  67 #ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
  68         aghik   %r2,%r0,-MCOUNT_INSN_SIZE
  69         lgrl    %r4,function_trace_op
  70         lgrl    %r1,ftrace_trace_function
  71 #else
  72         lgr     %r2,%r0
  73         aghi    %r2,-MCOUNT_INSN_SIZE
  74         larl    %r4,function_trace_op
  75         lg      %r4,0(%r4)
  76         larl    %r1,ftrace_trace_function
  77         lg      %r1,0(%r1)
  78 #endif
  79         lgr     %r3,%r14
  80         la      %r5,STACK_PTREGS(%r15)
  81         BASR_EX %r14,%r1
  82 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  83 # The j instruction gets runtime patched to a nop instruction.
  84 # See ftrace_enable_ftrace_graph_caller.
  85         .globl ftrace_graph_caller
  86 ftrace_graph_caller:
  87         j       ftrace_graph_caller_end
  88         lmg     %r2,%r3,(STACK_PTREGS_GPRS+14*8)(%r15)
  89         lg      %r4,(STACK_PTREGS_PSW+8)(%r15)
  90         brasl   %r14,prepare_ftrace_return
  91         stg     %r2,(STACK_PTREGS_GPRS+14*8)(%r15)
  92 ftrace_graph_caller_end:
  93         .globl  ftrace_graph_caller_end
  94 #endif
  95         lg      %r1,(STACK_PTREGS_PSW+8)(%r15)
  96         lmg     %r2,%r15,(STACK_PTREGS_GPRS+2*8)(%r15)
  97         BR_EX   %r1
  98 ENDPROC(ftrace_caller)
  99
 100 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 101
 102 ENTRY(return_to_handler)
 103         stmg    %r2,%r5,32(%r15)
 104         lgr     %r1,%r15
 105         aghi    %r15,-STACK_FRAME_OVERHEAD
 106         stg     %r1,__SF_BACKCHAIN(%r15)
 107         brasl   %r14,ftrace_return_to_handler
 108         aghi    %r15,STACK_FRAME_OVERHEAD
 109         lgr     %r14,%r2
 110         lmg     %r2,%r5,32(%r15)
 111         BR_EX   %r14
 112 ENDPROC(return_to_handler)
 113
 114 #endif