arch/um/kernel/dyn.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2 #include <asm/page.h>
   3
   4 OUTPUT_FORMAT(ELF_FORMAT)
   5 OUTPUT_ARCH(ELF_ARCH)
   6 ENTRY(_start)
   7 jiffies = jiffies_64;
   8
   9 SECTIONS
  10 {
  11   PROVIDE (__executable_start = START);
  12   . = START + SIZEOF_HEADERS;
  13   .interp         : { *(.interp) }
  14   __binary_start = .;
  15   . = ALIGN(4096);              /* Init code and data */
  16   _text = .;
  17   INIT_TEXT_SECTION(PAGE_SIZE)
  18
  19   . = ALIGN(PAGE_SIZE);
  20
  21   /* Read-only sections, merged into text segment: */
  22   .hash           : { *(.hash) }
  23   .gnu.hash       : { *(.gnu.hash) }
  24   .dynsym         : { *(.dynsym) }
  25   .dynstr         : { *(.dynstr) }
  26   .gnu.version    : { *(.gnu.version) }
  27   .gnu.version_d  : { *(.gnu.version_d) }
  28   .gnu.version_r  : { *(.gnu.version_r) }
  29   .rel.init       : { *(.rel.init) }
  30   .rela.init      : { *(.rela.init) }
  31   .rel.text       : { *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*) }
  32   .rela.text      : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) }
  33   .rel.fini       : { *(.rel.fini) }
  34   .rela.fini      : { *(.rela.fini) }
  35   .rel.rodata     : { *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*) }
  36   .rela.rodata    : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) }
  37   .rel.data       : { *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*) }
  38   .rela.data      : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) }
  39   .rel.tdata      : { *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*) }
  40   .rela.tdata     : { *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*) }
  41   .rel.tbss       : { *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*) }
  42   .rela.tbss      : { *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*) }
  43   .rel.ctors      : { *(.rel.ctors) }
  44   .rela.ctors     : { *(.rela.ctors) }
  45   .rel.dtors      : { *(.rel.dtors) }
  46   .rela.dtors     : { *(.rela.dtors) }
  47   .rel.got        : { *(.rel.got) }
  48   .rela.got       : { *(.rela.got) }
  49   .rel.bss        : { *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*) }
  50   .rela.bss       : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) }
  51   .rel.plt : {
  52         *(.rel.plt)
  53         PROVIDE_HIDDEN(__rel_iplt_start = .);
  54         *(.rel.iplt)
  55         PROVIDE_HIDDEN(__rel_iplt_end = .);
  56   }
  57   .rela.plt : {
  58         *(.rela.plt)
  59         PROVIDE_HIDDEN(__rela_iplt_start = .);
  60         *(.rela.iplt)
  61         PROVIDE_HIDDEN(__rela_iplt_end = .);
  62   }
  63   .init           : {
  64     KEEP (*(.init))
  65   } =0x90909090
  66   .plt            : { *(.plt) }
  67   .text           : {
  68     _stext = .;
  69     TEXT_TEXT
  70     SCHED_TEXT
  71     LOCK_TEXT
  72     *(.fixup)
  73     *(.stub .text.* .gnu.linkonce.t.*)
  74     /* .gnu.warning sections are handled specially by elf32.em.  */
  75     *(.gnu.warning)
  76
  77     . = ALIGN(PAGE_SIZE);
  78   } =0x90909090
  79   . = ALIGN(PAGE_SIZE);
  80   .syscall_stub : {
  81         __syscall_stub_start = .;
  82         *(.__syscall_stub*)
  83         __syscall_stub_end = .;
  84   }
  85   .fini           : {
  86     KEEP (*(.fini))
  87   } =0x90909090
  88
  89   .kstrtab : { *(.kstrtab) }
  90
  91   #include <asm/common.lds.S>
  92
  93   __init_begin = .;
  94   init.data : { INIT_DATA }
  95   __init_end = .;
  96
  97   /* Ensure the __preinit_array_start label is properly aligned.  We
  98      could instead move the label definition inside the section, but
  99      the linker would then create the section even if it turns out to
 100      be empty, which isn't pretty.  */
 101   . = ALIGN(32 / 8);
 102   .preinit_array     : { *(.preinit_array) }
 103   .init_array     : { *(.init_array) }
 104   .fini_array     : { *(.fini_array) }
 105   .data           : {
 106     INIT_TASK_DATA(KERNEL_STACK_SIZE)
 107     . = ALIGN(KERNEL_STACK_SIZE);
 108     *(.data..init_irqstack)
 109     DATA_DATA
 110     *(.data.* .gnu.linkonce.d.*)
 111     SORT(CONSTRUCTORS)
 112   }
 113   .data1          : { *(.data1) }
 114   .tdata          : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
 115   .tbss           : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
 116   .eh_frame       : { KEEP (*(.eh_frame)) }
 117   .gcc_except_table   : { *(.gcc_except_table) }
 118   .dynamic        : { *(.dynamic) }
 119   .ctors          : {
 120     /* gcc uses crtbegin.o to find the start of
 121        the constructors, so we make sure it is
 122        first.  Because this is a wildcard, it
 123        doesn't matter if the user does not
 124        actually link against crtbegin.o; the
 125        linker won't look for a file to match a
 126        wildcard.  The wildcard also means that it
 127        doesn't matter which directory crtbegin.o
 128        is in.  */
 129     KEEP (*crtbegin.o(.ctors))
 130     /* We don't want to include the .ctor section from
 131        from the crtend.o file until after the sorted ctors.
 132        The .ctor section from the crtend file contains the
 133        end of ctors marker and it must be last */
 134     KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
 135     KEEP (*(SORT(.ctors.*)))
 136     KEEP (*(.ctors))
 137   }
 138   .dtors          : {
 139     KEEP (*crtbegin.o(.dtors))
 140     KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
 141     KEEP (*(SORT(.dtors.*)))
 142     KEEP (*(.dtors))
 143   }
 144   .jcr            : { KEEP (*(.jcr)) }
 145   .got            : { *(.got.plt) *(.got) }
 146   _edata = .;
 147   PROVIDE (edata = .);
 148   .bss            : {
 149    __bss_start = .;
 150    *(.dynbss)
 151    *(.bss .bss.* .gnu.linkonce.b.*)
 152    *(COMMON)
 153    /* Align here to ensure that the .bss section occupies space up to
 154       _end.  Align after .bss to ensure correct alignment even if the
 155       .bss section disappears because there are no input sections.  */
 156    . = ALIGN(32 / 8);
 157   . = ALIGN(32 / 8);
 158   }
 159    __bss_stop = .;
 160   _end = .;
 161   PROVIDE (end = .);
 162
 163   STABS_DEBUG
 164
 165   DWARF_DEBUG
 166
 167   DISCARDS
 168 }